petite question d'un novice

[jerome]

Bonjour,

Je reviens vers vous les spécialistes excel pour la seconde fois. Votre première aide m'ayant permis de gagner beaucoup de temps. Je reviens vers vous pour une questioon qui me parait plus simple mais mon niveau n'est même pas suffisant pour y répondre:


2 B 0 1 2 1 1 1 B



Voici ci dessus la représentation d'une ligne excel (composé de 9 colonnes successives) avec 3 types (uniquement) de valeur alphanumérique (0,1,2) et le B signifiant un champ vierge non rempli (qui doit être considéré différent de 0).


Je voudrais calculer au bout de la ligne (via la zone de formule):

dans une première colonne:
compter le nombre de fois où on rencontre un 0 1 ou 2 sur la ligne (c a d qu'il faut compter le nombre de colonne moins le nombre de champs "Blanc"
dans le cas ci dessus le resultat de la ligne devrait donc être 7

Dans une deuxième colonne (presque la même question), compter le nombre de fois où on rencontre 1 ou 2 (ne pas compter le 0 cette fois ci). dans le cas ci dessus le resultat serait donc: 6



Merci par avance pour votre aide.


Bon courage à tous !!!

 

[Abel]

Bonjour jérome,

Pour le nb de val valeurs différentes de B :
=NB.SI(B5:J5;"<>B")

Pour le nb de 1 et de 2 :
=NB.SI(B5:J5;"=1")+NB.SI(B5:J5;"=2")
Il doit même y avoir moyen de faire plus court pour cette dernière (avec un OU quelque part, sans doute).

En espérant que cela te dépanne.

Abel

 

[JCA06]

Bonjour Jérome, Abel, le Forum,

Je fais mes premiers essais avec la fonction SOMMEPROD :

=+SOMMEPROD((A2:I2=0)*1+(A2:I2=1)*1+(A2:I2=2)*1)

Voici le principe : VRAI = 1, donc, si les cellules de A2 à I2 prennent successivement les valeurs suivantes en réponse à la condition =0 :
Valeurs 2 B 0 1 2 1 1 1 B
Test = 0 : 0 0 1 0 0 0 0 0 0, ce qui multiplié par 1 donne 1
Test = 1 : 0 0 0 1 0 1 1 1 0, ce qui multiplié par 1 donne 4
Test = 2 : 1 0 0 0 1 0 0 0 0, ce qui multiplié par 1 donne 2
Soit au total 7

Merci à Monique !

 

[Abel]

Arrgh !

C'est vrai que c'est costaud ce machin là.

Faudrait que je m'y mette aussi un jour.

Abel

 

[Monique]

Bonjour,

Au choix, du plus long au plus court.
Question 1 :
=SOMMEPROD(((A2:I2=0)+(A2:I2=1)+(A2:I2=2))*(A2:I2<>""))
=SOMMEPROD((A2:I2={0;1;2})*(A2:I2<>""))
=SOMMEPROD((A2:I2<3)*(A2:I2<>""))
=SOMMEPROD((ESTNUM(A2:I2))*1)
Question 2 :
=SOMMEPROD(((A2:I2=1)+(A2:I2=2))*(A2:I2<>""))
=SOMMEPROD((A2:I2<3)*(A2:I2>0)*(A2:I2<>""))
=SOMMEPROD((ESTNUM(A2:I2))-(A2:I2=0))
=SOMMEPROD((A2:I2={1;2})*(A2:I2<>""))

 

[chris]

Bonjour
Autre variantes :
1er cas
=NBVAL(A1:I1)

2ème cas
=SOMME(SI(A2:I2>0;1;0))
formule matricielle à valider par ctrl shift entrée

ou bien
=NBVAL(A3:I3)-NB.SI(A3:I3;0)

en formule standard

Chris

 

[jerome]

Merci à tous!!!

en moins d'une journée je croule sous les réponses et je n'ai que l'embarras du choix!!!


Juste une petite question subsdidiaire: est on strictement limité en nombre de colonne (256)? (et ligne pendant que j'y suis!!)

Sinon je vois pas trop comment je vais m'en sortir!!!


Est ce qu'un simpe rajouter colonne ou ligne fonctionne où y a t'il d'autres manip possible!!!
Y a t'il une limite?


Merci par avance

 

[@+Thierry]

Bonjour Jerome, Chris, Monique, JCA, Abel, le Forum

Pour ta dernière question, non Jérome, la limite d'une Feuille Excel est de 256 Colonnes sur 65536 Lignes.

Les Alternatives consistent soit à inverser ton tableau (si il y a moins de 256 lignes of course), soit à utiliser plusieurs feuilles, soit à concaténer certaines colonnes pour gagner de la place. (Concaténation de données que l'on peut évidemment récupérer soit dans des Formules soit par VBA)

Mais il est évident que celà complique pas mal les choses.

Bon Courage
@+Thierry

 

[jerome]

Merci Thierry et bonjour (j'allais oublier ;-)),

Ca me donne déjà les directions possibles. C'est quand même bizarre qu'on restreigne un tel logiciel à une limitation de colonne. il aurait même été plus logique d'avoir un "carré", enfin bon!!! Je peux peut être m'en tirer avec l'inversion des lignes et colonnes. Peux tu me dire si on peut faire ça en 100% automatique sans rien avoir à retoucher car j'ai déjà rentrer un travail conséquent (sur plus de 256 colonnes donc!!) et si je peux éviter de me refaire un max de manuel !!!


Merci par avance!!! et bon WE à tous!!

 

[jerome]

INVERSER LIGNE ET COLONNE

Bonjour,

Je suis géné par la délimitation à 256 colonnes. Je peux peut être m'en sortir en inversant lignes et colonnes. J'ai déjà énormément de chose dans mes tableaux (beaucoup plus que 256 malheureusement ;-) et voudrait faire la manip avec un max d'automatisation et avec le moins de retouche possible. Quel est le moyen le plus simple? je ne trouve pas de fonction directe mais comme je suis un novice à côté de tous les spécialistes que j'ai le plaisir de lire ici, j'ai surement raté qqc!!!


Merci à un ooeil averti de m'aider!!!

a+