decompte de jours mois année entre deux date

[306255]

Bonjour a tous,


est il possible de faire un décompte comme dans l exemple joint etre deux date pour connaitre le nombre de jours, mois et années qui sépare deux dates

merci d'avance

 

[Victor21]

Re : decompte de jours mois année entre deux date

Bonjour.

à conditon que l'utilitaire d'analyse soit coché, essayez :

=DATEDIF($C5;$E5;"Y")&" ans "&DATEDIF($C5;$E5;"YM")&" mois et "&DATEDIF($C5;$E5;"MD")&" jours"

 

[Philippe68]

Re : decompte de jours mois année entre deux date

Bonjour,

voir fichier

 

[karakoman1]

Re : decompte de jours mois année entre deux date

Bonjour à tous
=DATEDIF(C5;E5;"Y")&SI(DATEDIF(C5;E5;"Y")>1;" ans, ";" an, ")&DATEDIF(C5;E5;"YM") &" mois et "&DATEDIF(C5;E5;"MD")&SI(DATEDIF(C5;E5;"MD")>1;" jours";" jour")

Avec celle là, même si il y a plusieurs années, "an" prend un "s"

A+

 

[Philippe68]

Re : decompte de jours mois année entre deux date

Bonjour,

Dans la copie que j'ai envoyé, c'est déjà au pluriel

 

[karakoman1]

Re : decompte de jours mois année entre deux date

Bonjour Phillipe68
J'ai bien vu, mais une "1 années" ne prend pas un "s" 🙄
A+

 

[Philippe68]

Re : decompte de jours mois année entre deux date

ok, mais vu les 2 dates au départ, il y aura forcément plusieurs années à l'arrivée 😎

 

[Victor21]

Re : decompte de jours mois année entre deux date

Re,

Puisqu'on pinaille :

=SI(DATEDIF(C7;E7;"y")=0;"";DATEDIF(C7;E7;"Y")&SI(DATEDIF(C7;E7;"Y")>1;" ans, ";" an, "))&SI(DATEDIF(C7;E7;"YM")=0;"";DATEDIF(C7;E7;"YM") &" mois ")&SI(DATEDIF(C7;E7;"MD")=0;"";"et "&DATEDIF(C7;E7;"MD")&SI(DATEDIF(C7;E7;"MD")>1;" jours";" jour"))

N'affiche les ans, les mois et les jours que s'il y en a 🙂

 

[karakoman1]

Re : decompte de jours mois année entre deux date

Salut Victor21
Là, je replie mon drapeau et déclare forfait.
Tu mets tout le monde d'accord sur ton dernier coup. 🙂
Bonne journée et au plaisir

 

[karakoman1]

Re : decompte de jours mois année entre deux date

Re, Victor21
Rien que pour te "titiller", 😛 j'ai quand même trouvé un petit bug.
Quand il n'y a que des jours de différence, il affiche le: "et" 1 jour. Et toc!!
Mais je suis sûr que tu as déja la parade. 🙂
A+

 

[Victor21]

Re : decompte de jours mois année entre deux date

Re, re...

Oubliez, la formule transmise par Dull, quejesaluebienbas est parfaite🙂

 

[Dull]

Re : decompte de jours mois année entre deux date

Salut le fil

Pour le fun mais sans "et" et sans ","
Une formule de C@thy 🙂 si je ne m'abuse

=SI(C7="";"";SI(ET(DATEDIF(C7;E7;"y")=0;DATEDIF(C7;E7;"ym")=0;DATEDIF(C7;E7;"md")=0);0&" jour";SI(DATEDIF(C7;E7;"y")<>0;DATEDIF(C7;E7;"y")&SI(DATEDIF(C7;E7;"y")>1;" ans ";" an ");"")&SI(DATEDIF(C7;E7;"ym")<>0;DATEDIF(C7;E7;"ym")&" mois ";"")&SI(DATEDIF(C7;E7;"md")<>0;DATEDIF(C7;E7;"md")&SI(DATEDIF(C7;E7;"md")>1;" jours";" jour");"")))

Edit: Re Patrick 🙂 à la même seconde 😀
Bonne Journée

 

[Philippe68]

Re : decompte de jours mois année entre deux date

Re, salut Pat et Dull 😎

oui enfin, une bible de code qui fait 50kms de long pour avoir : "29 ans" au lieu de "29 années" avec un petit code 😛
nan je vous taquine les gars, no prob.

enfin si l'auteur de ce fil ne trouve pas son compte dans toutes ces réponses, je me fais moine mdrrr

 

[Staple1600]

Re : decompte de jours mois année entre deux date

Bonjour à tous


Pour infos:
DATEDIF a parfois quelque soucis de comportements
(Voir les fils sur XLD traitant de la chose)