Publipostage depuis Excel

[RENAUDER]

Bonjour,

Je souhaite effectuer un publipostage à partir d'Excel.
Tout se passe bien sauf qu'à chaque fois, j'ai la boîte de dialogue de Word intitulée Sélectionnez le tableau et là je dois choisir ma plage de données pour la fusion et pourtant dans mon code, j'ai précisé la plage de données avec Connection:="Plage"

Sub Mailing()
    Dim AppWord As Word.Application
    Set AppWord = New Word.Application
    AppWord.Visible = True
    AppWord.Documents.Open "C:\Excel\Castagnola\OF_Semaine A.doc"
    With AppWord.ActiveDocument.MailMerge
        .MainDocumentType = wdCatalog
        .OpenDataSource Name:="C:\Excel\Castagnola\BdD_semaine2.xls", _
                        ReadOnly:=True, _
                        Connection:="Plage"
    End With
    With ActiveDocument.MailMerge
        .Destination = wdSendToNewDocument
        .SuppressBlankLines = True
        .Execute
    End With
End Sub

 

[RENAUDER]

Re : Publipostage depuis Excel

Bonjour,
Ne cherchez plus, j'ai trouvé une solution

 

[Staple1600]

Re : Publipostage depuis Excel

Bonjour



Et quelle est-elle s'il te plait?


Merci pour nous autres.

 

[RENAUDER]

Re : Publipostage depuis Excel

Bonjour,
Voici ce que j'ai trouvé.

Sub OuvreOFSemaineB()
    ' Mise à jour du fichier de données Excel
    Workbooks.Open Filename:="d:\E-62\Gantt\BdD_semaine2.xls"
    Application.AskToUpdateLinks = False
    ActiveWorkbook.Close savechanges:=True
    ' Ouverture du document Word
    Dim AppWord As Word.Application
    Set AppWord = New Word.Application
    AppWord.Visible = True
    Set DocWord = AppWord.Documents.Open("C:\Excel\Castagnola\OF_Semaine B.doc")
    NomBase = "C:\Excel\Castagnola\BdD_semaine2.xls"
    With DocWord.MailMerge
        'Ouvre la base de données
        .OpenDataSource Name:=NomBase, _
            Connection:="Driver={Microsoft Excel Driver (*.xls)};" & "DBQ=" & _
            NomBase & "; ReadOnly=True;", SQLStatement:="SELECT * FROM [Feuil1$]"
        'Spécifie la fusion vers l'imprimante
        .Destination = wdSendToNewDocument    ' wdSendToPrinter
        .SuppressBlankLines = True
        'Prend en compte l'ensemble des enregistrements
        With .DataSource
            .FirstRecord = wdDefaultFirstRecord
            .LastRecord = wdDefaultLastRecord
        End With
        'Exécute l'opération de publipostage
        .Execute Pause:=False
    End With
End Sub