Compter le nombre de valeur "texte" différente d'une plage de cellule "texte"

[SPKF]

Bonjour,

Je cherche à compter le nombre de clients différents que ceux qui reviennent ponctuellement. Pour cela j’utilise deux feuilles distinctes.

La première feuille (Feuille 1), contient dans la colonne A, la liste des clients ponctuel.
[Colonne A]
Client AAA
Client AAB
Client AAC
Client AAD

La seconde feuille (Feuille 2), la liste de tous les clients (client ponctuel, occasionnel et parfois, la cellule reste vide)
[Colonne A]
Client AAA
Client ZZZ
« vide »
Client XYZ

Ce que je cherche à faire, c’est de compter les clients occasionnel et cellule vide (ceux qui ne figure pas dans la colonne A de la feuille1)

Auriez vous une idée ?

Merci d'avance

 

[job75]

Re : Compter le nombre de valeur "texte" différente d'une plage de cellule "texte"

Bonjour SPKF,

On supposera qu'il n'y a pas de titre en colonne A de Feuil2.

1) Définir (menu Insertion-Nom) le nom Plage avec la formule :

=DECALER(Feuil2!$A$1;;;EQUIV("zzz";Feuil2!$A:$A))

2) Le nombre de clients occasionnels et de cellules vides dans Plage est donné par :

=SOMMEPROD(--(NB.SI(Feuil1!A:A;Plage)=0))

3) Le nombre de cellules vides dans Plage est donné par :

=NB.VIDE(Plage)

4) Donc le nombre de clients occasionnels par :

=SOMMEPROD(--(NB.SI(Feuil1!A:A;Plage)=0))-NB.VIDE(Plage)

Edition : s'il y a un titre en A1, définir Plage avec la formule :

=DECALER(Feuil2!$A$2;;;EQUIV("zzz";Feuil2!$A:$A)-1)

A+

 

[CISCO]

Re : Compter le nombre de valeur "texte" différente d'une plage de cellule "texte"

Bonsoir

Bonjour,

.....

La première feuille (Feuille 1), contient dans la colonne A, la liste des clients ponctuels.
[Colonne A]
Client AAA
Client AAB
Client AAC
Client AAD

La seconde feuille (Feuille 2), la liste de tous les clients (client ponctuel, occasionnel et parfois, la cellule reste vide)
[Colonne A]
Client AAA
Client ZZZ
« vide »
Client XYZ


Merci d'avance

Si il y a vraiment tous les clients dans la seconde liste (ce qui n'est pas le cas dans ton exemple), il suffit de faire la différence avec NBVAL.

@ plus

 

[job75]

Re : Compter le nombre de valeur "texte" différente d'une plage de cellule "texte"

Bonjour SPKF, salut CISCO,

Tu as tout à fait raison CISCO, si la 2ème liste comprend tous les clients, le problème est sans grand intérêt.

J'ai supposé que ce n'était pas le cas.

Mais on peut compliquer en supposant qu'il y a des doublons dans la 2ème liste.

Dans ce cas le nombre de clients occasionnels est donné par :

=SOMME(SI(NON(NB.SI(Feuil1!A:A;Plage))*ESTTEXTE(Plage);1/NB.SI(Plage;Plage)))

C'est une formule matricielle, à valider par Ctrl+Maj+Entrée.

A+