XL 2010 Traitement de ligne-Faire correspondre chaque appli à son répertoire sur des lignes différentes

[ALK]

Bonjour tout le monde
je rencontre un problème sur excel .
Les données que j'ai à ma disposition sont sont sous la forme des données feui1 et je voudrais les mettre sous la forme Feuil2
Merci d'avance pour votre aide

 

[job75]

Bonjour ALK, le forum,

Voyez le fichier joint et cette macro dans le code de Feuil2 (clic droit sur l'onglet et Visualiser le code) :

Private Sub Worksheet_Activate()
Dim ncol%, tablo, resu(), i&, j%, n&
With Sheets("Feuil1").[A1].CurrentRegion
    ncol = .Columns.Count
    If ncol = 1 Then ncol = 2
    tablo = .Resize(, ncol) 'matrice, plus rapide
    ReDim resu(1 To .Rows.Count * (ncol - 1), 1 To 2)
End With
For i = 2 To UBound(tablo)
    For j = 2 To ncol
        If tablo(i, j) <> "" Then
            n = n + 1
            resu(n, 1) = tablo(i, 1)
            resu(n, 2) = tablo(i, j)
        End If
Next j, i
'---restitution--
If FilterMode Then ShowAllData 'si la feuille est filtrée
With [A2] 'cellule de destination à adapter
    If n Then .Resize(n, 2) = resu: _
        .Resize(n, 2).Borders.Weight = xlThin 'bordures
    .Offset(n).Resize(Rows.Count - n - .Row + 1, 2).Delete xlUp 'RAZ en dessous
End With
Columns.AutoFit 'ajustement largeurs
With UsedRange: End With 'actualise la barre de défilement verticale
End Sub

La macro se déclenche quand on active la feuille.

A+

 

[pierrejean]

Bonjour ALK

A tester:

 

[ALK]

Bonjour Job75,PierreJean
Quelle efficacité , tous les deux codes marchent
Merci beaucoup pour votre aide