1ère lettre du jour d'une date

[Xxaann]

Bonjour à tous,

J'aimerais avoir suivant une date de type 19/01/2016 la première lettre du jour c'est à dire M pour Mardi.

J'ai beau cherché ais là, je ne trouve vraiment pas...

Merci pour votre aide
Nico

 

[Victor21]

Re : 1ère lettre du jour d'une date

Bonsoir.

Essayez, avec la date en E1 :

=CHOISIR(EQUIV(JOURSEM(A1;1);{1;2;3;4;5;6;7};1);"D";"L";"M";"M";"J";"V";"S")

 

[job75]

Re : 1ère lettre du jour d'une date

Bonsoir Xxaann, Patrick,

Avec la date en A1 :

=MAJUSCULE(GAUCHE(TEXTE(A1;"jjj")))

A+

 

[Xxaann]

Re : 1ère lettre du jour d'une date

Merci Patrick et Job,
Je garderai en tête ces deux solutions.
La première, je comprends pas comment j'y ai pas pensé...

Excel, c'est tellement facile avec excel-download.

 

[Modeste geedee]

Re : 1ère lettre du jour d'une date

Salut Patrick©...

Heu... ??? pourquoi pas plus simplement :

=CHOISIR(JOURSEM(A1;2);"L";"M";"M";"J";"V";"S";"D")

ou bien encore :

=STXT("DLMMJVS";JOURSEM(A1);1)

 

[Victor21]

Re : 1ère lettre du jour d'une date

Bonsoir, Gérard, Modeste geedee

Salut Patrick©...

Heu... ??? pourquoi pas plus simplement :

=CHOISIR(JOURSEM(A1;2);"L";"M";"M";"J";"V";"S";"D")

Parce que !!​

 

[job75]

Re : 1ère lettre du jour d'une date

Re, salut Modeste geedee,

Une autre formule puisqu'on aime JOURSEM :

=STXT("DLMMJVS";JOURSEM(A1);1)

Mais elle prend 24 octets en mémoire alors que celle de mon post #3 en prend 20...

Edit : j'avions point vu l'Edit de Modeste

Bonne nuit.

 

[Modeste geedee]

Re : 1ère lettre du jour d'une date

Bonsour®
autre formulation ...

=INDEX({"D";"L";"m";"M";"J";"V";"S"};JOURSEM(A1))

 

[Victor21]

Re : 1ère lettre du jour d'une date

Bonjour à tous

Une autre formule puisqu'on aime JOURSEM :

=STXT("DLMMJVS";JOURSEM(A1);1)

Et si on n'aime pas :

=STXT("DLMMJVS";MOD(A1-1;7)+1;1)

 

[job75]

Re : 1ère lettre du jour d'une date

Bonjour à tous,

Modeste, à cause de la matrice ta formule du post #8 "pèse" 59 octets.

Patrick, ta formule du post #9 ne va plus si l'on passe au calendrier 1904.

A+

 

[Modeste geedee]

Re : 1ère lettre du jour d'une date

Bonsour®
pour le fun et autre élucubration...

=CAR(CODE(TEXTE(A1;"jjj"))-32)

 

[urbanito1]

Re : 1ère lettre du jour d'une date

Le forum bonjour,xxaann, job75,modestegedee, victor21
je me permets de m'insérer

ce post m'intéresse, mais comment distinguer M ( mardi ) et M (mercredi) ?

merci

urbanito1

 

[Victor21]

Re : 1ère lettre du jour d'une date

Bonjour, urbanito.

[...]ce post m'intéresse, mais comment distinguer M ( mardi ) et M (mercredi) ?

Le mardi, c'est simple, c'est jour de lessive
Blague à part, par exemple :

=NOMPROPRE(GAUCHE(TEXTE(A1;"jjj");2))

 

[Modeste geedee]

Re : 1ère lettre du jour d'une date

Bonsour®

ce post m'intéresse, mais comment distinguer M ( mardi ) et M (mercredi) ?

m minuscule pour mardi
M majuscule pour Mercredi :

=STXT("DLmMJVS";JOURSEM(A1);1)

 

[Jouxte]

Re : 1ère lettre du jour d'une date

Bonjour le Forum, bonjour à tous,

En principe mardi s'écrit avec "m" et mercredi avec "M".

Bon courage à tous.

JCG