[formule] somme de 2 colonnes sur 4

[Hervé]

bonjour les copains

je cherche a faire la somme de 2 colonnes sur 4. c'est à dire la somme des colonnes "ab"+"ef"+"ij"+"mn" etc...

cette formule =SOMMEPROD((MOD(COLONNE(A1:H1)-1;2)=0)*1;A1:H1)

permet d'additionner une colonne sur deux, comment la modifier ?

merci

a plus

 

[david84]

Re : [formule] somme de 2 colonnes sur 4

Bonjour,
peut-être comme ceci :

=SOMMEPROD((MOD(COLONNE(A1:H1)-1;4)=0)*1;A1:H1)+SOMMEPROD((MOD(COLONNE(A1:H1)-1;4)=1)*1;A1:H1)

ou :

=SOMMEPROD((MOD(COLONNE(A1:H1)-1;4)=0)*1+(MOD(COLONNE(A1:H1)-1;4)=1)*1;A1:H1)

A+

 

[job75]

Re : [formule] somme de 2 colonnes sur 4

Bonjour Hervé, david84,

Ou aussi :

=SOMMEPROD((MOD(COLONNE(A1:Y1)-1;4)=0)*(A1:Y1+B1:Z1))

Edit : et mieux :

=SOMMEPROD((MOD(COLONNE(A1:Y1);4)=[COLOR="Red"]1[/COLOR])*(A1:Y1+B1:Z1))

A+

 

[job75]

Re : [formule] somme de 2 colonnes sur 4

Re,

Une formule meilleure car elle utilise un peu moins d'octets en mémoire :

=SOMMEPROD((MOD(COLONNE(A1:Z1);4)=LIGNE(1:2))*A1:Z1)

Noter que le membre de gauche est une matrice à 2 dimensions : 26 x 2.

A+

 

[david84]

Re : [formule] somme de 2 colonnes sur 4

Re,

Une formule meilleure car elle utilise un peu moins d'octets en mémoire :

Code:

=SOMMEPROD((MOD(COLONNE(A1:Z1);4)=LIGNE(1:2))*A1:Z1)

Bien vu Job !
Question : sur quoi te base-tu pour dire cela ? Est-ce par pure logique ou t'appuies-tu sur des éléments plus tangibles ?
Je te pose la question parce que je sais que dans le cadre du VBA, on peut utiliser notamment le timer pour calculer la vitesse d'exécution d'une macro et je ne sais pas si cela (ou une autre possibilité) peut-être utilisé dans le cadre des formules natives d'Xl pour évaluer leur vitesse, espace mémoire,...
Ayant remarqué que tu navigues allègrement du VBA aux formules, cela m'intéressait d'avoir ton avis sur la question🙂.
A+

 

[job75]

Re : [formule] somme de 2 colonnes sur 4

Bonjour le fil, le forum,

On ne trouve pas toujours tout de suite 😱 la solution la plus simple :

=SOMMEPROD((MOD(COLONNE(A1:Z1)-1;4)[COLOR="Red"]<2[/COLOR])*A1:Z1)

Le -1 était une bonne idée Hervé 🙂

@ David : vois ce fil pour le nombre d'octets d'une formule :

https://www.excel-downloads.com/threads/nombre-doctets-memoire-dune-expression.129833/

Ceci dit la formule du post #4 est peut-être plus lente à exécuter que celle du post #3 car il y a d'avantage d'opérations (multiplications).

A+

 

[david84]

Re : [formule] somme de 2 colonnes sur 4

Re,
merci Job car c'est intéressant comme outil🙂.
Bon, si j'ai bien compris, tu notes la taille du fichier avant l'application d'une formule et sa taille après et tu vois la différence.
Si tu dois comparer plusieurs formules, tu le fais entre chaque nouvelle formule.
Si c'est bien cela🙄, n'y a-t-il pas moyen par macro qu'il te l'indique à ta demande ? Reste ensuite à faire la soustraction entre la dernière taille indiquée (correspondant à la dernière formule testée) et celle d'avant (soit l'avant-dernière formule testée, soit le poids initial si c'est la 1ère formule testée)?
On pourrait peut-être imaginer une macro utilisable dans n'importe quel classeur ouvert sur l'ordi que l'on pourrait utiliser pour tester des formules à proposer dans le cadre du site ou pour son utilisation perso.
Qu'en dis-tu et est-ce faisable ?
A+

 

[job75]

Re : [formule] somme de 2 colonnes sur 4

Re David,

Bon, si j'ai bien compris, tu notes la taille du fichier avant l'application d'une formule et sa taille après et tu vois la différence.

Non car le poids d'un fichier varie seulement par sauts de 512 ko.

En fait je calcule à la main le nombre d'octets, car je connais le nombre d'octets utilisés par les opérateurs, fonctions, etc... (voir le fil).

On peut aussi utiliser le fichier du fil, je l'ai déposé pour ça...

Peut-être qu'une macro pourrait faire ce travail, je n'ai pas essayé car pas évident.

A+

 

[david84]

Re : [formule] somme de 2 colonnes sur 4

Re,

Envoyé par david84 Voir le message
Bon, si j'ai bien compris, tu notes la taille du fichier avant l'application d'une formule et sa taille après et tu vois la différence.
Non car le poids d'un fichier varie seulement par sauts de 512 ko.

On peut aussi utiliser le fichier du fil, je l'ai déposé pour ça...

Je parlais en l'occurrence du fichier du fil mais c'est bien que tu me précises à nouveau le fait que le poids d'un fichier ne varie que par saut de 512 ko.
Bon par macro, je ne peux t'aider alors dommage car je pense que cela pourrait nous être bien utile.
A+

 

[Hervé]

Re : [formule] somme de 2 colonnes sur 4

coucou

merci beaucoup pour les formules et la discution

lien tres interressant, la chasse aux octets dans les formules, je ne connaissais pas ceci.

il est vrai que maintenant vu nos micros, ce n'est plus une de nos préoccupations principales, alors qu'il n'y a qu'une 15 aine d'années, c'etait presque obligatoire.

a plus

 

[Hervé]

Re : [formule] somme de 2 colonnes sur 4

re

job,

Le -1 était une bonne idée Hervé 🙂

tu penses bien que cette formule n'est pas de moi 🙂, je l'ai piqué à tibo je crois ou peut etre à monique (enfin un de mes deux maitres)

a plus