tester si 2 cellules sur une même ligne ont un commentaire identique.

[Chri8Ed]

Bonjour à tous

J’aurai besoin de tester par ligne si 2 cellules (Colonne J à V)
ont un commentaire identique.

Et en l’occurrence comme pour les 2 commentaires avec "Damien" dans mon exemple
Celles-ci s’affichent alors pour m’en alerter
Cela peut être aussi une autre forme d’alerte, ce qui compte c’est que cela se voit.

Il n’a pas de formule pour effectuer ce test
Est-ce qu’une fonction serait capable de le faire ?

Peut-être que quelqu’un à déjà effectuer ce genre de fonction ?

Merci

 

[Theze]

Bonjour,

Une piste avec une fonction perso à mettre dans un module standard :

Function Commentaire(Plage As Range) As String
   
    Dim Cel As Range
    Dim Dico As Object
    Dim Cle As Variant
    Dim Com As Comment
    Dim Texte As String
    Dim Retour As String
   
    Set Dico = CreateObject("Scripting.Dictionary")
   
    For Each Cel In Plage
   
        Set Com = Cel.Comment
       
        If Not Com Is Nothing Then
           
            Texte = Com.Shape.TextFrame.Characters.Text
           
            If Dico.exists(Texte) = False Then Dico.Add Texte, 1 Else Dico(Texte) = Dico(Texte) + 1
           
        End If
       
    Next Cel

    For Each Cle In Dico.Keys
   
        If Dico(Cle) > 1 Then Retour = Retour & Cle & "|"
       
    Next Cle
   
    If Retour <> "" Then Retour = Left(Retour, Len(Retour) - 1)
   
    Commentaire = Retour
   
End Function

Tu peux appeler cette fonction dans la feuille de calcul de cette façon :

=Commentaire(J6:V6)

si il y a plusieurs paires de commentaires les noms seront séparés par une barre verticale.

 

[Chri8Ed]

Bonsoir Theze
Merci beaucoup
C'est exactement ce qu'il me fallait
Super
A+