Sélection d'un mois donne YTD

shroomers88

XLDnaute Nouveau
Bonjour,

Je suis à la recherche depuis un moment déjà de la façon de faire pour effectuer une somme de janvier jusqu'au mois sélectionné, ou encore year-to-date. La façon dont mon fichier fonctionne est la suivante :

-Feuilles des mois : entrée des données pas un usager. Le nombre de mois de mon vrai fichier ne s'arrête évidemment pas à Mars, mais pour être en mesure de "poster" mon fichier sur le site j'ai enlevé plusieurs feuilles.

-Feuille Stats YTD : permet de sélectionner le nom de la feuille qui correspond à un mois et d'obtenir les statistiques pour ce mois, selon les données saisies dans le mois en question. Je me sers de la fonction indirect pour trouver le nom de la feuille portant le nom d'un mois.

Ce que j'aimerais faire c'est de sélectionner un mois et que cela me donne la somme pour tous les mois antérieurs incluant le mois sélectionné. Exemple : je sélectionne Mars dans la cellule C6 et cela fait la somme de toutes les cellules pertinentes pour les mois antérieurs à Mars via la formule indirect ou autre. Ces formules sont contenues dans la feuille Stats YTD aux colonnes D, F, H, J et L.

Mon fichier est en PJ
 

Pièces jointes

  • Test_YTD.xlsx
    288.4 KB · Affichages: 59
  • Test_YTD.xlsx
    288.4 KB · Affichages: 67

shroomers88

XLDnaute Nouveau
Re : Sélection d'un mois donne YTD

Bonjour,

Merci pour le lien. J'ai été capable d'adapter les formules en D10 et D12 de sorte que mon calcul prend en compte les tous les mois en les mois X et Y sélectionné. Pour ce faire, j'utilise la formule pour une Somme 3D entre un mois de départ et un mois de fin comme expliqué dans le lien proposé, soit : =SOMMEPROD(SOMME.SI(INDIRECT(TEXTE(DATE(2006;LIGNE(INDIRECT(MOIS("1/"&B2)&":"&
MOIS("1/"&B3)));1);"mmmm")&"!A1:A10");">0")).

Par contre j'ai beaucoup de difficulté à adapter la formule en D13. Est-ce que je dois mettre SOMMEPROD comme premier argument ? C'est pourtant ce que je fais mais sans succès.

Merci encore pour l'aide donné!
 

chris

XLDnaute Barbatruc
Re : Sélection d'un mois donne YTD

Bonjour

J'ai finalement trouvé d'autres formules qui semblent fonctionner :

J'ai nommé

  • Lmois la liste des 12 mois de ton onglet liste déroulante
  • Lmois1 la cellule c2 de cette liste qui contient Janvier.

Code:
=SOMMEPROD(NB.SI(INDIRECT(DECALER(Lmois1;;;EQUIV(C$6;LMois;0))&"!$C10:$C$184");C$9))

=SOMMEPROD(SOMME.SI(INDIRECT(DECALER(Lmois1;;;EQUIV(C$6;LMois;0))&"!$C$10:$C$184");C$9;INDIRECT(DECALER(Lmois1;;;EQUIV(C$6;LMois;0))&"!$L$10:$L$184")))
 

shroomers88

XLDnaute Nouveau
Re : Sélection d'un mois donne YTD

Bonjour Chris,

La formule proposée ne me permet pas de faire ce que je souhaite. Pour être en mesure de calculer le YTD, j'ai ajouté un nouveau contrôle en D6 (voir fichier en pièce-jointe). Ce nouveau contrôle me permet d'arriver à mes fins pour les calculs en D11 et D13 avec la formule suivante quelque peu modifié : =SOMMEPROD(SOMME.SI(INDIRECT(TEXTE(DATE(2006;LIGNE(INDIRECT(MOIS("1/"&B2)&":"&
MOIS("1/"&B3)));1);"mmmm")&"!A1:A10");">0")) . Les formules exactes sont dans le fichier et cela correspond à la formule "Somme 3D entre un mois de départ et un mois de fin" du lien mentionné ci-dessus dans la conversation.

Par contre, je ne suis pas en mesure d'adapter la formule pour la cellule D14, D17 à D26 et les cellules des colonnes C à L pour les lignes 41 à 42. Je souhaiterais procéder sans définir de noms, mais si ce n'est pas possible je nommerai les champs nécessaires. Je crois que je ne saisis pas bien ce que SOMMEPROD fait ou j'ai besoin de voir exactement la formule pour au moins les champs D14 et C42 qui m'éclairerait sûrement un peu.

Merci !
 

Pièces jointes

  • Test_YTD.xlsx
    255.4 KB · Affichages: 46
  • Test_YTD.xlsx
    255.4 KB · Affichages: 45

chris

XLDnaute Barbatruc
Re : Sélection d'un mois donne YTD

Bonjour

Un YTD part de janvier sauf si l'année de l'entreprise n'est pas calendaire donc j'ai gardé début en janvier.

Mes formules, plus courtes, adaptées à tes changements semblent fonctionner. Voir en jaune dans le classeur joint.
 

Pièces jointes

  • Test_YTD3.xlsx
    265.5 KB · Affichages: 58

Tlse31

XLDnaute Nouveau
Re : Sélection d'un mois donne YTD

Salut Chris,
Besoin urgent de votre précieuse aide.
Je voudrais créer une formule me permettant de calculer le montant total réalisé pour le mois sur une année, en fonction du numero de compte(cell B3), l'année (cell B7...) et le mois (cell A8....).
J'ai entré les infos dans la macro en fonction de celle contenues dans la base de donnée access.
 

