Séparer une chaine de caractère

[maval]

Bonjour,

J'aimerai trouvé un code VBA pour séparer une chaine de caractère de la façon suivante:

De la colonne "A"Le Tignet : 3 124 habitants (2011 : 3099)

vers la colonne "B" Le Tignet et la colonne "C" : 3 124 habitants (2011 : 3099)

Je vous remercie d'avance

Cordialement

Maval

 

[Dull]

Re : Séparer une chaine de caractère

Salut maval, le Forum

je sais que tu as demandé en VBA mais j'insiste sur le fait qu'une formule est souvent plus indiqué
en ColB

=GAUCHE(A2;CHERCHE(":";A2;1)-1)

en ColC

=STXT(A2;CHERCHE(" : ";A2;1);50)

Bonne Journée

 

[maval]

Re : Séparer une chaine de caractère

Bonjour Dull

Je suis sur que tu as raison sur le faite que la formule est souvent plus indiqué que le VBA.
Le problème est que j'ai 95 feuilles avec environ 800 colonnes alors avec le VBA sa vas beaucoup plus vite

Merci et très WE

Maval

 

[Dull]

Re : Séparer une chaine de caractère

Re,

tout dépends de ce que tu appelle rapidité

regarde le fichier joint je me suis arrêté à 5672 lignes
sélectionne B2:C2
place ton curseur en bas à droite de la cellule C2 juqu'a voir apparaitre une petite croix fine
double click c'est quasi instantané

Bonne Journée

 

[ROGER2327]

Re : Séparer une chaine de caractère

Bonjour à tous

Trois fonctions personnalisées :​

Function toto(x)
    toto = Split(x, ":", 2)
End Function

Function tutu(x)
Dim tmp
    tmp = Split(x, ":", 2)
    If UBound(tmp) < 1 Then tmp = Array("", "")
    tutu = tmp
End Function

Function tata(x)
Dim tmp
    tmp = Split(x, ":", 2)
    If UBound(tmp) > 0 Then tmp(1) = " :" & tmp(1) Else tmp = Array("", "")
    tata = tmp
End Function

ROGER2327
#6151

Dimanche 8 Tatane 139 (Susception du Croc à Merdre - fête Suprême Seconde)
3 Thermidor An CCXX, 3,5010h - melon
2012-W29-6T08:24:09Z

 

[maval]

Re : Séparer une chaine de caractère

Re,

A oui, la je dit RESPECT il n'y a pas de doute je vais appliqué cela.

Je te remercie beaucoup

Bon WE

Maval

 

[ROGER2327]

Re : Séparer une chaine de caractère

Suite...

Pour traiter la colonne A en une passe, voir l'onglet Feuil2.​

Sub gaga()
Dim i&, Plg As Range, s(), Tmp
    Set Plg = Range(Cells(2, 1), Cells(Rows.Count, 1).End(xlUp))
    ReDim s(1 To Plg.Count, 1)
    For i = 1 To Plg.Count
        Tmp = Split(Plg(i), ":", 2)
        s(i, 0) = Tmp(0)
        s(i, 1) = Tmp(1)
    Next
    Plg.Offset(0, 1).Resize(, 2).Value = s
End Sub

Private Sub CommandButton1_Click()
    gaga
End Sub

ROGER2327
#6152

Dimanche 8 Tatane 139 (Susception du Croc à Merdre - fête Suprême Seconde)
3 Thermidor An CCXX, 3,8544h - melon
2012-W29-6T09:15:02Z

 

[Staple1600]

Re : Séparer une chaine de caractère

Bonjour à tous


Une solution VBAisée d'une solution manuelle qui mixe Données/Convertir et concaténation par formule
(brute de décoffrage en direct de l'enregisteur de macros)

Sub Macro1()
' Macro enregistrée le 21/07/2012 par Staple1600
'Bien sûr faire les adaptations nécessaires pour les plages de données
'ici j'avais mis des données de  test en A1:A26
    Selection.TextToColumns Destination:=Range("D1"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, _
        Semicolon:=False, Comma:=False, Space:=False, Other:=True, OtherChar _
        :="(", FieldInfo:=Array(Array(1, 1), Array(2, 1)), TrailingMinusNumbers:=True
    Range("D1:D26").Select
    Selection.TextToColumns Destination:=Range("B1"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, _
        Semicolon:=False, Comma:=False, Space:=False, Other:=True, OtherChar _
        :=":", FieldInfo:=Array(Array(1, 1), Array(2, 1)), TrailingMinusNumbers:=True
    Range("D1").FormulaR1C1 = "=RC[-1]&"" (""&RC[1]"
  Range("D1").AutoFill Destination:=Range("D1:D26")
    Range("D1:D26").Select
    Selection.Copy
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Columns("C:C").Select
    Application.CutCopyMode = False
    Selection.Delete Shift:=xlToLeft
    Columns("D:D").Select
    Selection.Delete Shift:=xlToLeft
End Sub

 

[maval]

Re : Séparer une chaine de caractère

Bonjour Roger2327, Staple1600

Je remercie infiniment et vous souhaite un bon WE

Maval