souci avec les prénoms

[Sylvie64]

Bonjour,

j'ai un souci avec les prénoms, quand je mets mes formules tout va bien, mais le
problème c'est quand il ni a pas de majuscule au prénom et bien la dernière lettre du nom
ce mets avec les prénoms (voir en PJ, colonne E)

Y a t-il une solution ?
Se sont des fichiers que j'ai repris et cela me pose un vrai problème !!!

Merci pour votre aide.

Sylvie

 

[job75]

Re : souci avec les prénoms

Bonjour à tous,

Admirateur, comme tous ici, des formules de Monique, j'ose quand même les modifier un chouia :

=SUPPRESPACE(GAUCHE(D2;EQUIV(FAUX;ESTNUM(TROUVE(" ";D2;LIGNE(INDIRECT("1:"&NBCAR(D2)))));0)-1))

=SUPPRESPACE(SUBSTITUE(D2;E2;))

A+

 

[david84]

Re : souci avec les prénoms

Bonjour à tous,
Pas suivi tout le fil donc je ne sais pas si cela répond à l'ensemble des critères, mais testé sur le fichier de Monique :
pour les noms :

=GAUCHE(D2;NBCAR(D2)-EQUIV(" ";STXT(D2;NBCAR(D2)-LIGNE($1:$255);1);0))

pour les prénoms :

=DROITE(D2;EQUIV(" ";STXT(D2;NBCAR(D2)-LIGNE($1:$255);1);0))

Formules matricielles
A+

 

[job75]

Re : souci avec les prénoms

Bonjour David,

Tu as tout à fait raison, c'est nettement plus simple encore, bravo.

Mais un petit bémol : s'il y a [Edit : seulement] un nom sans aucun espace, les formules renvoient #N/A.

Alors que chez Monique (et chez moi), le nom passe alors dans la colonne des prénoms...

A+

 

[david84]

Re : souci avec les prénoms

Re
salut Job, j'avais prévenu que je n'avais pas suivi le fil donc il se peut que la solution ne réponde pas à l'ensemble des exemples fournis (je n'ai testé que sur le fichier de Monique car cela m'intéressait de voir ce qu'elle avait proposé).
Quand tu dis

s'il y a un nom sans aucun espace, les formules renvoient #N/A

, que veux-tu dire ? Un nom seul ?
Donne un exemple STP, j'ai la tête un peu farcie cet AM.
A+

 

[job75]

Re : souci avec les prénoms

Re,

Ben tu entres seulement david84 en D2...

A+

 

[JCGL]

Re : souci avec les prénoms

Bonjour à tous,

N'apporte rien à la discussion

Si ce n'est le plaisir de croiser autant d'amis rassemblés...

Chamrousse (1 750 m) : Grand Soleil et 26° (thermomètre en plein soleil...)

UnCitronVertàvotresantécesoiretundeuxièmepourlesinsulaires

A++
A+ à tous

 

[david84]

Re : souci avec les prénoms

Re
à 1ère vue et si je t'ai compris :

=SI(ESTNA(GAUCHE(D2;NBCAR(D2)-EQUIV(" ";STXT(D2;NBCAR(D2)-LIGNE($1:$255);1);0)));D2;GAUCHE(D2;NBCAR(D2)-EQUIV(" ";STXT(D2;NBCAR(D2)-LIGNE($1:$255);1);0)))

ramène alors la totalité de la cellule (mais bon, le but étant de séparer les prénoms des noms, tu dois avoir...un prénom et un nom).
A+

Edit : je salue JC (profites-en !) et pierrejean.

 

[pierrejean]

Re : souci avec les prénoms

Re

Salut a tous mes amis

Pour conserver ma reputation:
2 petites fonctions personnalisées (en parallele avec les matrcielles de MONIQUE a qui je presente mes hommages)

 

[job75]

Re : souci avec les prénoms

Re David,

OK, et en 2ème vue j'écrirais plus simplement :

=SI(NB.SI(D2;"* *");GAUCHE(D2;NBCAR(D2)-EQUIV(" ";STXT(D2;NBCAR(D2)-LIGNE($1:$255);1);0));D2)

Monique doit rigoler

Edit : salut JC, tu commençais à nous manquer tu sais

A+

 

[david84]

Re : souci avec les prénoms

Re

et en 2ème vue j'écrirais plus simplement

Ben, tu as une bien meilleure 2ème vue que moi !
Tu peux aussi écrire :

=SI(ESTNUM(TROUVE(" ";D2));GAUCHE(D2;NBCAR(D2)-EQUIV(" ";STXT(D2;NBCAR(D2)-LIGNE($1:$255);1);0));D2)

A+

 

[job75]

Re : souci avec les prénoms

Re David,

NB.SI(D2;"* *") prend 13 octets, ESTNUM(TROUVE(" ";D2)) en prend 15.

Mais bof...

A+

 

[Sylvie64]

Re : souci avec les prénoms

Je vois que "Tibo" me connait bien !! effectivement j'avais omis de préciser qu'il y avait des noms composés, merci pour ta formule.

Et non, je n'ai plus de souci "Staple1600" encore merci à tous pour votre aide.

@+

 

[david84]

Re : souci avec les prénoms

Re

NB.SI(D2;"* *") prend 13 octets, ESTNUM(TROUVE(" ";D2)) en prend 15.

Mais bof...

Cela me fait penser qu'il faudra un jour qu'on aborde à nouveau ce sujet (mais bon avant, je vais essayer de comprendre un peu mieux le VBA parce que je ne t'étais d'aucune utilité dans ce post car n'y comprenant pas grand chose et mélangeant différents paramètres tels que nombre d'octets, vitesse d'exécution,...).
A+

 

[Sylvie64]

Re : souci avec les prénoms (pour Tibo)

Bonjour Tibo,

En mettant cette formule tout va bien :


Code:

=GAUCHE(D2;EQUIV(1;(CODE(STXT(SUPPRESPACE(D2);LIGNE(INDIRECT("$1:$100"));2))
<97)*(DROITE(STXT(SUPPRESPACE(D2);LIGNE(INDIRECT("$1:$100"));2))=" ")*(CODE(
STXT(SUPPRESPACE(D2);LIGNE(INDIRECT("$1:$100"))+3;1))>96);0)+1)



Mais quand le nom fini par É et bien ça me donne toujours ceci : #N/A


Y a t-il une autre possibilité pour que la formule accepte les É ?

Merci pour ton aide

Sylvie

 

[Tibo]

Re : souci avec les prénoms

Salut Sylvie,

Essaye avec cette adaptation :

=GAUCHE(C2;EQUIV(1;(EXACT(MAJUSCULE(STXT(SUPPRESPACE(C2);LIGNE(INDIRECT("$1:
$100"));2));(STXT(SUPPRESPACE(C2);LIGNE(INDIRECT("$1:$100"));2))))*(DROITE(STXT(
SUPPRESPACE(C2);LIGNE(INDIRECT("$1:$100"));2))=" ")*(CODE(STXT(SUPPRESPACE(C2);
LIGNE(INDIRECT("$1:$100"))+3;1))>96);0)+1)

Toujours en matricielle

Regarde également les autres solutions qui ont été proposées dans ce fil.

Le cas échéant, crée un fichier avec les différentes hypothèses que tu peux rencontrer avec les noms et les différentes formules proposées.

@+