double clique sur 1 celllule change la couleur de plusieurs cellules

[noon]

bonjour a tous

je voudrais en un double clique sur 1 cellule que celle ci change de couleur et quand je redouble clique dessus elle redevienne blanche
donc si je double clique sur "a2" elle devient verte mais la cellule d'à coté aussi soit la "a1" et la "a3" doivent devenir verte
et en recliquant sur "a2" elles redeviennent sans couleur

alors j'ai ces 2 codes mais qui me font pas exactement ce que je veux

le 1er: celui je n'arrive pas a mettre de la couleur sur les cellule d'à coté

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Excel.Range, Cancel As Boolean)
If Not Application.Intersect(Target, Range("A1:J21")) Is Nothing Then
With Target
If Selection.Interior.ColorIndex = 50 Then
Selection.Interior.ColorIndex = xlNone
Else
Selection.Interior.ColorIndex = 50
End If
End With
End If
End Sub

la 2eme
celui est pas mal mais je n'arrive pas a ce que les cellules redeviennent sans couleur

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Column = 2 Then
Cells(Target.Row, 2).Interior.ColorIndex = 4
Cells(Target.Row, 1).Interior.ColorIndex = 4
Cells(Target.Row, 3).Interior.ColorIndex = 4
End If
End Sub

bref j'ai besoin de vos aides
merci

 

[JCGL]

Re : double clique sur 1 celllule change la couleur de plusieurs cellules

Bonjour à tous,

Peux-tu essayer ceci :

Option Explicit

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Target.Column = 2 Then
        If Cells(Target.Row, 2).Interior.ColorIndex = 4 Then
            Union(Cells(Target.Row, 2), Cells(Target.Row, 1), Cells(Target.Row, 3)).Interior.ColorIndex = xlNone
        Else
            Union(Cells(Target.Row, 2), Cells(Target.Row, 1), Cells(Target.Row, 3)).Interior.ColorIndex = 4
        End If
    End If
End Sub

A + à tous

 

[Dull]

Re : double clique sur 1 celllule change la couleur de plusieurs cellules

Salot noon, le Forum

Peut-être comme cela

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Column = 2 Then
Cancel = True
For i = 1 To 3
    Cells(Target.Row, i).Interior.ColorIndex = IIf(Cells(Target.Row, i).Interior.ColorIndex = 4, xlNone, 4)
Next i
End If
End Sub

EDITION: Salut mon JC, Content de te croiser à nouveau

Bonne Journée

 

[JCGL]

Re : double clique sur 1 celllule change la couleur de plusieurs cellules

Bonjour à tous,

Pour le plaisir de croiser de nouveau mon Didier

Option Explicit


Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Target.Column = 2 Then
            Union(Cells(Target.Row, 2), Cells(Target.Row, 1), Cells(Target.Row, 3)).Interior.ColorIndex = IIf(Cells(Target.Row, 2).Interior.ColorIndex = 4, xlNone, 4)
    End If
End Sub

A+++ l'ami
A + à tous

 

[noon]

Re : double clique sur 1 celllule change la couleur de plusieurs cellules

bonjour
jcgl et dull

j'ai essayé vos 2 versions et ça marche super bien

merci a tous les 2

à bientôt pour d'autre aides qui me sont indispensables