macro creation fichier Txt automatiquement

[popeckjunior]

Bonjour,

me revoici après plusieurs moi d'abscence.je n'ai pas reussi à trouver l'info ds le forum, à chaquue fois il y avez un truc pour que je n'y arrive pas.

mon retour est lié au fait que j'ai un petit probleme sous excel.

j'ai un fichier avec pas mal de macro… l'une d'elle est la création d'un "menu" dans la bare d'outil de excel( tres intéréssant) cf fichier excel
=> au meme niveau que fichier/Edition affichage etc...

toutefois il a un probleme car je ne semble pas avoir pris l'enssemble de la macro…. Desole ...je vais essaayer de donner un produit fini pour les "archives" du forum
mon probleme est en faits que je souhaite créer dans ce menu un bouton afin de me permettre de cree automatiquement un fichier en format Txt (separateur : Tabulation)
la feuille excel à prendre en compte (serait dans la mesure du possible une feuille caché).
Ainsi, le fichier txt créer de facon automatique se placerai au meme endroi que le fichier excel.

j'aurais besoin d'un autre petit coups de main mais chaque chose à la fois...

Je vous remerci encore de votre aide, j'aspere avoir été assez claire dans me propos, en esperant que se poste servira à d'autre personne

bonne soirree

 

[kjin]

Re : macro creation fichier Txt automatiquement

Bonjour,
Le code de ton message #8

Sep = " "

insère un espace entre chaque donnée et non une tabulation, on est d'accord, mais jusqu'ici, je n'ai pas utilisé ce code
Dans le fichier joint, 2 méthodes
- enregistrement direct en txt avec tabulations, comme déjà proposé

Sub EnregistreTxt()
Dim rep As String, fich As String
rep = ActiveWorkbook.Path & "\"
fich = "Txt_Direct"
    ActiveSheet.Copy
    ActiveWorkbook.SaveAs rep & fich & ".txt", xlText, False
    Application.DisplayAlerts = False
    ActiveWorkbook.Close
    Application.DisplayAlerts = True
End Sub

- écriture des données une à une dans un fichier txt séparées par une tabulation

Sub ExportTxtVtab()
Dim c As Range, i As Long, j As Long, chaine As String
Set c = ActiveSheet.Cells.SpecialCells(xlCellTypeLastCell)
Open ActiveWorkbook.Path & "\Txt_vbTab.txt" For Output As #1
For i = 1 To c.Row
    For j = 1 To c.Column
        chaine = chaine & Cells(i, j) & vbTab
    Next
    chaine = Left(chaine, Len(chaine) - 1)
    Print #1, chaine
    chaine = ""
Next
Close #1
End Sub

Je ne vois aucune différence, mais bon
A+
kjin

 

[popeckjunior]

Re : macro creation fichier Txt automatiquement

Bonjour forum

le fichier que tu as mis sur le forum fonxctionne...

SUPER , MERCI encore

toutefois je dois etre sur la feuille pour effectuer la macro

je souhaite masquer la feuille excel, et lancer la macro à partir d'une autre feuille.

peux tu modifier la macro?

cela serai parfais

merci encore de t'être penché sur mon probleme

Merci Forum!!!!

 

[kjin]

Re : macro creation fichier Txt automatiquement

Bonjour,
Le fichier oui, mais qelle(s) macro(s) ?!

Sub EnregistreTxt()
Dim rep As String, fich As String
rep = ActiveWorkbook.Path & "\"
fich = "Txt_Direct"
With Sheets("[COLOR="Blue"]F2[/COLOR]") 'remplace F2 par le nom de la feuille
    .Visible = True
    .Copy
    ActiveWorkbook.SaveAs rep & fich & ".txt", xlText, False
    Application.DisplayAlerts = False
    ActiveWorkbook.Close
    .Visible = xlVeryHidden
End With
Application.DisplayAlerts = True

End Sub

Sub ExportTxtVtab()
Dim c As Range, i As Long, j As Long, chaine As String
With Sheets("[COLOR="Blue"]F2[/COLOR]") 'remplace F2 par le nom de la feuille
    .Visible = True
    Set c = .Cells.SpecialCells(xlCellTypeLastCell)
    Open ActiveWorkbook.Path & "\Txt_vbTab.txt" For Output As #1
    For i = 1 To c.Row
        For j = 1 To c.Column
            chaine = chaine & .Cells(i, j) & vbTab
        Next
        chaine = Left(chaine, Len(chaine) - 1)
        Print #1, chaine
        chaine = ""
    Next
    Close #1
    .Visible = xlVeryHidden
End With

End Sub

A+
kjin

 

[popeckjunior]

Re : macro creation fichier Txt automatiquement

slt

desoler je n'avez pas preciser

en faits les deux fonctionnés
je viens de faire un teste est semble que cela fonctionne impec

merci encore de t'être pecher sur mon probleme

il me reste à resoudre d'autre petit probleme mais cela est l'occasion de creer un autre poste

merci encore de t'être pencher sur mon probleme

Nana