Microsoft 365 activation de la dernière feuille créée selon son n° (pas sa position)

[Usine à gaz]

Bonjour à toutes et à tous,

J'ai besoin de pouvoir activer la dernière feuille créée dans mon classeur
Par exemple ici j'ai créé les Feuile1 à 6

le code "Sheets(Sheets.Count).Select" fonctionne

mais active la dernière Feuille selon sa position dans le classeur
alors que c'est la dernière créé soit la Feuil6 que je souhaite activer.

Malgré mes recherches et essais, je n'ai pas trouvé comment coder.
Pourriez-vous m'aider sachant que mes feuilles sont créées depuis longtemps et donc antérieurement au code que vous m'aurez (je l'espère LOL) transmis.
Je joins un fichier test.

Avec mes remerciement,
Je vous souhaite à toutes et à tous une belle journée,
amicalement,
lionel,

 

[Usine à gaz]

Re-Patrick,

Je vais regarder et je te dirai
lionel,

 

[eriiic]

Bonjour à tous,

comme ce n'est que la dernière qui t'intéresse, autant ne stoker que celle-ci dans un nom :

Private Sub Workbook_NewSheet(ByVal Sh As Object)
    ThisWorkbook.Names.Add Name:="derniere", RefersTo:=Sh.Name
End Sub

Sub test()
    Sheets([derniere]).Activate
End Sub

ou stocker le codename si le nom peut être amené à être modifié.
eric

 

[Usine à gaz]

Bonsoir Eric,

Merci d'êtes là toi aussi

Mais ton code ne va pas fonctionner.
Normal car j'aurais du mieux expliquer :
Le fichier dans lequel la code va être utilisé est un fichier de facturation.
Il y a une feuille "matrice" nommée "Facture"
- les infos par client sont saisie dans cette feuille dans laquelle il y a un bouton pour facturer.
- Quand je clique sur le bouton, une nouvelle feuille est créée et est renommée au nom du client concerné
et ainsi de suite pour tous les clients,

Donc la feuille ne s'appelle plus "dernière" ou "Feuil1" mais du nom client client concerné.
lionel,

 

[ChTi160]

bonsoir lionel
Bonsoir le Fil,le Forum
ne peux tu creer ce nom lors de la procedure qui nomme la nouvelle feuille？
ThisWorkbook.Names.Add Name:="derniere", RefersTo:= NomFeuille
non teste
ne faut il pas effacer les .Names , crees precedemment？
jean marie

 

[eriiic]

Oui, tu connais le nom du client à la création de la feuille, c'est ce nom qui doit être mémorisé en plus de l'attribuer à la feuille.
Si vraiment c'est impossible à ce moment il faut mémoriser son codename et boucler sur toutes les feuilles pour le retrouver.

ne faut il pas effacer les .Names , crees precedemment？

J'avais testé, le nouveau écrase l'ancien

 

[mapomme]

Bonsoir @arthour973, @Roblochon, @patricktoulon, @job75, @ChTi160, @eriiiic,

Une tentative de mapomme:

• dans le module de code de ThisWorkbook, Il y a une procédure évènementielle Workbook_NewSheet(...) qui s'exécute à la création d'une nouvelle feuille
• dans le module mod_PlusRecent, il y a une procédure afficherPlusRecente(...) qui affiche la feuille créée le plus récemment

Normalement (à contrôler) :

• l'ordre des feuilles peut être modifié
• les noms des feuilles peuvent être modifiés
• les codename peuvent être modifiés
• les feuilles peuvent être supprimées
• s'il ne reste que les feuilles présentes à la création du classeur, alors on affiche la feuille la plus à droite

Merci de bien vouloir le tester et de trouver les erreurs (en général, les autres trouvent l'erreur la plus grosse et la plus évidente qui puisse exister)

code de Workbook_NewSheet :

Private Sub Workbook_NewSheet(ByVal Sh As Object)
Dim xsh, i&, max&, DerCodeName
   'parcours de tous les item "indice" de chaque feuille de calcul
   'pour déterminer le max des indices et la feuille associée
   'l'item indice est le premier (item numéro 1)
   On Error Resume Next
   For Each xsh In ThisWorkbook.Worksheets
      If LCase(xsh.Name) <> xsh.Name Then
         i = 0: i = CLng(xsh.CustomProperties.Item(1))
         If i > max Then max = i
      End If
   Next xsh
   On Error GoTo 0
   'on ajoute dans CustomProperties de la nouvelle feuille le mouveau max
   Sh.CustomProperties.Add "indice", (max + 1)
End Sub

Code de afficherPlusRecente(...):

Sub afficherPlusRecente()
Dim xsh, i&, max&, leNom$
   'parcours de tous les item "indice" de chaque feuille de calcul
   'pour déterminer le max des indices et la feuille associée
   'l'item indice est le premier (item numéro 1)
   On Error Resume Next
   For Each xsh In ThisWorkbook.Worksheets
      i = 0: i = CLng(xsh.CustomProperties.Item(1))
      If i > max Then
         max = i
         leNom = xsh.Name
      End If
   Next xsh
   'Si leNom est vide, on active la dernière feuille du classeur
   'sinon on affiche la dernière feuille créée
   If leNom = "" Then
      ThisWorkbook.Worksheets(ThisWorkbook.Worksheets.Count).Select
   Else
      ThisWorkbook.Worksheets(leNom).Select
   End If
End Sub

 

[patricktoulon]

re
la je dit respect
c'est invisible et ça fonctionne même avec des suppressions intermédiaire
je n'y avais pas penser au customproperties

voila une vrai solution +++

 

[Usine à gaz]

Bonjour Gérard,
Bonjour Patrick,
Bonjour Eric,
Bonjour Jean-Marie,
Bonjour Roblochon ... Le Forum,

@mapomme
Merci pour ce code effectivement super génial
Je viens de tester avec le fichier que tu as joint et j'y ai vu, me semble-t-il ,un souci "mineur" et non gênant pour moi.
Je vais tester plus avant dans mon fichier de travail et je reviendrai pour te le dire.
Encore merci à toi
lionel,

 

[mapomme]

Re,

Je viens de tester avec le fichier que tu as joint et j'y ai vu, me semble-t-il ,un souci "mineur" et non gênant pour moi

Et par curiosité, puis je connaître ce souci "mineur" et non gênant pour toi ?

 

[Staple1600]

Bonjour le fil

mapomme
Moi, j'en vois un de majeur de souci (non pas dans ton code) mais sur un autre plan que j'évoquerais en MP
ultérieurement, une fois que j'aurais fini de griller mes tartines et "torréfier" mes graines.
Ceci dit bravo pour ce bel ouvrage VBAistique

 

[patricktoulon]

Bonjour a tous

cette fonction n'existant pas je vois la une fonction in/out a faire

peut être avec property get/let

ou simplement avec une fonction et l'argument optionel

if ismissing( argument ) then
récupération du custompropertie.item(x)
else
création de la customproperties (add)
end if

 

[Usine à gaz]

Bonjour JM,

Pas de souci pour te parler en MP

 

[patricktoulon]

re

bon j'ai testé avec properties get /let ca fonctionne correctement

dans le module thisworkbook

Private Sub Workbook_NewSheet(ByVal Sh As Object)
LastCreatedSheet = Sh
End Sub

dans un module standard

Property Let LastCreatedSheet(Sh)
    Dim xsh, i&, max&, DerCodeName
    'parcours de tous les item "indice" de chaque feuille de calcul
    'pour déterminer le max des indices et la feuille associée
    'l'item indice est le premier (item numéro 1)
    On Error Resume Next
    For Each xsh In ThisWorkbook.Worksheets
        If LCase(xsh.Name) <> xsh.Name Then
            i = 0: i = CLng(xsh.CustomProperties.Item(1))
            If i > max Then max = i
        End If
    Next xsh
    On Error GoTo 0
    'on ajoute dans CustomProperties de la nouvelle feuille le nouveau max
    Sh.CustomProperties.Add "indice", (max + 1)
End Property

Property Get LastCreatedSheet()
    Dim xsh, i&, max&, leNom$
    'parcours de tous les item "indice" de chaque feuille de calcul
    'pour déterminer le max des indices et la feuille associée
    'l'item indice est le premier (item numéro 1)
    On Error Resume Next
    For Each xsh In ThisWorkbook.Worksheets
        i = 0: i = CLng(xsh.CustomProperties.Item(1))
        If i > max Then
            max = i
            leNom = xsh.Name
        End If
    Next xsh
    Set LastCreatedSheet = Sheets(leNom)
End Property

sub de test

Sub test2()
    MsgBox LastCreatedSheet.Name
End Sub

chapo stapple160

quand je pense que pour une incrementation invisible ex:facture,etc ce principe est parfait j'ai honte des procédés que j'utilise

 

[Usine à gaz]

Bonjour Patrick,

Bravo pour ce boulot mais ce dont j'ai besoin, ce n'est pas d'un msgbox mais qu'il active la dernière feuille créée
lionel,

 

[Usine à gaz]

LOL JM, tu as raison, je suis allé trop vite
lionel,