Autres Suppression de ligne particulières

[lynyrd]

Bonsoir le forum
est ce possible par VBA de supprimer la ligne entière s'il n'y a rien dans la colonne "B"
Merci.

 

[mapomme]

Bonsoir @lynyrd,

Testez le code suivant:

Sub SuppLigneSiBvide()
With Sheets("Feuil1")
  On Error Resume Next
  .Range("b1:b" & .Cells(.Rows.Count, "a").End(xlUp).Row).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End With
End Sub

Ou plus court:

Sub SuppLigneSiBvide()
  Sheets("Feuil1").Columns(2).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End Sub

 

[lynyrd]

C'est nickel mapomme
Merci.

 

[job75]

Bonjour lynyrd, mapomme, le forum,

La macro de mapomme peut prendre beaucoup de temps sur de grands tableaux.

Voyez le fichier joint avec - seulement - 18360 lignes.

Cette macro est beaucoup plus rapide mais il faut défusionner les cellules pour pouvoir trier :

Sub Suppression_job75()
Dim t, col%, h&
t = Timer
Application.ScreenUpdating = False
With Sheets("Feuil1").UsedRange
    .UnMerge 'défusionne pour pouvoir trier
    col = .Columns.Count + 2
    .Columns(col) = 1
    Intersect(.Columns(2).SpecialCells(xlCellTypeBlanks).EntireRow, .Columns(col)) = ""
    .EntireRow.Sort .Columns(col), Header:=xlNo 'tri pour regrouper et accélérer
    .Columns(2).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
    .Columns(col) = ""
    '---refusionne (à adapter au besoin)---
    h = .Rows.Count
    With .Cells(1, 3).Resize(, 6)
        .Merge
        .AutoFill .Resize(h), xlFillFormats
    End With
    With .Cells(1, 9).Resize(, 6)
        .Merge
        .AutoFill .Resize(h), xlFillFormats
    End With
End With
MsgBox "Suppression en " & Format(Timer - t, "0.00 \s"), , "job75"
End Sub

A+

 

[mapomme]

Bonjour @job75 et bon dimanche ,

La macro de mapomme peut prendre beaucoup de temps sur de grands tableaux.

C'est pas faux mais comme le tableau n'était pas grand, j'ai joué la paresse , je le reconnais