Moyenne sur des valeurs auquelles on affecte des coefficients différents

[SEB60OISE]

Bonjour,
je voudrais effectuer une moyenne sur 4 valeurs mais en leur affectant des coefficients différents :
en E3 je voudrais la moyenne de A3 à D3 en mettant
- coefficient 2 pour A3 mais je voudrais qu'elle soit considérée comme négative
- coefficient 1 pour B3 mais je voudrais qu'elle soit considérée comme négative
- coefficient 1 pour C3 mais je voudrais qu'elle soit considérée comme positive
- coefficient 2 pour D3 mais je voudrais qu'elle soit considérée comme positive

 

[ROGER2327]

Bonjour md0100, bonjour à tous.

Ceci

=SIERREUR(SI(($C3+$D3*2-$A3*2-$B3)/SOMME($A3:$D3)=0;
             ($C3+$D3*2-$A3*2-$B3)/SOMME($A3:$D3)&" = à 0";
          SI(($C3+$D3*2-$A3*2-$B3)/SOMME($A3:$D3)>0;
             ($C3+$D3*2-$A3*2-$B3)/SOMME($A3:$D3)&" sup à 0";
          SI(($C3+$D3*2-$A3*2-$B3)/SOMME($A3:$D3)>1;
             ($C3+$D3*2-$A3*2-$B3)/SOMME($A3:$D3)&" sup à 1";
      SI((ET(($C3+$D3*2-$A3*2-$B3)/SOMME($A3:$D3)<=0;($C3+$D3*2-$A3*2-$B3)/SOMME($A3:$D3)>=-1));
             ($C3+$D3*2-$A3*2-$B3)/SOMME($A3:$D3)&" inf à 0";
             ($C3+$D3*2-$A3*2-$B3)/SOMME($A3:$D3)&" inf à 1"))));
"Vide")

est fort long. Il me semble que

=SIERREUR((D3*2+C3-B3-A3*2)/SOMME(A3:D3)&" "&
       SI((D3*2+C3-B3-A3*2)=0;               "égal à 0";
       SI((D3*2+C3-B3-A3*2)/SOMME(A3:D3)>0;  "sup. à 0";
       SI((D3*2+C3-B3-A3*2)/SOMME(A3:D3)>=-1;"sup. à -1 et inf à 0";
                                             "inf. à -1")));
"Vide")

devrait faire l'affaire.

Sans les espaces mises pour faciliter la lecture, on a

=SIERREUR((D2*2+C2-B2-A2*2)/SOMME(A2:D2)&" "&SI((D2*2+C2-B2-A2*2)=0;"égal à 0";SI((D2*2+C2-B2-A2*2)/SOMME(A2:D2)>0;  "sup. à 0";SI((D2*2+C2-B2-A2*2)/SOMME(A2:D2)>=-1;"sup. à -1 et inf à 0";"inf. à -1")));"Vide")

Bonne journée.


ℝOGER2327
#8349

Jeudi 26 Absolu 144 (Saint Joseb, notaire à la mode de Bretagne - fête Suprême Quarte)
12 Vendémiaire An CCXXV, 0,2752h - immortelle
2016-W40-1T00:39:38Z

 

[mdo100]

Bonjour ROGER2327, toutes et tous,

Effectivement, c'est beaucoup plus court.

Dans ce cas supprimer les $"Référence absolue" par colonne est pertinent.
Puis décomposer la formule et la mettre à la ligne dans la "barre des formules" dans un premier temps permet d'y voir plus clair et donc de pouvoir, voir les simplifications a effectuer.

Je retiens cette astuce pour une prochaine fois.

Bonne journée.
Cordialement.

 

[ROGER2327]

Suite...

... pour une autre formule, plus légère :​

=SIERREUR((D3*2+C3-B3-A3*2)/SOMME(A3:D3)&" "&
CHOISIR(1-SOMME(-((D3*2+C3-B3-A3*2)/SOMME(A3:D3)<{-1.0.0,00000001}));
"sup. à 0";"égal à 0";"sup. à -1 et inf à 0";"inf. à -1");SI(NB(A3:D3);"calcul impossible";""))

