sos Index Equiv ??

kawi99

XLDnaute Junior
Bonjour à tous,

Je viens à vous car je cale... !

Je cherche depuis des jours comment récupérer automatiquement des données en fonction d'un mois particulier.

Dans le fichier joint, je souhaite qu'en fonction du mois (cellule AO3), la formule puise dans le tableau Z4:AK26 et les fasse automatiquement ressortir dans le tableau AP05:AQ26 (nombre de personnes, par sexe, par age pour le mois demandé).

Je pense que la soluce réside dans INDEX et EQUIV mais je ne sais pas m'en servir ;(

Je vous remercie d'avance, ça me dépannerait beaucoup !

Cordialement, K99
 

Pièces jointes

  • Question Index Equiv.xlsx
    18.7 KB · Affichages: 15

Yoyo01000

XLDnaute Occasionnel
Bonjour,
je ne comprends pas ce que tu veux précisément faire apparaître dans AO-AP-AQ ?

à quoi correspondent tes données dans la plage Z5:AQ26 ?

si c'est mieux pour toi, joins un fichier de que tu attends dans les colonnes AO-AP-AQ depuis quelles données !
 

kawi99

XLDnaute Junior
Bonjour,
je ne comprends pas ce que tu veux précisément faire apparaître dans AO-AP-AQ ?

à quoi correspondent tes données dans la plage Z5:AQ26 ?

si c'est mieux pour toi, joins un fichier de que tu attends dans les colonnes AO-AP-AQ depuis quelles données !

Re et merci pour votre aide.
Désolé si je n'ai pas été super clair.
Je souhaite avoir le dispatch dans les colonnes AP:AQ du nombre de femmes et hommes en fonction de leur age (en fonction du mois demandé).
La formule actuelle en AP5 est la suivante =SOMMEPROD(($S$5:$S$484=1)*($Q$5:$Q$484=AP$1)*($W$5:$W$484=$AO5)*($AK$5:$AK$484))
$AK$5:$AK$484 > Correspond à décembre et je dois à chaque fois décaler la colonne pour avoir le mois qui m'intéresse.
Ce que je souhaite faire, c'est une formule qui récupère automatiquement le nombre de personnes en fonction du mois que je choisirai (AO3)
Si je dis en AO3 : 30/06/2018... Pouf.. il récupère les données dans la colonne de juin (AE) et me dispatche les pers selon leur age/sx
C'est faisable ?
Merci.
Cdlt K99
 

Iznogood1

XLDnaute Impliqué
Bonjour,

La formule en AP5 (à copier/coller sur les lignes et colonnes suivantes bien sûr) devient :
=SOMMEPROD(($S$5:$S$484=1)*($Q$5:$Q$484=AP$1)*($W$5:$W$484=$AO5)*(MOIS($Z$4:$AK$4)=MOIS($B$2))*($Z$5:$AK$484))

Les modifications faites sont :
  • ajouter : *(MOIS($Z$4:$AK$4)=MOIS($B$2)) --> on retourne une matrice d'une ligne avec la valeur VRAI pour la colonne correspondant au mois
  • modifier : $AK$5:$AK$484 qui devient $Z$5:$AK$484 --> on applique le calcul sur toute la plage Z:AK au lieu de seulement sur la colonne AK

Remarques :
  • Pas besoin de valider par CTRL + Maj + Entée, SommeProd est "par nature" matricielle
  • Les parenthèses ne sont utiles que pour les critères -> superflues pour la dernière plage
  • Enfin, l'utilisation de plages nommées permet de s'affranchir d'un nombre prédéfini de lignes (ici 484) et d'avoir des formules beaucoup plus lisibles comme :
    =SOMMEPROD((Exclusion=1)*(Sexe=AP$1)*(Age=$AO5)*(MOIS(Mois)=MOIS($B$2))*Data)

Voir fichier joint
 

Pièces jointes

  • Question Index Equiv.xlsx
    18.9 KB · Affichages: 8
Dernière édition:

kawi99

XLDnaute Junior
Bonjour,

La formule en AP5 (à copier/coller sur les lignes et colonnes suivantes bien sûr) devient :
=SOMMEPROD(($S$5:$S$484=1)*($Q$5:$Q$484=AP$1)*($W$5:$W$484=$AO5)*(MOIS($Z$4:$AK$4)=MOIS($B$2))*($Z$5:$AK$484))

Les modifications faites sont :
  • ajouter : *(MOIS($Z$4:$AK$4)=MOIS($B$2)) --> on retourne une matrice d'une ligne avec la valeur VRAI pour la colonne correspondant au mois
  • modifier : $AK$5:$AK$484 qui devient $Z$5:$AK$484 --> on applique le calcul sur toute la plage Z:AK au lieu de seulement sur la colonne AK

Remarques :
  • Pas besoin de valider par CTRL + Maj + Entée, SommeProd est "par nature" matricielle
  • Les parenthèses ne sont utiles que pour les critères -> superflues pour la dernière plage
  • Enfin, l'utilisation de plages nommées permet de s'affranchir d'un nombre prédéfini de lignes (ici 484) et d'avoir des formules beaucoup plus lisibles comme :
    =SOMMEPROD((Exclusion=1)*(Sexe=AP$1)*(Age=$AO5)*(MOIS(Mois)=MOIS($B$2))*Data)

Voir fichier joint
Bonjour Iznoggod1,
Tout simplement super ! Merci beaucoup !!
PS : je n'étais pas si loin de la solution ^^
Bonne continuation à toi et au forum
encore merci, K99
 

Discussions similaires

Statistiques des forums

Discussions
311 711
Messages
2 081 786
Membres
101 817
dernier inscrit
carvajal