XL 2016 [Résolu] Modifier les propriétés d'un document

[Sonia31]

Bonjour,
J'ai recherché en vain des pistes de solution sur ma question, c'est pourquoi je crée une nouvelle discussion.

Je cherche à modifier via macro Excel les propriétés du document, notamment le fait de cocher ou pas le mode lecture seule (cf Pj pour clarifier).

Savez-vous s'il est possible de faire cela? Si oui, comment?

 

[Bernard_XLD]

Bonjour

Voici un code qui fait cela.

Bien cordialement, @+

Sub Fichier_en_Lecture_Seule()
    Dim Nom_Fichier As String, Objet_Fichier As Variant, Fichier_a_Modifier As Variant
    'initialisation dialogue pour choix du fichier
    With Application.FileDialog(msoFileDialogFilePicker)
        .ButtonName = "Modifier"
        .AllowMultiSelect = False
        .InitialFileName = ThisWorkbook.Path & "\*"
        .Title = "Choisissez le fichier à modifier"
        .Filters.Clear
        .Filters.Add "Fichiers Excel", "*.xlsm; *.xlsx", 1
        .Show
        If .SelectedItems.Count > 0 Then
            Nom_Fichier = .SelectedItems(1)
        Else
            MsgBox "pas de fichier sélectionné", vbOKOnly + vbInformation
            Exit Sub
        End If
    End With
    'Création de l'objet fichier
    Set Objet_Fichier = CreateObject("scripting.filesystemobject")
    Set Fichier_a_Modifier = Objet_Fichier.getfile(Nom_Fichier)
    'modification de l'attribut en lecture seule
    Fichier_a_Modifier.Attributes = 1
    Set Objet_Fichier = Nothing
    Set Fichier_a_Modifier = Nothing
End Sub

 

[job75]

Bonjour Sonia31, Yeahou,

Sub a()
SetAttr ActiveWorkbook.FullName, vbReadOnly
End Sub

https://www.mediaforma.com/vba-excel-modifier-lire-attributs-fichiers/

A+

 

[Bernard_XLD]

Bonjour job75

Tiens, je la connaissais pas celle la !
merci

Cordialement, @+

 

[Sonia31]

Bonjour,

Merci à tous les 2, cela fonctionne parfaitement !

Bien à vous,

Sonia