Moyenne par mois

[stef2cr]

Bonjour,

Je voudrais faire une moyenne des dépenses de tous les mois de l'année en cours.

Je mets comme formule:
=MOYENNE(C5;E5;G5;I5;K5;M5;O5;Q5;S5;U5;W5;Y5)

Les cellules correspondent au mois de l'année. Le problème est que je n'ai pas de résultat pour les mois à venir, donc ma moyenne est fausse.

Difficile à expliquer alors, je vous joins le fichier.

Merci d'avance de votre aide.

 

[Tibo]

Re : Moyenne par mois

Bonjour,

Un essai avec une formule matricielle :

=MOYENNE(SI((MOD(COLONNE(B5:Y5);2)=1)*(B5:Y5<>0);B5:Y5))

Formule matricielle à valider par CTRL + MAJ + ENTREE

@+

 

[stef2cr]

Re : Moyenne par mois

Merci pour la réponse rapide. Je ne connais pas "matricielle" je vais regarder de plus près.

 

[Excel-lent]

Re : Moyenne par mois

Bonjour Stef2cr,

Ta formule MOYENNE est juste et fonctionne à la perfection.

La partie erronée sont tes formules ligne 5
En D5 remplacer la formule :

=(E5-C5)/C5

par la formule ci-dessous :

=SI(E5="";"";(E5-C5)/C5)

En E5 remplacer la formule :

=SOMME(E6:E10)

par la formule ci-dessous :

=SI(SOMME(E6:E10)=0;"";SOMME(E6:E10))

Fait de même (un simple "copier/coller" fonctionne) avec toutes les autres formules de la ligne 5 et tu verras que ta formule MOYENNE fonctionnera (et cela sans avoir à la modifier ).

Bonne soirée

Edition : Bonjour Tibo. Excuse, je ne t'avais pas vu. Tant pis, cela fera deux solutions pour Stef2cr. Ainsi il n'aura que l'embarras du choix.

 

[stef2cr]

Re : Moyenne par mois

Merci,
J'ai adapté la deuxième méthode.
Je cherche à comprendre la méthode matricielle.

Merci à vous 2
Comme d'habitude rapide et efficace ce forum.

 

[Excel-lent]

Re : Moyenne par mois

Bonsoir stef2cr,

De rien.

Une façon comme une autre de faire un petit "up", pour que Tibo voit se message et te réponde.

Je préfère le laisser expliquer sa formule.

Bonne fin de soirée

 

[Tibo]

Re : Moyenne par mois

Salut Excel-lent,

Alors, reprenons :

=MOYENNE(SI((MOD(COLONNE(B5:Y5);2)=1)*(B5:Y5<>0);B5:Y5))

D'après la disposition du tableau, les montants à prendre en compte sont situés dans des cellules dont la colonne est de rang impair.

Ces cellules sont repérées grâce à cette partie de la formule :

(MOD(COLONNE(B5:Y5);2)=1)

Ensuite, pour le calcul de la moyenne, il ne faut pas prendre en compte les cellules égales à 0.

Ces cellules sont repérées grâce à cette partie de la formule :

(B5:Y5<>0)

En multipliant ces deux matrices, Excel va générer une matrice de 0 et de 1

Appliquée à la plage de cellules B5:Y5, et associée à la fonction MOYENNE, Excel ne va prendre en compte que les cellules répondant aux deux critères.

Il faut simplement valider par CTRL + MAJ + ENTREE pour que Excel sache qu'il s'agit d'une formule matricielle.

Voilou pour la tentative d'explication

@+