Microsoft 365 Restitution d'une liste de valeurs avec des critères variables à partir d'une matrice

[ThierryT]

Bonjour
Il est probable que la réponse à mon problème ai déjà été fournie, mais je n'arrive pas à trouver la solution exacte sur le forum. je vous remercie grandement par avance pour toute aide à la résolution de mon problème suivant :

dans l'onglet 1 se trouvent mes données brutes sous la forme :
- nom des élèves en colonne 1
- jours en ligne 1
- un chiffre pour chaque intersection L/C qui indique si l'élève est présent et à quel groupe de travail il est affecté
Dans l'onglet 2, je cherche à faire apparaitre automatiquement la liste des élèves affectés groupe par groupe, en fonction du jour sélectionné (ma variable d'affichage)
==> Cf le fichier xls en PJ

J'ai tenté de résoudre le sujet par la fonction INDEX + EQUIV et je ne parvient pas au résultat voulu (soit il m'affiche une erreur, soit il m'affiche le contenu de la colonne correspondant au jour sélectionné, mais il ne m'affiche pas une liste restreinte des élèves qui répondent aux critères voulus). J'ai également creusé via RECHERCHEX mais sans résultat.

Bref, est ce que qqun aurait une idée de la bonne façon de résoudre ce sujet, que ce soit via macro ou via formule directe)

Un grand merci par avance !

 

[R@chid]

Bonjour et Bienvenue sur XLD,

Toutes les versions d'Excel à partir de 2007
En N8 :

=SIERREUR(INDEX($B$5:$B$19;PETITE.VALEUR(SI(DECALER($B$5:$B$19;;EQUIV($P$4;$C$4:$L$4;0))=COLONNES($N:N);LIGNE(INDIRECT("1:"&LIGNES($B$5:$B$19))));LIGNES($8:8)));"")

@ valider par Ctrl+Maj+Entrée (Sauf si tu es sous Excel pour Microsoft 365)
@ tirer vers le bas et vers la droite


Excel pour Microsoft 365
En N8 :

=FILTRE($B$5:$B$19;DECALER($B$5:$B$19;;EQUIV($P$4;$C$4:$L$4;0))=COLONNES($N:N))

@ tirer vers la droite


Cordialement

 

[ThierryT]

Bonjour et Bienvenue sur XLD,

Toutes les versions d'Excel à partir de 2007
En N8 :

=SIERREUR(INDEX($B$5:$B$19;PETITE.VALEUR(SI(DECALER($B$5:$B$19;;EQUIV($P$4;$C$4:$L$4;0))=COLONNES($N:N);LIGNE(INDIRECT("1:"&LIGNES($B$5:$B$19))));LIGNES($8:8)));"")

@ valider par Ctrl+Maj+Entrée (Sauf si tu es sous Excel pour Microsoft 365)
@ tirer vers le bas et vers la droite


Excel pour Microsoft 365
En N8 :

=FILTRE($B$5:$B$19;DECALER($B$5:$B$19;;EQUIV($P$4;$C$4:$L$4;0))=COLONNES($N:N))

@ tirer vers la droite


Cordialement

Bonjour R@chid !
Un très grand merci pour la rapidité et la qualité de votre réponse, cela marche parfaitement et m'a fait économisé bcp de temps !!