XL 2013 [RESOLU]Macro conversion PDF fichier WORD (depuis excel)

kaozuin

XLDnaute Nouveau
Bonjour à tous,

J'ai une nouvelle fois besoin de vos lumière (ou aide :))

J'ai un fichier, où avec une macro j'obiten les liens de fichier word et je souhaite, via une macro ouvrir ces fichiers pour les "publier (ou enregistrer) au format PDF dans le même répertoire que la source.

Ci joint un fichier Excel où j'ai ma macro d'extraction de liens.

Auriez vous cela en réserve ? :)

En vous remerciant d'avance.
 

Pièces jointes

  • Extract fichier dossier.xlsm
    19.8 KB · Affichages: 39

job75

XLDnaute Barbatruc
Bonjour kaozuin,

Vous n'avez pas de réponse parce que ce n'est pas clair.

S'il s'agit simplement de créer un document PDF à partir d'un document Word :
Code:
Sub PDF_Word()
Dim chemin$, doc$, pdf$, Wapp As Object
chemin = ThisWorkbook.Path & "\" 'à adapter
doc = "Mon document.docx" 'à adapter
pdf = Left(doc, InStrRev(doc, ".") - 1) & ".pdf"
Application.DisplayAlerts = False 'si le fichier Word est ouvert
On Error Resume Next
Set Wapp = GetObject(, "Word.Application")
If Wapp Is Nothing Then Set Wapp = CreateObject("Word.Application")
With Wapp.Documents.Open(chemin & doc)
    .ExportAsFixedFormat chemin & pdf, ExportFormat:=17 '17 => wdExportFormatPDF
    .Close False
    If Wapp.Documents.Count = 0 Then Wapp.Quit
End With
End Sub
Téléchargez les fichiers zippés joints dans le même dossier.

A+
 

Pièces jointes

  • PDF Word(1).zip
    29.3 KB · Affichages: 30

kaozuin

XLDnaute Nouveau
Re bonjour,

Je réouvre le sujet car j'ai un petit souci avec cette macro !

Je souhaiterais que cette dernière enchaine les conversion j'ai bien les bons lien / info mais on dirait que la conversion est ''sautée'' !

Avez vous une idée d'où cela peut il venir ?
 

kaozuin

XLDnaute Nouveau
Ha pardon je n'avais pas vue cette ligne :)

Ci joint un exemple :

il faut d'abord aller dans l'éditeur marco / Feuille 1 et modifier manuellement le chemin du dossier à analyser
puis lancer l'analyse (ce qui exterait les infos)
puis lancer la macro du module 1 ( ta macro que j'ai un peu modifier).
 

Pièces jointes

  • PDF auto.zip
    101.5 KB · Affichages: 14

job75

XLDnaute Barbatruc
J'ai supprimé votre code, bien trop compliqué et en plus inutile, voici ma macro complétée :
Code:
Sub PDF_Word()
Dim chemin$, doc$, Wapp As Object, pdf$
chemin = ThisWorkbook.Path & "\" 'à adapter
doc = Dir(chemin & "*.docx") '1er document du dossier
Application.DisplayAlerts = False 'si un document Word est ouvert
On Error Resume Next
Set Wapp = GetObject(, "Word.Application")
If Wapp Is Nothing Then Set Wapp = CreateObject("Word.Application")
While doc <> ""
    pdf = Left(doc, InStrRev(doc, ".") - 1) & ".pdf"
    With Wapp.Documents.Open(chemin & doc)
        .ExportAsFixedFormat chemin & pdf, ExportFormat:=17 '17 => wdExportFormatPDF
        .Close False
    End With
    doc = Dir 'document suivant du dossier
Wend
If Wapp.Documents.Count = 0 Then Wapp.Quit
End Sub
 

Pièces jointes

  • PDF auto(1).zip
    98 KB · Affichages: 34
Dernière édition:

kiki29

XLDnaute Barbatruc
Salut, via Acrobat ( pas le Reader )
Sauvegarder un fichier PDF au format TEXTE via VBA Excel avec "com.adobe.acrobat.doc" ou "com.adobe.acrobat.docx"

VB:
Option Explicit

Sub PDF2Word()
Dim Acro As Object
Dim AVdoc As Object
Dim PDDoc As Object
Dim JSO As Object
Dim sSource As String
Dim sDest As String
Dim sExt As String
Dim Deb As Currency

    Deb = Timer
    Application.StatusBar = ""
   
    sExt = "doc"
    sSource = ThisWorkbook.Path & "\" & "Test.pdf"
    sDest = Replace(sSource, ".pdf", "." & sExt, 1)

    Set Acro = CreateObject("AcroExch.App")
    Set AVdoc = CreateObject("AcroExch.AVDoc")

    If AVdoc.Open(sSource, vbNull) = True Then
        Set PDDoc = AVdoc.GetPDDoc
        Set JSO = PDDoc.GetJSObject
        JSO.SaveAs sDest, "com.adobe.acrobat." & sExt
    End If

    AVdoc.Close False

    Acro.Exit
    Set AVdoc = Nothing
    Set Acro = Nothing
   
    Application.StatusBar = "Terminé : " & Format(Timer - Deb, "0.000 s")
End Sub
 

Pièces jointes

  • Sans titre-1.png
    Sans titre-1.png
    196.8 KB · Affichages: 16
Dernière édition:

Discussions similaires

Statistiques des forums

Discussions
311 709
Messages
2 081 774
Membres
101 816
dernier inscrit
Jfrcs