RÉSOLU] Double clic cellule A2

[un internaute]

Bonjour le forum
Dans ThisWorkbook jai cette macro

Private Sub Workbook_Open()
 Dim Sh As Worksheet
 Dim An%
 An = Year(Date)
 For Each Sh In ThisWorkbook.Worksheets
  With Sh
   If .Name <> "Retraites " & An Then .Visible = xlSheetVeryHidden
  End With
Range("A1").Select
 Next
End Sub

Dans un module j'ai cette macro

Sub AfficherOnglets()
Application.ScreenUpdating = False
Dim Onglets As Worksheet
   For Each Onglets In Worksheets
    Onglets.Visible = True
  Next Onglets
Application.ScreenUpdating = True
End Sub

Je voudrais afficher masquer toutes les feuilles par un doubleclic sur cellule A2
Et aussi faire apparaître que l'année en cours (2019) à l'enregistrement
Merci à vous

 

[fanfan38]

Bonjour
Un fichier est toujours le bienvenu...
Faire un clic droit sur l'onglet de la feuille concernée
choisir visualiser le code
copier coller la macro ci dessous...
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Row <> 2 Then Exit Sub
If Target.Column <> 1 Then Exit Sub
Application.ScreenUpdating = False
Dim i As Integer
For i = 1 To Sheets.Count
If Sheets(i).Name <> CStr(Year(Date)) Then
Select Case Sheets(i).Visible
Case Is = False
Sheets(i).Visible = True
Case Is = True
Sheets(i).Visible = False
End Select
End If
Next
Application.ScreenUpdating = True
End Sub

A+ François

 

[un internaute]

Bojour fanfan 38
Ça bloque sur cette ligne

Sheets(i).Visible = False

Cordialement

 

[fanfan38]

Pas chez moi d'ou la nécessité d'un fichier...
comment s'appelle ta feuille?
Et aussi faire apparaître que l'année en cours (2019) à l'enregistrement ?

A+ François

 

[un internaute]

j'ai 2 feuilles Retraites 2018 et Retraites 2019
Oui lorsque j'enregistre je veux que l'année en cours apparaisse.
Je suis sous EXCEL 2003
Merci
Bien à toi

 

[fanfan38]

Voilà pourquoi il y a une erreur...
ci joint nouvelle macro à mettre sur la feuille Retraites 2019

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Row <> 2 Then Exit Sub
If Target.Column <> 1 Then Exit Sub
Application.ScreenUpdating = False
Dim i As Integer, nomfeuille As String
nomfeuille = ActiveSheet.Name
For i = 1 To Sheets.Count
If Sheets(i).Name <> nomfeuille Then
Select Case Sheets(i).Visible
Case Is = False
Sheets(i).Visible = True
Case Is = True
Sheets(i).Visible = False
End Select
End If
Next
Application.ScreenUpdating = True
End Sub

A+ François

 

[un internaute]

Nickel fanfan 38
Un grand merci à toi
Bonne journée

 

[job75]

Bonjour un internaute, fanfan38,

Avec ces macros dans le ThisWorkbook du fichier joint :

Private Sub Workbook_Open()
MasqueSauf "Retraites " & Year(Date) 'nom adaptable
End Sub

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
If Target.Address <> "$A$2" Then Exit Sub
Cancel = True
For Each Sh In Sheets
    If Sh.Visible <> xlSheetVisible Then Affiche: Exit Sub
Next
MasqueSauf "Retraites " & Year(Date) 'nom adaptable
End Sub

Sub MasqueSauf(nom$)
Dim Sh As Object
On Error Resume Next
If IsError(Sheets(nom)) Then MsgBox "Créez la feuille '" & nom & "' !", 48: Affiche: Exit Sub
For Each Sh In Sheets
    If Sh.Name <> nom Then Sh.Visible = xlSheetHidden
Next
End Sub

Sub Affiche()
Dim Sh As Object
For Each Sh In Sheets
    Sh.Visible = xlSheetVisible
Next
End Sub

Bonne journée.

 

[un internaute]

Bonjour [U]job75[/U]
Au moment où j'ai enlevé [RÉSOLU) j'ai reçu ton post
Eh! oui ça n'enregistrais pas à annee en cours et il fallait cliquer sur une autre cellule pour pouvoir recliquer sur A2.
Là tout fonctionne à merveille
Ce matin j'étais un peu pressé (comme tout retraité) et je ne l'avais pas vu
Merci à

 

[un internaute]

Bonjour job75
Pas d'inquiètude tout fonctionne bien
J'ai eu le temps de regarder un peu plus près
Moi j'ai une macro intitulée NouvelleAnnee dans un module standard
Peut-on "l'insérer" dans ce que tu as fait?
Si trop de "casse" on en reste là
Bien cordialement

 

[job75]

Bonjour un internaute, le forum,

J'ai répondu à ceci :

Je voudrais afficher masquer toutes les feuilles par un doubleclic sur cellule A2

Si vous voulez autre chose dites-le clairement et joignez votre fichier.

Bonne journée.

 

[un internaute]

bonjour job75
Pas d'inquiètude tout fonctionne à merveille
C'était seulement si on pouvait utiliser ma macro dans fichier joint
Cordialement

 

[job75]

Rien n'empêche d'utiliser la macro NouvelleAnnee, elle fait autre chose, c'est tout.

 

[un internaute]

Re [U]job75[/U]
Ok Merci
Bon WE à toi et au forum
Cordialement