Tester qu'une cellule contient un nombre parmis du texte

nalouz

XLDnaute Nouveau
bonjour a tous,

Jai un petit probleme a vous proposer:
Jaimerai connaitre une formule qui puisse dire si une cellule contient un ou plusieur nombres. Cad que si dans une cellule il y a "je mappelle luc et jhabite au n°5 de la rue" la fonction me dise VRAI car il y a le "5" et inversement sur une cellule ne contient pas de nombre.

merci merci de votre aide

nalouz
 

mth

XLDnaute Barbatruc
Re : Tester qu'une cellule contient un nombre parmis du texte

Bonjour nalouz

Un essai avec cette formule (matricielle à valider par CTRL MAJ ENTER)

Code:
=SI(SOMME(SI(NON(ESTERREUR(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1)*1));1))>0;VRAI)

Bien à toi,

mth
(euh.. en me relisant, on doit pouvoir trouver plus court ...)

Edit: :) :) Bonjour Tibo :) :)
Edit 2: Merci Tibo pour ta formule plus courte, bien mieux :)
 
Dernière édition:

Tibo

XLDnaute Barbatruc
Re : Tester qu'une cellule contient un nombre parmis du texte

Bonjour nalouz, bonjour Mireille, bises :),

J'ai vu la même question ailleurs où j'ai apporté la réponse suivante, similaire à la tienne sur le principe :

Code:
=SI(SOMMEPROD(ESTNUM(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1)*1)*1);"contient un ou des nombre(s)";"ne contient pas de nombres")

à valider par ENTREE

@+

Edit : Mireille, j'ai repris ta formule pour tenter de la raccourcir, ça donne ceci :

Code:
=SI(SOMME(ESTNUM(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1)*1)*1);VRAI)

Matricielle, donc CTRL + MAJ + ENTREE

@+
 
Dernière édition:

Dugenou

XLDnaute Barbatruc
Re : Tester qu'une cellule contient un nombre parmis du texte

Bonjour à tous,

Une autre approche avec 10 colonnes intermédiaires : je sais pas si c'est mieux !
 

Pièces jointes

  • chiffredanstexte.xls
    14.5 KB · Affichages: 103
  • chiffredanstexte.xls
    14.5 KB · Affichages: 118
  • chiffredanstexte.xls
    14.5 KB · Affichages: 152

BOISGONTIER

XLDnaute Barbatruc
Repose en paix
Re : Tester qu'une cellule contient un nombre parmis du texte

Bonjour,

Renvoie VRAI si A1 contient au moins un chiffre

=SOMMEPROD(--ESTNUM(CNUM(STXT(A1;LIGNE($1:$255);1))))>0

ou

=SOMME(--ESTNUM(CNUM(STXT(A1;LIGNE(1:255);1))))>0
Maj+ctrl+entrée

JB
 
Dernière édition:

Dugenou

XLDnaute Barbatruc
Re : Tester qu'une cellule contient un nombre parmis du texte

Re,

Avec ceci en matriciel ça fonctionne aussi (valeurs 0 à 9 en C3:L3)
Code:
=SI(MAX(SI(ESTERREUR(CHERCHE($C$3:$L$3;A4));0;1))=0;"pas de chiffres";"chiffre")

Cordialement
 

nalouz

XLDnaute Nouveau
Re: Re : Tester qu'une cellule contient un nombre parmis du texte

Une autre question maintenant,
la meme chose mais je voudrais que la fonction repere une suite de chiffre de 4 caracteres ou plus, Cad "10 00" ou "332 54" mais pas "23 3" . est ce possible?
 

Tibo

XLDnaute Barbatruc
Re : Tester qu'une cellule contient un nombre parmis du texte

re,

S'il n'y a pas d'espace dans la chaîne numérique :

Code:
=EQUIV(VRAI;ESTNUM(STXT(SUBSTITUE(A1;" ";"µ");LIGNE(INDIRECT("$1:$255"));4)*1);0)+1

Matricielle à valider par CTRL + MAJ + ENTREE


Avec des espaces au niveau de la chaîne numérique, pas trouvé pour le moment, je regarde.

@+
 

hoerwind

XLDnaute Barbatruc
Re : Tester qu'une cellule contient un nombre parmis du texte

Bpnjour, salut les autres,

Pour Tibo : si dans ta (très jolie) formule tu remplaces "µ" par "", cela semble fonctionner.
Et si tu la places dans un ESTNUM( ), elle renverra VRAI ou Faux, tel que demandé
 

Tibo

XLDnaute Barbatruc
Re : Re: Re : Tester qu'une cellule contient un nombre parmis du texte

re, salut hoerwind,

Merci pour ta solution.

...mais je voudrais que la fonction repere une suite de chiffre de 4 caracteres...

En fait, j'avais interprété "repère une suite de chiffres" comme étant le souhait d'en déterminer l'emplacement.

Et si on supprime les espaces, je ne vois pas comment déterminer l'emplacement précis de la chaîne de 4 chiffres (avec espaces) dans la chaîne initiale.

Attendons le retour de notre ami.

@+
 

hoerwind

XLDnaute Barbatruc
Re : Tester qu'une cellule contient un nombre parmis du texte

Re,

Déterminer le début de l'emplacement d'une chaine de chiffres ne pose pas problème, vois la pièce jointe.
De là yapluka ...
Mais là c'est une autre question, pas insurmontable à mon avis.
 

Pièces jointes

  • ExtractionChaineDeChiffres.xls
    15 KB · Affichages: 100

Discussions similaires

Statistiques des forums

Discussions
311 711
Messages
2 081 794
Membres
101 817
dernier inscrit
carvajal