shroomers88

XLDnaute Nouveau
Re : Sélection d'un mois donne YTD

Bonjour Chris,

Décidément, j'ai de la difficulté à comprendre les fonctions que tu utilises... J'aimerais bien comprendre ou du moins en arriver à faire mes calculs. Pour la cellule D17, je ne suis pas capable de la modifier pour arriver au résultat souhaité. J'essaie la formule : =SOMMEPROD(NB.SI.ENS(INDIRECT(DECALER(ListeDéroulante!$C$2;;;EQUIV($C$6;ListeDéroulante!$C$2:$C$13;0))&"!$h10:$h$184");INDIRECT(DECALER(ListeDéroulante!$C$2;;;EQUIV($C$6;ListeDéroulante!$C$2:$C$13;0))&"!$h10:$h$184")<>0;INDIRECT(DECALER(ListeDéroulante!$C$2;;;EQUIV($C$6;ListeDéroulante!$C$2:$C$13;0))&"!$C10:$C$184");$C$10)) et ça ne fonctionne pas...

Pareillement pour la cellule C40, C41 ou C42... je n'y arrive tout simplement pas.

Pour celle que tu m'as retourné j'ai bêtement recopié en réutilisant le même format et changeant les références et ça fonctionne bien. Si tu peux je prendrais bien encore un coup de pouce au moins pour D17 et l'une des trois autres de C40 à C42.

Merci beaucoup, ton aide est fort appréciée!
 

shroomers88

XLDnaute Nouveau
Re : Sélection d'un mois donne YTD

J'essaie aussi cette formule en D17 et ça ne veut vraiment pas fonctionner.... =SOMMEPROD(NB.SI.ENS(INDIRECT(DECALER(ListeDéroulante!$C$2;;;EQUIV($C$6;ListeDéroulante!$C$2:$C$13;0))&"!$h10:$h$184");<>0;INDIRECT(DECALER(ListeDéroulante!$C$2;;;EQUIV($C$6;ListeDéroulante!$C$2:$C$13;0))&"!$C10:$C$184");$C$9))
 

shroomers88

XLDnaute Nouveau
Re : Sélection d'un mois donne YTD

J'ai aussi essayé ça sans succès :

=SOMMEPROD(NB.SI.ENS(INDIRECT(DECALER(ListeDéroulante!$C$2;;;EQUIV($C$6;ListeDéroulante!$C$2:$C$13;0))&"!$C10:$C$184");ListeDéroulante!$A$2;INDIRECT(DECALER(ListeDéroulante!$C$2;;;EQUIV($C$6;ListeDéroulante!$C$2:$C$13;0))&"!$H10:$H$184");""))
 

chris

XLDnaute Barbatruc
Re : Sélection d'un mois donne YTD

Bonjour

D17 :
Code:
=SOMMEPROD(NB.SI.ENS(INDIRECT(DECALER(LMois1;;;EQUIV($D$6;LMois;0))&"!$C10:$C$184");C$10;INDIRECT(DECALER(LMois1;;;EQUIV($D$6;LMois;0))&"!$h10:$h$184");"<>"))

Pour le reste je n'ai pas le temps ce matin
 

shroomers88

XLDnaute Nouveau
Re : Sélection d'un mois donne YTD

Bonjour Chris, j'ai essayé la formule suivante en C40 (ainsi que plusieurs déclinaisons) mais elle ne fonctionne pas :

=SI(SOMMEPROD(NB.SI(INDIRECT(DECALER(ListeDéroulante!$C$2;;;EQUIV($C$6;ListeDéroulante!$C$2:$C$13;0))&"!$C$10:$C$184");ListeDéroulante!$A$2<>""));SOMME($D$30:$D$38)/SOMMEPROD(NB.SI(INDIRECT(DECALER(ListeDéroulante!$C$2;;;EQUIV($C$6;ListeDéroulante!$C$2:$C$13;0))&"!$C$10:$C$184");ListeDéroulante!$A$2));0)

Pourtant ça semble tenir la route mais la réponse donne 0 alors qu'elle devrait donné 100$ selon les données des feuilles Janvier et Février.
 

shroomers88

XLDnaute Nouveau
Re : Sélection d'un mois donne YTD

Salut Chris, j'ai finalement été en mesure de résoudre tous les problèmes de mon classeur! J'ai dû décanter chacune des formules mais je comprends maintenant bien la manipulation. Il ne me reste qu'à m'exercer un peu avec encore pour la maîtrise à 100%. Merci encore pour ton aide, c'est très apprécié!
 

chris

XLDnaute Barbatruc
Re : Sélection d'un mois donne YTD

RE

Entre temps j'ai trouver ceci pour C41
Code:
=SOMMEPROD(SOMME.SI(INDIRECT(DECALER(LMois1;;;EQUIV($D$6;LMois;0))&"!$C$10:$C$184");C$10;INDIRECT(DECALER(LMois1;;;EQUIV($D$6;LMois;0))&"!$M$10:$M$184")))/SOMMEPROD(NB.SI.ENS(INDIRECT(DECALER(LMois1;;;EQUIV($D$6;LMois;0))&"!$C$10:$C$184");C$10;INDIRECT(DECALER(LMois1;;;EQUIV($D$6;LMois;0))&"!$M$10:$M$184");"<>"))

Comme c'est fait...
 

Discussions similaires

Réponses
46
Affichages
630
Réponses
14
Affichages
639

Statistiques des forums

Discussions
311 711
Messages
2 081 789
Membres
101 817
dernier inscrit
carvajal