Bonne soirée.​

ℝOGER2327
#8350

Jeudi 26 Absolu 144 (Saint Joseb, notaire à la mode de Bretagne - fête Suprême Quarte)
12 Vendémiaire An CCXXV, 6,4449h - immortelle
2016-W40-1T15:28:04Z

 

[mdo100]

Re ROGER2327,

La dernière partie de ta formule ne fonctionne pas.

SI(NB(A3:D3);"calcul impossible"

Je me suis permis de rectifier par:

SI(NB(A3:D3)=0;"calcul impossible"

Mais merci pour cette autre variante.

Cordialement

 

[ROGER2327]

Re mdo100,

Re ROGER2327,

La dernière partie de ta formule ne fonctionne pas.

SI(NB(A3:D3);"calcul impossible"

(...)

Si. Elle fait ce que je veux qu'elle fasse.​

(...)
Je me suis permis de rectifier par:

SI(NB(A3:D3)=0;"calcul impossible"

(...)

Dites plutôt «modifier» que «rectifier» car la formule modifiée ne fait plus la même chose que la formule initiale. Voyez le classeur joint.​

Bonne soirée.


ℝOGER2327
#8351

Jeudi 26 Absolu 144 (Saint Joseb, notaire à la mode de Bretagne - fête Suprême Quarte)
12 Vendémiaire An CCXXV, 8,0534h - immortelle
2016-W40-1T19:19:41Z

 

[mdo100]

Re ℝOGER2327,

Mais je ne discute pas vos très grandes compétences en mathématique, je connais vos pots sur ce forum et bien souvent je n'y comprends rien, mais je sais que vous résolvez souvent des problèmes complexes.
Mon niveau d'Excel ne date que d'un peu plus d'une année, j'apprends seul à 50 ans et sans aide, sauf bien entendu en voyant les solutions des autres contributeurs(trices) dont vous.
Avant j'étais demandeur, aujourd'hui je me permet d'être contributeur.
Bien que j'ai demandé de l'aide pour un problème en VBA, il y a quelques temps de cela, mais que je reste sur ma faim, je n'ais pas eu l'aide souhaitée. Quel dommage.
J'apporte des solutions en tant que contributeur, mais à mon niveau, j'accepte la critique, sans mal les prendre, car elles me permettent d'apprendre encore plus.
Le bon terme est modifié, j'ai employé rectifier, erreur de vocabulaire certainement dû à mon niveau d'étude qui fait parti de la France d'en bas.

En tout cas merci pour vos solutions que je garde sous le coude, elles me serviront pour moi où pour aider quelqu'un d'autre.

Bonne soirée.

Cordialement.

 

[SEB60OISE]

Merci à tous pour votre aide.
Encore une petite question : vos formules à tous sont super mais le calcul en E8 sur la pièce jointe me donne trop de chiffres après la virgule et quand je fais format de le cellule, nombre et que je coche 2 ou 3 ou autre chose dans nombre de décimales ça ne change rien... j'ai toujours -1.458333333333 inf. à -1 il doit se baser seulement sur le -1 je pense. Une idée ?

 

[ROGER2327]

Re...

La formule renvoie du texte et on ne peut pas fixer le nombre de décimales d'un texte ! Il faut faire l'arrondi d'affichage dans la formule. Essayez ceci :

=SIERREUR(ARRONDI((D3*2+C3-B3-A3*2)/SOMME(A3:D3);3)&" "&
CHOISIR(1-SOMME(-((D3*2+C3-B3-A3*2)/SOMME(A3:D3)<{-1.0.0,00000001}));
"sup. à 0";"égal à 0";"sup. à -1 et inf à 0";"inf. à -1");SI(NB(A3:D3);
"calcul impossible";""))

Bonne soirée.


ℝOGER2327
#8353

Samedi 28 Absolu 144 (Xylostomie - Vacuation)
14 Vendémiaire An CCXXV, 7,2078h - réséda
2016-W40-3T17:17:55Z

 

[SEB60OISE]

C'est ce que je voulais.
Merci pour tout.
Bonne soirée