Microsoft 365 Supprimer ligne si cellule différente d'une valeur numérique et si vide

[pierrof]

Bonjour,

Dans mon nouveau projet, j'aimerais à l'aide d'une macro supprimer les lignes de mon tableau (tableau pouvant atteindre 15000 lignes) si la valeur de la cellule A n'est pas un nombre ou si elle est vide.

Je laisse un fichier exemple.

Merci d'avance de votre aide.

Cordialement

 

[Staple1600]

Bonjour

Tu peux le faire en deux passes (sans macro)
F5/Cellules/Constantes/Texte => OK
Puis tu supprimes les lignes sélectionnées
2ième passe
F5/Cellules/Vides=> OK
Puis tu supprimes les lignes sélectionnées

 

[Staple1600]

Re

Ce qui donnerait en VBA

Sub Macro1()
Application.ScreenUpdating = False
Columns("A:A").SpecialCells(xlCellTypeConstants, 2).EntireRow.Delete
Range(Cells(1), Cells(Rows.Count, 1).End(3)).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End Sub

Maintenant, sur 15000 lignes, cela risque de faire tousser Excel

Mais d'autres viendront qui te proposeront des solutions plus évoluées

EDITION: Ce n'est pas encore un autre, ce n'est que moi
Cette version est un peu plus rapide
(j'ai testé sur 5000 lignes)

Sub Macro2()
Application.ScreenUpdating = False
Columns("A:A").Sort key1:=Cells(1), Order1:=xlDescending, Header:=xlNo
Columns("A:A").SpecialCells(xlCellTypeConstants, 2).EntireRow.Delete
End Sub

 

[pierrof]

Bonjour Staple 1600,

Merci pour ce code, juste une petite question la ligne des entêtes de colonne est supprimer aussi avec le code comme faire pour ne pas la supprimer?

Sub Macro1()
Application.ScreenUpdating = False
Columns("A:A").SpecialCells(xlCellTypeConstants, 2).EntireRow.Delete
Range(Cells(1), Cells(Rows.Count, 1).End(3)).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End Sub

Merci encore.

Cordialement

 

[Staple1600]

Re

Comme ceci, je suppose

Sub Macro3()
Application.ScreenUpdating = False
Columns("A:A").Sort key1:=Cells(1), Order1:=xlDescending, Header:=xlYes
Range(Cells(2, 1), Cells(Rows.Count, 1).End(3)).SpecialCells(xlCellTypeConstants, 2).EntireRow.Delete
End Sub

 

[Phil69970]

Bonjour @pierrof , @Staple1600

Je te propose ce fichier en partant de la base de Staple

*Merci de ton retour

Edit : pour info 0.13s pour 15 000 lignes avec 10 000 lignes supprimées sur mon PC

@Phil69970

 

[Staple1600]

Bonjour Phil69970

J'ai une petite requete
T'est-il possible quand tu publies une solution de publier le code VBA dans le corps du message en plus de la PJ ?
(Cela m'évite de stocker la multitude de fichiers exemple d'XLD)
Et comme dans ce message, tu pars sur ma base, j'aimerais voir à quoi ressemble ton code
Merci.

 

[Phil69970]

Re

Voici le code VBA

Sub Supprime()
Application.ScreenUpdating = False
Dim Derlig&
Derlig = Worksheets("Feuil1").Range("A" & Rows.Count).End(xlUp).Row
Columns("A:A").Insert Shift:=xlToRight, CopyOrigin:=xlFormatFromLeftOrAbove
[A2] = 1: Range("A2:A" & Derlig).DataSeries
Columns("A:N").Sort key1:=Cells(2), Order1:=xlDescending, Header:=xlYes
Range("B2:B" & Derlig).SpecialCells(xlCellTypeConstants, 2).EntireRow.Delete
Range("B2:B" & Derlig).SpecialCells(xlCellTypeBlanks, 4).EntireRow.Delete
Columns("A:N").Sort key1:=Cells(1), Order1:=xlAscending, Header:=xlYes
Columns("A:A").Delete
End Sub

Private Sub CommandButton1_Click()
Supprime
End Sub

Pour info 0.13s pour 15 000 lignes avec 10 000 lignes supprimées sur mon PC

@Phil69970

 

[Staple1600]

Re

Merci
Normalement, si on fait le tri, plus besoin de supprimer les lignes vides car elles retrouvent en fin de tableau.
Je ne comprends pas l'ajout de la colonne et le Dataseries
Il faudrait peut-être que j'ouvre ta PJ pour comprendre
Ce qui ruinerait mon plan d'économie d'octets
(cf mon message précédent)

PS: Je me suis basé sur ce seul critère

si la valeur de la cellule A n'est pas un nombre ou si elle est vide.

Donc je n'occupe que la colonne A, et peut importe ce qu'il à droite de la colonne A, non ?
puisque on supprime des lignes entières ?
Damned! Mais oui, c'est tout le tableau qu'il faut trier.

Bon bah, je vais télécharger ta PJ.

 

[Phil69970]

Re

Je ne comprends pas l'ajout de la colonne et le Dataseries

C'est pour remettre tout en place (dans le même ordre que le fichier était au départ ) après avoir enlevé les lignes textes et vides.
Cela me permet de rendre le fichier comme je l'ai trouvé au départ et d’éviter d’avoir un post me disant c'est pas dans l'ordre je suis perdu......

@Phil69970

 

[Phil69970]

Re

plus besoin de supprimer les lignes vides car elles retrouvent en fin de tableau.

Je crois que c’était dans la demande .

si la valeur de la cellule A n'est pas un nombre ou si elle est vide.

@Phil69970

 

[Staple1600]

Re

=>Phil
J'ai donc ouvert ta PJ

Donc sur la base du fichier de Phil basé sur ma base
(oui je sais cela fait beaucoup de base )
Je change mon fusil d'épaule
et je propose cette autre façon de faire

Sub Suppr_ALPHA_VIDE()
Dim l&, r As Range
Application.ScreenUpdating = False
l = ActiveSheet.UsedRange.Rows.Count
Columns("A:N").Sort key1:=Cells(2), Order1:=xlDescending, Header:=xlYes
Set r = Range("N2:N" & l)
r.FormulaR1C1 = "=IF(OR(ISTEXT(RC[-13]),ISBLANK(RC[-13])),""Staple"",1)"
r = Range("N2:N" & l).Value
r.SpecialCells(xlCellTypeConstants, 2).EntireRow.Delete
Columns(14).Clear
End Sub

PS; je te laisse tester sur 15000 lignes
(car mon PC n'est point véloce)

 

[Phil69970]

Re

0.87s sur les mêmes 15 000 lignes avec les mêmes 10 000 lignes à supprimées sur mon PC

Je pense que remplir les blancs en texte est plus lent que supprimer les blancs directement .....
Ou alors "Staple" est trop long à écrire .....

Après le demandeur choisira si il est à 0.74 s près vu de mon PC.

@Phil69970

 

[Staple1600]

RE

La formule : OU(ESTTEXTE(A2);ESTVIDE(A2))
Elle ne checke pas que les blancs
Tu peux faire le test avec Phil à la place de Staple
ou même $ comme string

 

[Phil69970]

Re

Gain non significatif 0.01s

@Phil69970