Copie de feuille sans les caracteristiques Private Sub

[christ-94]

Bonjour

le problème

Je veux faire une copie d’une feuille Excel dans un nouveau classeur mais en gardant le mise en page.
Mais qu'en je copie la feuille j’ai aussi la copie des Private Sub de la feuille copier
Existe t’il un moyen pour évite de copie l’intelligence de la feuille copier.

Merci d'avance

 

[MichelXld]

Re : Copie de feuille sans les caracteristiques Private Sub

bonjour

Tu peux utiliser cet exemple pour copier une feuille d'un classeur et supprimer tout le code que contient ce nouveau classeur

'nécessite d'activer la référence
'Microsoft Visual Basic for Applications Extensibility 5.3.
Dim VbComp As VBComponent
 
'Copie une feuille dans un nouveau classeur
ThisWorkbook.Worksheets("Feuil1").Copy
 
For Each VbComp In ActiveWorkbook.VBProject.VBComponents
    With VbComp.CodeModule
        .DeleteLines 1, .CountOfLines
    End With
Next VbComp

Bonne soirée
MichelXld

 

[christ-94]

Re : Copie de feuille sans les caracteristiques Private Sub

Bonjour

Fonctionne nickel 🙂

par contre est t'il possible de charge le module complémentaire a l'ouverture du classeur "Microsoft Visual Basic for Applications Extensibility 5.3" par une routine en vba ou de s'assure qu'il soit bien chargé


Merci d'avance

 

[Spitnolan08]

Re : Copie de feuille sans les caracteristiques Private Sub

Bonjour Christ94, Michel,

Le code suivant te permet de cocher cette référence à l'ouverture du classeur

Private Sub WorkBook_Open()
'***Référence Microsoft Visual Basic for Applications Extensibility 5.3.
Dim X As String, Y As String
Dim compo As Object

Y = "VBIDE" '***Nom de la référence
X = "C:\Program Files\Fichiers communs\Microsoft Shared\VBA\VBA6\VBE6EXT.OLB"  '***Chemin d'accès de la référence
'***Décoche la référence si elle est déjà cochée
For Each compo In ThisWorkbook.VBProject.References
    If compo.Name = Y Then ThisWorkbook.VBProject.References.Remove compo
Next
'***Coche la référence
ThisWorkbook.VBProject.References.AddFromFile X
End Sub

Cordialement

 

[christ-94]

Re : Copie de feuille sans les caracteristiques Private Sub

Super, l'ensemble des deux macros est une idylle 😀



Merci a vous deux