XL 2010 supprimer un chiffre si et seulement si placé en début de cellule

[sebbbbb]

bonjour

je m'arrache les cheveux pour trouver une formule. Je souhaiterai que si une cellule commence par un chiffre une autre cellule reprenne les mêmes élément mais sans le chiffre ( si et seulement si le chiffre apparaît en début de cellule)

ex :
cellule A1 : 12 remorques vides
devienne en cellule A2 : remorques vides

par contre si A1 = remorque vide
alors A2 s'écrit à l'identique

si A1 = remorque 19 vide
là aussi A2 s'écrit à l'identique

Merci beaucoup a vous
seb

 

[CISCO]

Bonsoir

Essaye avec

=SI(ESTNUM(--STXT(A1;1;1));STXT(A1;CHERCHE(" ";A1);9^9);A1)

@ plus

 

[Boo2bafoot]

Salut Seb,

Teste cette formule en A2 :

=SI(ESTNUM(GAUCHE(A1;1)*1);DROITE(A1;NBCAR(A1)-CHERCHE(" ";A1));A1)

Bonne soirée

Edit: Je n'avais pas vu la réponse de Cisco, que je salue... Désolé si ça fait doublon

 

[sebbbbb]

Parfait
merci à vous 2
quelle réactivité !

 

[job75]

Bonjour sebbbbb, CISCO, Boo2bafoot,

Une autre solution :

=SUPPRESPACE(STXT(A1;MAX(1;ESTNUM(-GAUCHE(A1))*TROUVE(" ";A1&" "));9^9))

Noter que TROUVE(" ";A1&" ") évite de renvoyer une erreur s'il n'y a aucun espace en A1.

Remarquer que cette formule évite la fonction SI grosse consommatrice d'octets en mémoire :

- formule de CISCO => 68 octets (mais elle serait à compléter car elle donne un espace superflu)

- formule de Boo2bafoot => 71 octets

- formule de job75 => 56 octets.

A+

 

[sebbbbb]

Super
Merci

 

[sebbbbb]

Excellent
Merci

 

[job75]

Re,

Optimisée pour fonctionner dans tous les cas de figure, la formule avec SI de CISCO :

=SUPPRESPACE(SI(ESTNUM(-GAUCHE(A1));STXT(A1;CHERCHE(" ";A1&" ");9^9);A1))

"pèse" 70 octets.

A+

 

[sebbbbb]

bonjour
est il possible d'adapter cette formule pour que ce soit l'inverse ; cad que seule les chiffres figurant à gauche apparaissent et pas le reste.
un grand merci par avance
seb

 

[job75]

Bonsoir sebbbbb,

Si le nombre situé en tête est séparé du reste par un espace :

=SIERREUR(--GAUCHE(A1;TROUVE(" ";A1&" "));"")

A+

 

[job75]

Re,

Si le nombre en tête n'est pas toujours séparé du reste par un espace :

=SIERREUR(--GAUCHE(A1;SOMMEPROD(--ESTNUM(-(GAUCHE(A1;LIGNE(INDIRECT("1:"&NBCAR(A1))))&0))));"")

Edit : &0 est nécessaire au cas où le texte qui suit commence par " a" ou " p", voyez ce fil :

https://www.excel-downloads.com/threads/12-a-ou-12-p.20019156/

En outre cela permet de récupérer des nombres négatifs.

Bonne nuit.

 

[sebbbbb]

EXCELLENT ! encore une fois
merci infiniment
seb