Somme de chiffres qui compose un mot (4 lettres)

starz

XLDnaute Occasionnel
Bonjour,
Pouvez vous m'aider à résoudre mon problème de formule auto.

Je souhaiterai calculer la somme des chiffres qui compose un mot de 4 lettres, par exemple M3G1 = 4 dans 2 cellules et affiché dans une autre cellule la somme la plus élevé des 2.

Si A2=4 et C2=2 alors B2=4 (car A2>C2)

Je joins un fichier pour faciliter la tâche.

Merci
 

Pièces jointes

  • MTS.xls
    17 KB · Affichages: 73
  • MTS.xls
    17 KB · Affichages: 74
  • MTS.xls
    17 KB · Affichages: 72

JBOBO

XLDnaute Accro
Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour,

Une solution basique avec un tableau annexe, pas des plus elegante mais qui fonctionne!
 

Pièces jointes

  • MTS.xls
    28 KB · Affichages: 54
  • MTS.xls
    28 KB · Affichages: 59
  • MTS.xls
    28 KB · Affichages: 56

KenDev

XLDnaute Impliqué
Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour Starz, Victor,

Avec l'hypothèse que les seuls cas possibles sont présent dans le fichier (c.à.d Lettre-Chiffre-Lettre-Chiffre OU Lettre-Chiffre OU vide) une autre proposition :
en B2 :
Code:
=MAX(CNUM(DROITE(GAUCHE(A2&REPT("0";4-NBCAR(A2));2);1))+CNUM(DROITE(A2&REPT("0";4-NBCAR(A2));1));CNUM(DROITE(GAUCHE(C2&REPT("0";4-NBCAR(C2));2);1))+CNUM(DROITE(C2&REPT("0";4-NBCAR(C2));1)))
Cordialement

KD

Edit : bonjour Jbobo
 

CHALET53

XLDnaute Barbatruc
Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour Starz, Victor,

Cela suppose (et c'est peut-être le cas) que les nombres soient toujours en position 2 et 4. Pour C3, la formule ne fonctionne pas : pas de valeur en position 4

Je propose une solution batarde avec des colonnes qui peuvent être cachées

Ou alors en VBA

a+
 

Pièces jointes

  • starz.xls
    26.5 KB · Affichages: 58
  • starz.xls
    26.5 KB · Affichages: 57
  • starz.xls
    26.5 KB · Affichages: 59

hoerwind

XLDnaute Barbatruc
Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour, salut les autres,

En B2 :
Code:
=MAX(SI(NBCAR(A2);STXT(A2;2;1);0)+SI(NBCAR(A2)>3;STXT(A2;4;1);0);SI(NBCAR(C2);STXT(C2;2;1);0)+SI(NBCAR(C2)>3;STXT(C2;4;1);0))
formule à copier vers le bas
 

Monique

Nous a quitté
Repose en paix
Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour,

à essayer :

Code:
=SOMME(SI(ESTNUM(STXT(A2;LIGNE(INDIRECT(1&":"&NBCAR(A2)));1)*1);STXT(A2;LIGNE(INDIRECT(1&":"&NBCAR(A2)));1)*1))

Formule matricielle, à valider par ctrl, maj et entrée
 

david84

XLDnaute Barbatruc
Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour,
en attendant plus court :
Code:
=MAX(SOMME(SI(ESTNUM(CHERCHE(1;A2));1);SI(ESTNUM(CHERCHE(2;A2));2);SI(ESTNUM(CHERCHE(3;A2));3);SI(ESTNUM(CHERCHE(4;A2));4);SI(ESTNUM(CHERCHE(5;A2));5);SI(ESTNUM(CHERCHE(6;A2));6);SI(ESTNUM(CHERCHE(7;A2));7);SI(ESTNUM(CHERCHE(8;A2));8);SI(ESTNUM(CHERCHE(9;A2));9));SOMME(SI(ESTNUM(CHERCHE(1;C2));1);SI(ESTNUM(CHERCHE(2;C2));2);SI(ESTNUM(CHERCHE(3;C2));3);SI(ESTNUM(CHERCHE(4;C2));4);SI(ESTNUM(CHERCHE(5;C2));5);SI(ESTNUM(CHERCHE(6;C2));6);SI(ESTNUM(CHERCHE(7;C2));7);SI(ESTNUM(CHERCHE(8;C2));8);SI(ESTNUM(CHERCHE(9;C2));9)))
A+

Edit : Ben Monique a fait plus court:), mais si j'ai bien compris, en adaptant la formule de Monique :
Code:
=MAX(SOMME(SI(ESTNUM(STXT(A2;LIGNE(INDIRECT(1&":"&NBCAR(A2)));1)*1);STXT(A2;LIGNE(INDIRECT(1&":"&NBCAR(A2)));1)*1));SOMME(SI(ESTNUM(STXT(C2;LIGNE(INDIRECT(1&":"&NBCAR(C2)));1)*1);STXT(C2;LIGNE(INDIRECT(1&":"&NBCAR(C2)));1)*1)))

ou sur 4 caractères

Code:
=MAX(SOMME(SI(ESTNUM(STXT(A2;{1;2;3;4};1)*1);STXT(A2;{1;2;3;4};1)*1));SOMME(SI(ESTNUM(STXT(C2;{1;2;3;4};1)*1);STXT(C2;{1;2;3;4};1)*1)))
 
Dernière édition:

starz

XLDnaute Occasionnel
Re : Somme de chiffres qui compose un mot (4 lettres)

Bonjour et merci à tous pour vos réponse !
J'ai testé la formule matricielle de Monique en premier et ça fonctionne.
Cependant, honte à moi, j'ai oublié une chose dans ma demande :
Il y a un coef multiplicateur à rajouter pour certaine ligne - bien souvent quand on doit multiplier on n'a pas besoin de comparer les cellules.

Je rejoins mon exemple à jour, je pense que c'est plus clair.

Merci

starz
 

Pièces jointes

  • MTS.xls
    17 KB · Affichages: 43
  • MTS.xls
    17 KB · Affichages: 48
  • MTS.xls
    17 KB · Affichages: 44

Discussions similaires

Statistiques des forums

Discussions
311 721
Messages
2 081 929
Membres
101 843
dernier inscrit
Thaly