Sommeprod plusieurs conditions

[bobjazz]

Bonjour le Forum

J'ai plusieurs fonctions avec sommeprod qui fonctionnent dans mon fichier, mais j'en ai une qui met une erreur #VALEUR! et je ne vois pas pourquoi.
Si je calcule la colonne P avec "=SOMMEPROD('Liste Interventions'!$P$2:$P$44)" j'ai bien la somme, mais des que je met les 2 conditions, cela ne fonctionne pas. Mon but est de compter le nombre d'heures en fonction du mois et de la prestation.
Je joins un fichier plus facile que mes explications.

Merci d'avance pour votre aide.

Cdlt,

Bobjazz

 

[mapomme]

Re : Sommeprod plusieurs conditions

Bonjour bobjazz,

Essayez ces deux formules à tirer vers la droite:

Formule en C11:

=SOMMEPROD((MOIS('Liste Interventions'!$L$2:$L$44)=MOIS(C$2))*('Liste Interventions'!$C$2:$C$44=$A$3);'Liste Interventions'!$P$2:$P$44)

ou

=SOMMEPROD((MOIS('Liste Interventions'!$L$2:$L$44)=MOIS(C$2))*('Liste Interventions'!$C$2:$C$44=$A$3)*(0&'Liste Interventions'!$P$2:$P$44))

Fomule en C20:

=SOMMEPROD((MOIS('Liste Interventions'!$L$2:$L$44)=MOIS(C$2))*('Liste Interventions'!$C$2:$C$44=$A$12);'Liste Interventions'!$P$2:$P$44)

ou

=SOMMEPROD((MOIS('Liste Interventions'!$L$2:$L$44)=MOIS(C$2))*('Liste Interventions'!$C$2:$C$44=$A$12)*(0&'Liste Interventions'!$P$2:$P$44))

 

[bobjazz]

Re : Sommeprod plusieurs conditions

Bonjour,

Merci cela fonctionne, une question pourquoi on met ; à la place de*.

Merci

Bobjazz

 

[CPk]

Re : Sommeprod plusieurs conditions

Bonjour a essayer...

=SOMMEPROD((MOIS('Liste Interventions'!$L$2:$L$44)=MOIS(C$2))*('Liste Interventions'!$C$2:$C$44=$A$3)*(ESTNUM('Liste Interventions'!$P$2:$P$44)))

Oups trop tard pardon

 

[bobjazz]

Re : Sommeprod plusieurs conditions

Re

Merci à vous cela fonctionne.

Bon Week-end

Bobjazz

 

[mapomme]

Re : Sommeprod plusieurs conditions

Re,

La colonne P contient des cellules apparemment vides mais qui en réalité contiennent le résultat d'une formule qui renvoie une chaine vide (chaine certes vide mais c'est néanmoins une chaine de caractères).

SOMMEPROD va donc effectuer un produit d'un nombre (le produit des deux premières parenthèses) avec une chaine de caractères et ça ne lui plaît pas.

Une deuxième forme (en fait sa définition) de SOMMEPROD est : SOMMEPROD(matrice1 ; matrice2 ; matrice3 ; ...)
Sous cette forme, SOMMEPROD accepte les chaines de caractères.

(Tout comme la fonction SOMME. =SOMME("aaa";1;4) renvoie 5 mais = "aaa" + 1 + 4 renvoie une erreur)

NB: si dans la formule de la colonne P, vous remplacez les "" par le chiffre 0, alors votre formule initiale SOMMEPROD retourne un résultat correct.

 

[bobjazz]

Re : Sommeprod plusieurs conditions

Merci pour la réponse

Bon week-end

Bobjazz