VBA : tableau de variables type

[Zahara]

Bonjour à tous,

pour un programme, je dois définir une donnée personnalisée, on va dire "ville",
ensuite je définis un tableau de ce type de donnés, on va dire "région"

Mais là ou j'ai un problème, c'est que je souhaiterais appeler une procédure utilisant mon tableau, et que ça ne compile pas.

Voici un exemple de code :


type ville
nom as string
code_postal as integer
end type

public region(3) as ville

sub principale()
'blabla pour initialiser "region"
call secondaire(region)
end sub

sub secondaire(byref region)
'blabla
end sub

Voilà, quelqu'un a-t-il une idée?
Merci d'avance!

 

[PMO2]

Re : VBA : tableau de variables type

Bonjour,

Votre variable region étant Public elle est visible par toutes les procédures de votre projet.

EXEMPLE

Type ville
  nom As String
  code_postal As Long 'car Integer limité de -32768 à +32767
End Type

Public region(1 To 3) As ville

Sub principale()
region(1).nom = "Paris"
region(1).code_postal = 75000
region(2).nom = "Marseille"
region(2).code_postal = 13000
region(3).nom = "Lyon"
region(3).code_postal = 69000
  '--- Indice spécifié à partir de cette Sub ---
Call secondaire(3)
  '--- Le ou les indices seront spécifiés ultérieurement à l'intérieur de la Sub appelée ---
Call secondaireBis
End Sub

Sub secondaire(Indice As Long)
MsgBox region(Indice).code_postal & "   " & region(Indice).nom
End Sub

Sub secondaireBis()
Dim i&
For i& = LBound(region) To UBound(region)
  Debug.Print region(i&).code_postal & "   " & region(i&).nom
Next i&
End Sub

Cordialement.

PMO
Patrick Morange