SOMMEPROD (Somme entre dates) mais avec Colonne Variable

[Valentin_Loupe]

Bonjour à tous,

Je me penche depuis pas mal de temps sur une formule SOMMEPROD améliorée mais ne parviens pas à obtenir ce que je souhaite.

En fait, Je dois réaliser une somme de valeurs comprises entre deux dates (ca c'est réussi avec le SOMMEPROD à 2 conditions) mais maintenant je voudrais pouvoir faire varier la colonne de laquelle la somme est à réaliser à l'aide d'un RECHERCHEH par exemple.

Pour le moment, ma formule ressemble à :

=SOMMEPROD(('Feuil2'!$A$2:$A$1000>=DATE(ANNEE(D23);MOIS(D23);1))*('Feuil2'!$A$2:$A$1000<=DATE(ANNEE(D23);MOIS(D23);JOUR(FIN.MOIS(D23;0))))*('Feuil2'!$B$2:$B$1000))

Grace à cette formule, on parvient à regarder dans la colonne A si la date est bien supérieure ou égale au premier jour du mois de D23 et inférieure ou égale au dernier jour du mois de D23 et si oui, on somme les valeurs correspondantes présentes en colonne B. Or, c'est cette colonne B qui peut être amenée à varier.

J'aimerais donc pouvoir rechercher une valeur dans la ligne d'entete de la Feuil2 via un RECHERCHEH par exemple et pouvoir changer de colonne à sommer.

Je reste bien sur à disposition si il y a besoin,

Un grand merci par avance,

Valentin

 

[ROGER2327]

Re : SOMMEPROD (Somme entre dates) mais avec Colonne Variable

Bonjour Valentin_Loupe

Un petit support (au format .xls si possible) illustrant la chose nous éviterait d'en construire un au pif pour tester une éventuelle solution…
À plus tard, peut-être.​

ROGER2327
#5044

Vendredi 13 Pédale 138 (Sainte Valburge, SQ)
17 Ventôse An CCXIX
2011-W10-1T14:06:40Z

 

[Hippolite]

Re : SOMMEPROD (Somme entre dates) mais avec Colonne Variable

Bonjour,
Ne sachant pas en fonction de quoi la colonne B varie, c'est difficile de se prononcer.
Y-aurait-il matière à utiliser DECALER ?

 

[Valentin_Loupe]

Re : SOMMEPROD (Somme entre dates) mais avec Colonne Variable

Re-bonjour !

Tout d'abord, merci de passer du temps à résoudre mon problème.
Sinon, en effet, voici une pièce jointe.

Valentin

 

[ROGER2327]

Re : SOMMEPROD (Somme entre dates) mais avec Colonne Variable

Re...

Je ne lis pas les fichiers .xlsx avec Excel2003. Voyez tout de même une proposition à adapter dans le classeur joint.​

ROGER2327
#5045

Vendredi 13 Pédale 138 (Sainte Valburge, SQ)
17 Ventôse An CCXIX
2011-W10-1T14:49:28Z

 

[JNP]

Re : SOMMEPROD (Somme entre dates) mais avec Colonne Variable

Bonsoir le fil ,
en E23

=SOMMEPROD((Feuil2!$A$2:$A$1000>=DATE(ANNEE(D23);MOIS(D23);1))*(Feuil2!$A$2:$A$1000<=DATE(ANNEE(D23);MOIS(D23);JOUR(FIN.MOIS(D23;0))))*(INDIRECT("Feuil2!$"&CAR(EQUIV($J$9;Feuil2!$B$1:$P$1;0)+65)&"$2:$"&CAR(EQUIV($J$9;Feuil2!$B$1:$P$1;0)+65)&"$1000")))

Je joins le fichier en XLS pour l'ami Roger .
Bonne soirée

 

[Valentin_Loupe]

Re : SOMMEPROD (Somme entre dates) mais avec Colonne Variable

Bonjour à toutes les personnes du fil,

C'est impeccable ! Merci beaucoup beaucoup pour votre aide !
C'est Excel/lent !

Merci encore,

Valentin

 

[ROGER2327]

Re : SOMMEPROD (Somme entre dates) mais avec Colonne Variable

Re…

Merci, JNP

La formule que je proposai plus tôt s'adapte ainsi :

=SI(ESTNA(EQUIV($J$9;Feuil2!$B$1:$P$1;0));"";SOMMEPROD((DATE(ANNEE($D23);MOIS($D23);1)<=Feuil2!$A$2:$A$185)*(Feuil2!$A$2:$A$185<DATE(ANNEE($D23);MOIS($D23)+1;1))*INDEX(Feuil2!$B$2:$P$185;;EQUIV($J$9;Feuil2!$B$1:$P$1;0))))

en E23, à recopier vers le bas.​

ROGER2327
#5047

Vendredi 13 Pédale 138 (Sainte Valburge, SQ)
17 Ventôse An CCXIX
2011-W10-1T15:34:50Z

 

[JCGL]

Re : SOMMEPROD (Somme entre dates) mais avec Colonne Variable

Bonjour à tous,
Salut Roger,

Un essai avec colonnes nommées et liste de validation au format *.xls

A+ à tous

Édition : Salut JNP

 

[ROGER2327]

Re : SOMMEPROD (Somme entre dates) mais avec Colonne Variable

Re…

JCGL[/B];960929]Bonjour à tous,
Salut Roger,

Un essai avec colonnes nommées et liste de validation au format *.xls

A+ à tous

Il est certain que cela prend une autre allure et clarifie les choses…​

ROGER2327
#5048

Vendredi 13 Pédale 138 (Sainte Valburge, SQ)
17 Ventôse An CCXIX
2011-W10-1T15:49:25Z

 

[Valentin_Loupe]

Re : SOMMEPROD (Somme entre dates) mais avec Colonne Variable

Bonjour le fil, le forum,

Merci encore pour toutes ces réponses !
Puis-je abuser de votre gentillesse ?

Je voudrais savoir si il serait possible également de sortir le Max du mois associé.
Ainsi, sous l'onglet "Analyse Comparative", on pourrait avoir par mois la somme (Cellules E23:E28) et juste à droite en colonne F, la valeur Max de chaque mois ?

Est-ce possible ?

Merci par avance,

Valentin

 

[JNP]

Re : SOMMEPROD (Somme entre dates) mais avec Colonne Variable

Re ,
La même que le SOMMEPROD

=MAX((Feuil2!$A$2:$A$1000>=DATE(ANNEE(D23);MOIS(D23);1))*(Feuil2!$A$2:$A$1000<=DATE(ANNEE(D23);MOIS(D23);JOUR(FIN.MOIS(D23;0))))*(INDIRECT("Feuil2!$"&CAR(EQUIV($J$9;Feuil2!$B$1:$P$1;0)+65)&"$2:$"&CAR(EQUIV($J$9;Feuil2!$B$1:$P$1;0)+65)&"$1000")))

mais à valider en matricielle avec Ctrl+Maj+Enter
Bonne soirée