XL 2013 [RESOLU]Macro conversion PDF fichier WORD (depuis excel)

[kaozuin]

Bonjour à tous,

J'ai une nouvelle fois besoin de vos lumière (ou aide )

J'ai un fichier, où avec une macro j'obiten les liens de fichier word et je souhaite, via une macro ouvrir ces fichiers pour les "publier (ou enregistrer) au format PDF dans le même répertoire que la source.

Ci joint un fichier Excel où j'ai ma macro d'extraction de liens.

Auriez vous cela en réserve ?

En vous remerciant d'avance.

 

[kiki29]

Re,@jui42, je ne possède pas de bdc, désolé .....

 

[jui42]

Bonjour le fil ,
Pour ceux qui chercherais, voici une fonction permettant de convertir tout les pdf contenus dans un dossier en document word. Code à placer dans un word projet

Cdt

Sub Main()
    
    Dim Source_Folder_Path As String, Target_Folder_Path As String
    Dim File_Names As String
    Dim doc As Document
    
    '// Step 1. Assign Folder Paths
    Source_Folder_Path = "votre chemin ou se trouve les pdf"
    Target_Folder_Path = "votre chemin ou vous voulez que les word se crée"
    
    If Right(Source_Folder_Path, 1) <> "\" Then
        Source_Folder_Path = Source_Folder_Path & "\"
    End If
    
    If Right(Target_Folder_Path, 1) <> "\" Then
        Target_Folder_Path = Target_Folder_Path & "\"
    End If
    
    '// Step 2. Grad all the PDF files
    
    File_Names = Dir(Source_Folder_Path & "*.pdf")
    
    Application.DisplayAlerts = wdAlertsNone
    
    Do While File_Names <> ""
        
        Set doc = Documents.Open(Source_Folder_Path & File_Names, False)
        
        '// Convert the PDF file to Word Doc
        doc.SaveAs2 Target_Folder_Path & Replace(File_Names, ".pdf", ".docx"), wdFormatDocumentDefault
        doc.Close False
        
        Set doc = Nothing
        
        File_Names = Dir()
    Loop
    
    Application.DisplayAlerts = wdAlertsAll
    
    MsgBox "Conversion is finished"
End Sub

 

[job75]

Bonjour jui42,

C'est très bien et c'est nouveau pour moi, merci.

Mais puisque nous sommes sur un forum Excel utilisez cette macro dans un fichier Excel :

Sub Concersion_PDF_Word()
Dim chemin$, fichier$, Wapp As Object, Wdoc As Object
chemin = ThisWorkbook.Path & "\" 'dossier à adapter éventuellement
fichier = Dir(chemin & "*.pdf") '1er fichier du dossier
Set Wapp = CreateObject("Word.Application")
Wapp.Visible = True
Wapp.DisplayAlerts = False 'wdAlertsNone
While fichier <> ""
    Set Wdoc = Wapp.Documents.Open(chemin & fichier)
    Wdoc.SaveAs2 chemin & Replace(fichier, ".pdf", ".docx"), 16 'wdFormatDocumentDefault
    Wdoc.Close False
    fichier = Dir 'fichier suivant
Wend
Wapp.Quit
MsgBox "Conversion terminée"
End Sub

A+

 

[jui42]

Salut @job75 en effet c'est plus cohérent Merci pour la trad en Excel