macro recherche/écrit

[titine06]

Salut tout le monde,
je suis nouvelle sur ce forum, et je viens vous demander de l'aide car pour la première fois, je doit faire une macro accomplire une tache.

Je vous énnonce mon problème:

J'ai 2 feuilles.

J'aimerai que lorsque j'appui sur le bouton de la feuille 1, les informations rentrées sur le tableau aille s'inscrire sur la feuille 2 en fonction de la date inscrite (ligne) et en fonction du nom inscrit (collonne)

A savoir que: dans mon fichier complet,
-il y a une infinité (quand meme pas mais presque ) de nom dans la feuille 2 (tranche de collonne)
-il y a une infinité (ou presque ) de date (en ligne) dans la fueille 2.

Est ce que vous pouriez m'aider? ou il faut que je détail plus? ou que je fasse petit à petit?

Je vous dit merci d'avance!

 

[Minick]

Re : macro recherche/écrit

Salut,

Place ce code dans un module et lance le sur le clique de ton bouton

Option Explicit

Sub ALOPouet()
    Dim CptLigSrc As Integer, LigDst As Integer
    Dim ColInitDst As Byte
    Dim Rech As Variant
    
    For CptLigSrc = 2 To Sheets("ALO").Range("D1").End(xlDown).Row
        Set Rech = Sheets("Pouet").Rows(1).Find(what:=Sheets("ALO").Range("E" & CptLigSrc).Value, LookIn:=xlValues, lookat:=xlWhole)
        If Not Rech Is Nothing Then
            ColInitDst = Rech.Column - 3
            
            Set Rech = Sheets("Pouet").Columns(1).Find(what:=Sheets("ALO").Range("D" & CptLigSrc).Value, LookIn:=xlFormulas, lookat:=xlWhole)
            If Not Rech Is Nothing Then
                LigDst = Rech.Row
                Sheets("Pouet").Cells(LigDst, ColInitDst).Value = Sheets("ALO").Range("F" & CptLigSrc).Value
                Sheets("Pouet").Cells(LigDst, ColInitDst + 1).Value = Sheets("ALO").Range("G" & CptLigSrc).Value
                Sheets("Pouet").Cells(LigDst, ColInitDst + 2).Value = Sheets("ALO").Range("H" & CptLigSrc).Value
                Sheets("Pouet").Cells(LigDst, ColInitDst + 3).Value = Sheets("ALO").Range("I" & CptLigSrc).Value
                Sheets("Pouet").Cells(LigDst, ColInitDst + 5).Value = Sheets("ALO").Range("J" & CptLigSrc).Value
                Sheets("Pouet").Cells(LigDst, ColInitDst + 6).Value = Sheets("ALO").Range("K" & CptLigSrc).Value
            End If
        End If
    Next CptLigSrc
End Sub

++
Minick

 

[titine06]

Re : macro recherche/écrit

Salut Minick,

c'est vraiment génial ce code, en plus je peux remplacer des valeurs précédemment rentrée. Et c'est plutôt clair j'arrive un peu à la comprendre, je le réutiliserai souvent!


je te remercie !! en plus si vite !

à bientot ! et bonne soirée!!