XL 2016 SOMME.SI.ENS ou

[desmonts]

Bonjour à toutes et tous,

J'essais de faire un somme.si.ens, dans une de mes colonnes critère je dois mettre 3 critères différent et la impossible, aurriez vous une solution.
La 1ère fonctionne si je veux avoir le montant total HT sur 2017, chez EQT ayant un statut "comptabilisé" (3 conditions dans 3 colonnes cela fonctionne.
SOMME.SI.ENS(Suivi!G:G;Suivi!A:A;"EQT";Suivi!D;2017;Suivi!F:F;"Comptabilisé")

Par contre si je veux avoir le montant total HT sur 2017, chez EQT ayant comme statut "En cours de validation" ou "document transmis" ou "Facture émise" et la je coince malgré plusieurs essais. Estce possible avec cette fonction ?

Merci d'avance

 

[Jocelyn]

Bonjour le Forum,
Bonjour desmonts,

avec somm.si.ens() je ne sais pas bien faire par contre avec un sommeprod() ca pourrait donner quelque chose comme

=sommeprod((Suivi!A:A="EQT")*(Suivi!D=2017)*((Suivi!F:F;"document transmis")+(Suivi!F:F;"En cours de validation")+(Suivi!F:F;"Facture émise"))*Suivi!G:G)

Cordialement

 

[desmonts]

Merci Jocelyn pour cette réponse rapide.
J'ai essayé mais il me met qu'il y une erreur qu'il faut mettre un '. Je m'arrache les cheveux, cela ne doit pas être grand chose, je suis pas très doué .

 

[job75]

Bonjour desmonts, Jocelyn,

Jocelyn a juste oublié les signes = :

=SOMMEPROD((Suivi!A:A="EQT")*(Suivi!D:D=2017)*((Suivi!F:F="document transmis")+(Suivi!F:F="En cours de validation")+(Suivi!F:F="Facture émise"));Suivi!G:G)

A+

 

[desmonts]

Merci à vous 2. Cela fonction top votre solution
je m'en étais sorti en additionnant de somme.si.ens mais bien moins éléguant
=SOMME.SI.ENS(Suivi!G:G;Suivi!A:A;"EQT";Suivi!D;2017;Suivi!F:F;"Facture émise")+SOMME.SI.ENS(Suivi!G:G;Suivi!A:A;"EQT";Suivi!D;2017;Suivi!F:F;"Document transmis")+SOMME.SI.ENS(Suivi!G:G;Suivi!A:A;"EQT";Suivi!D;2017;Suivi!F:F;"En cours de validation")

 

[Jocelyn]

re,

en faisant le copier collé j'ai oublier de changer les ; par des =

Cordialement

EDIT oup's Bonjour job 75

 

[Amilo]

Bonsoir,

je m'en étais sorti en additionnant de somme.si.ens mais bien moins éléguant

Une autre formule pour le fun :

=SOMME(SOMME.SI.ENS(Suivi!G:G;Suivi!A:A;"EQT";Suivi!D:D;2017;Suivi!F:F;{"document transmis";"En cours de validation";"Facture émise"}))

Cordialement