Extraire initial prénom composé

[Jacko57]

Bonjour 🙂

Pour faire un tableau excell qui servira ensuite en publipostage a créer des utilisateurs sur un serveur je recherche la bonne formule qui pourra m'afficher dans une cellule l'initial de prénom j'ai cette formule pour des prénom simple =GAUCHE(B2) mais je trouve pas pour les prénoms composés 😎

explication : PRENOMS INITIALE

Jean j

Jean Jacques jj

aussi Jean-Jacques jj


Merci de me répondre si vous connaissez la formule

@++

Jacko 😀

 

[Tibo]

Re : Extraire initial prénom composé

Bonjour,

Une première réponse par formule :

=SI(ESTNUM(TROUVE(" ";SUBSTITUE(A1;"-";" ")));GAUCHE(A1)&
STXT(SUBSTITUE(A1;"-";" ");TROUVE(" ";SUBSTITUE(A1;"-";" "))+1;1);
GAUCHE(A1))

Consiste à déterminer si le prénom est composé. Si oui, on remplace le - (s'il y en a un) par un espace et on recherche ensuite la position de l'espace.

Je te laisse essayer

Bonne soirée

@+

 

[mécano41]

Re : Extraire initial prénom composé

Bonjour,

Il y a aussi cela qui va bien. Tu peux ajouter &"." avant & STXT... si tu veux un point entre les deux initiales

=GAUCHE(B2;1) & STXT(B2;SI(NON(ESTERREUR(TROUVE(" ";B2)));TROUVE(" ";B2);SI(NON(ESTERREUR(TROUVE("-";B2)));TROUVE("-";B2);"ce n'est pas composé"))+1;1)

Cordialement

 

[Tibo]

Re : Extraire initial prénom composé

re,

Retour avec une formule un peu plus courte :

=SUPPRESPACE(GAUCHE(SUBSTITUE(A1;"-";" "))&STXT(SUBSTITUE(
A1;"-";" ")&"  ";TROUVE(" ";SUBSTITUE(A1;"-";" ")&"  ")+1;1))

Si on part du principe que tous les prénoms composés sont séparés par un espace, celle-ci, plus courte :

=SUPPRESPACE(GAUCHE(A1)&STXT(A1&"  ";TROUVE(" ";A1&"  ")+1;1))

@+

 

[mécano41]

Re : Extraire initial prénom composé

Attention, ce que j'ai donné ne fonctionne pas si le prénom n'est pas composé. Je l'avais fait en plusieurs formules qui fonctionnaient et que j'ai regroupées... On pourrait la modifier mais cela devient trop long donc...pas intéressant.

Désolé !

 

[Jacko57]

Re : Extraire initial prénom composé

Super je viens de tester la formule ça marche impeccable 🙂

re,

Retour avec une formule un peu plus courte :

=SUPPRESPACE(GAUCHE(SUBSTITUE(A1;"-";" "))&STXT(SUBSTITUE(
A1;"-";" ")&"  ";TROUVE(" ";SUBSTITUE(A1;"-";" ")&"  ")+1;1))

Merci pour la rapidité je pensais pas avoir une réponse aussi vite

Mais une question comment trouvez vous toutes les infos pour pouvoir sortir des formules aussi complexe ? 😱

un grand Merci a tous en tous cas

@++

Jacko