Date dans Textbox

[peresseromain]

Bonjour à tous,

Pouvons nous mettre dans une textbox des slash "/" pour éviter de les tapers à chaque saisie. Ex:__/__/____ Pour chaque textbox voulu.

Si oui comment on fait le prgramme et ou je le rentre sachant que j'ai 70 textbox.

Merci d'avance

Je cherche depuis trois jours help me please🙁

 

[PascalXLD]

Re : Date dans Textbox

Bonjour

Voici un code récupéré sur ce forum mais il y a tellement de temps
Je l'ai recopié d'un vieux fichier
le "Tb_AccDateDeb" c'était le nom de mon textbox

Private Sub Tb_AccDateDeb_Change()

If Len(Me.Tb_AccDateDeb.Value) = 3 Then
    If Right(Me.Tb_AccDateDeb.Value, 1) <> "/" Then
        Me.Tb_AccDateDeb.Value = Left(Me.Tb_AccDateDeb.Value, 2) & "/" & Right(Me.Tb_AccDateDeb.Value, Len(Me.Tb_AccDateDeb.Value) - 2)
    End If
ElseIf Len(Me.Tb_AccDateDeb.Value) = 6 Then
    If Right(Me.Tb_AccDateDeb.Value, 1) <> "/" Then
        Me.Tb_AccDateDeb.Value = Left(Me.Tb_AccDateDeb.Value, 5) & "/" & Right(Me.Tb_AccDateDeb.Value, Len(Me.Tb_AccDateDeb.Value) - 5)
    End If
End If

End Sub

 

[degap05]

Re : Date dans Textbox

Bonjour,

J'utilise ce code (du forum):
Private Sub TextBox4_Change()
If Len(TextBox4) = 2 Or Len(TextBox4) = 5 Then TextBox4 = TextBox4 & "/"
End Sub

pour une TextBox4, à adapter.

A+

 

[PascalXLD]

Re : Date dans Textbox

Re

En effet c'est une version simplifiée

Perso je l'avais modifié au cas où des personnes par habitude tapent les "/" sans le faire exprès cela evitait d'avoir 29//01//2010

 

[degap05]

Re : Date dans Textbox

Re

En effet c'est une version simplifiée

Perso je l'avais modifié au cas où des personnes par habitude tapent les "/" sans le faire exprès cela evitait d'avoir 29//01//2010

Bonjour,

Dans cette version, il n'est pas possible d'ajouter un ou plusieurs "/".
Par contre, si l'on s'est trompé, arrivé après la frappe de l'année et que l'on veut revenir en arrière, il n'est possible d'effacer que l'année.
Peut-être une amélioration à apporter pour pouvoir tout effacer et recommencer ?
A+

 

[bqtr]

Re : Date dans Textbox

Bonjour à tous,

Avec ces deux codes, on peut revenir en arrière pour corriger une erreur et seule la saisie de chiffre est autorisée.

Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
  If InStr("0123456789", Chr(KeyAscii)) = 0 Then KeyAscii = 0
End Sub



Private Sub TextBox1_Change()

Dim Chaine
TextBox1.MaxLength = 10
Chaine = Replace(TextBox1.Value, "/", "")
If Len(Chaine) > 2 Then Chaine = Left(Chaine, 2) & "/" & Right(Chaine, Len(Chaine) - 2)
If Len(Chaine) > 5 Then Chaine = Left(Chaine, 5) & "/" & Right(Chaine, Len(Chaine) - 5)
TextBox1.Value = Chaine

End Sub

Maintenant si tu as 70 TB à remplir je pense qu'un module de classe serait le plus approprié. Les évènements KeyPress et Changes sont possible.


A+

 

[peresseromain]

Re : Date dans Textbox

Bonjour a tous,

Merci sa marche du tonnere.

Vraiment super ce forum. 🙂

Encore merci et a bientôt

Cordialement

PERESSE Romain