Trouver l'avant dernière valeur d'une colonne en fonction de 2 critères

[JU621]

Bonjour à tous,


J'ai un tableau qui reprend des unités , les leçons afférentes à chaque unité et une note dans une troisième colonne.

Je souhaite voir s'afficher, dans une quatrième colonne, l'avant dernière note pour la même unité et même leçon.

J'ai essayé différentes combinaisons avec " Sommeprod", "Index" et " Equiv" mais sans succès jusqu'à présent.

Pourriez-vous me donner un petit coup de pouce pour trouver cette formule qui me dépasse .....

Merci à vous

 

[R@chid]

Re : Trouver l'avant dernière valeur d'une colonne en fonction de 2 critères

Bonsoir,

si j'ai bien compris :

=INDEX(F$5:F$41;GRANDE.VALEUR(SI(C$5:C$41&D$5:D$41=C5&D5;LIGNE(INDIRECT("1:"&LIGNES(F$5:F$41))));MIN(2;NB.SI.ENS(C$5:C$41;C5;D$5:D$41;D5))))

@ valider par Ctrl+Shift+Enter

@ tirer vers le bas





@ + +

 

[JU621]

Re : Trouver l'avant dernière valeur d'une colonne en fonction de 2 critères

Bonsoir Rachid,

C'est de la formule .... Par contre, en effectuant un tri par date, je remarque des erreurs dans les valeurs sélectionnées.

De plus, il faudrait que la case reste vide si c'est la première note dans la leçon concernée.

Je te joins le fichier pour visualiser.

 

[R@chid]

Re : Trouver l'avant dernière valeur d'une colonne en fonction de 2 critères

Re,
en H5 :

=SIERREUR(INDEX(F$5:F$41;GRANDE.VALEUR(SI(C$5:C$41&D$5:D$41=C5&D5;LIGNE(INDIRECT("1:"&LIGNES(F$5:F$41))));2));"")

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas

j'ai pas constaté d'anomalie en triant.


@ + +

 

[mapomme]

Re : Trouver l'avant dernière valeur d'une colonne en fonction de 2 critères

Bonjour JU621,

Juste pour saluer R@chid , je propose une autre formule matricielle[SUP](*)[/SUP] (plus longue et moche, bien sûr!) :

=SIERREUR(INDEX(F$1:F$41;1/(1/MAX((A$5:A$41=MAX((A$5:A$41<A5)*(C$5:C$41=C5)*(D$5:D$41=D5)* A$5:A$41))*(C$5:C$41=C5)*(D$5:D$41=D5)*LIGNE(A$5:A$41))));"")

[SUP](*)[/SUP] : à valider par Ctrl+Maj+Entrée en H5, puis, à tirer vers le bas.

 

[JU621]

Re : Trouver l'avant dernière valeur d'une colonne en fonction de 2 critères

Bonjour ma pomme,

Excellent, la formule matricielle fonctionne très bien .

Je pense qu'il était nécessaire d'introduire le critère relatif aux dates de saisie.

Merci à toi et également à Rachid pour votre investissement, j'avoue que c'était trop compliqué pour mon niveau .... mais grâce à vous je progresse de jour en jour.

@+ et bon week-end !