Transférer le contenu du commentaire sur une autre colonne

[othal]

bonjour à tous,

je voudrais savoir s'il est possible de récupérer le contenu des commentaires lié à la plage de cellules A2:A35 et de le transférer dans la plage de cellules B1:B35.

ci-joint fichier exemple
merci de votre aide

 

[tototiti2008]

Re : Transférer le contenu du commentaire sur une autre colonne

Bonjour othal,

Je ne peux que te conseiller le site de Boisgontier qui est très complet sur le sujet :

http://boisgontierjacques.free.fr/pages_site/commentaire.htm

ce qui devrait donner dans ton cas

Sub CommentCell()
Dim Cellule As Range
    For Each Cellule In Range("A2:A35")
        If Not Cellule.Comment Is Nothing Then
            Cellule.Offset(0, 1).Value = Cellule.Comment.Text
        End If
    Next Cellule
End Sub

 

[Guest]

Re : Transférer le contenu du commentaire sur une autre colonne

Bonjour,

Sub Dodododo()
Dim c As Range
With Sheets("Exemple")
    For Each c In .Range(.Cells(2, 1), .Cells(.Rows.Count, 1).End(xlUp))
        If Not c.Comment Is Nothing Then c(1, 2) = c.Comment.Text
    Next c
End With
End Sub

A+
[Edit]Hello tototiti, même combat!

 

[Papou-net]

Re : Transférer le contenu du commentaire sur une autre colonne

Bonjour othal, tototiti2008, Hasco,

Ma contribution avec une boucle réduite à sa plus simple expression.

Sub Copie()
For Each cel In Sheets("Exemple").Range("A:A").SpecialCells(xlCellTypeComments)
    cel.Offset(0, 1).Value = cel.Comment.Text
Next
End Sub

Et avec suppression du commentaire en colonne A :

Sub Copie()
For Each cel In Sheets("Exemple").Range("A:A").SpecialCells(xlCellTypeComments)
    cel.Offset(0, 1).Value = cel.Comment.Text
    cel.ClearComments
Next
End Sub

Cordialement.

 

[othal]

Re : Transférer le contenu du commentaire sur une autre colonne

merci de votre aide , le code de tototiti2008 fonctionne parfaitement