[FORMULE] Dénombrer/sommer les chiffres d'un nombre (cherche simplication formules)

[Staple1600]

Bonsoir à tous

Toujours dans mes histoires de chiffres et de nombres (séquelle de Kaprékar 😉)

Je cherche à simplifier les formules de la pièce jointe

(ou à découvrir vos approches "formulistique" novatrices )

pour dénombrer les chiffres impairs et pairs composant un nombre

(formule matricielles ou pas)

exemple:
44357

2 nombres pairs , somme des pairs : 8
3 nombres impairs, somme des impairs : 15

Merci à vous qui passerez dans ce fil.

PS: bien entendu, si des vbaistes veulent se joindre au formulistes, j'en serai ravi.

 

[Tibo]

Re : [FORMULE] Dénombrer/sommer les chiffres d'un nombre (cherche simplication formul

Bonsoir,

Pas mieux :

somme des chiffres :

=SOMMEPROD((STXT($A$2;LIGNE(INDIRECT("1:"&NBCAR($A$2)));1))*1)

somme des chiffres pairs :

=SOMMEPROD((EST.PAIR(STXT($A$2;LIGNE(INDIRECT("1:"&NBCAR($A$2)));1))*1)
*STXT($A$2;LIGNE(INDIRECT("1:"&NBCAR($A$2)));1))

somme des chiffres impairs :

=SOMMEPROD((EST.IMPAIR(STXT($A$2;LIGNE(INDIRECT("1:"&NBCAR($A$2)));1))*1)
*STXT($A$2;LIGNE(INDIRECT("1:"&NBCAR($A$2)));1))*1

nombre de chiffres pairs :

=SOMMEPROD((EST.PAIR(STXT($A$2;LIGNE(INDIRECT("1:"&NBCAR($A$2)));1))*1))

nombre de chiffres impairs :

=SOMMEPROD((EST.IMPAIR(STXT($A$2;LIGNE(INDIRECT("1:"&NBCAR($A$2)));1))*1))

Ne nécessite pas la validation matricielle grâce à SOMMEPROD

Formules un peu plus longues ou un peu plus courtes

Testé sur Excel 2007. Je ne sais plus (pour les versions antérieures) si les fonctions EST.PAIR et EST.IMPAIR font partie des fonctions nécessitant une macro complémentaire.

@+

 

[Staple1600]

Re : [FORMULE] Dénombrer/sommer les chiffres d'un nombre (cherche simplication formul

Bonsoir Tibo

Merci de passer par ici

Je vais tester de ce pas tes formules.


Au plaisir de te croiser au détour d'un fil.

PS: EDITION

Ces deux formules ne fonctionnent pas chez moi (Excel 2000)

nombre de chiffres pairs :
Code: =SOMMEPROD((EST.PAIR(STXT($A$2;LIGNE(INDIRECT("1:"&NBCAR($A$2)));1))*1))
nombre de chiffres impairs :
Code: =SOMMEPROD((EST.IMPAIR(STXT($A$2;LIGNE(INDIRECT("1:"&NBCAR($A$2)));1))*1))
.

(j'ai bien activé au préalable l'utilitaire d'analyse)

elles renvoient toujours 1

 

[ROGER2327]

Re : [FORMULE] Dénombrer/sommer les chiffres d'un nombre (cherche simplication formul

Bonsoir à tous

Pas mieux moi non plus...
Si on veut se passer de EST.PAIR ou EST.IMPAIR et du SI :

[COLOR="DarkSlateGray"][B]=SOMMEPROD(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1)*MOD(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1);2))
=SOMMEPROD(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1)*(1-MOD(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1);2)))[/B][/COLOR]

Je n'arrive pas à imaginer une autre approche.​

ROGER2327
#2922

 

[Staple1600]

Re : [FORMULE] Dénombrer/sommer les chiffres d'un nombre (cherche simplication formul

Bonsoir ROGER2327


Merci pour votre participation.

Je continue à chercher d'autres pistes d'approche.