(Resolu)Format Date dans plusieur Textbox dans multipage

[chaelie2015]

BONJOUR FORUM
JE RELANCE mon sousci dans une nouvelle discussion
j'ai un multi page de 08 pages et chaque page contient 09 TextBox
je souhaite saisir des date dans ces TextBox pour l’ensemble des TextBOX
salutations
NB/ Merci par avance PIERROT

 

[Pierrot93]

Re : Format Date dans plusieur Textbox dans multipage

Bonjour,

tu aurais du rester sur le même fil.... pas top de doublonner les discussions pour un meme sujet.... Alors je ne ferais qu'un seul essai avec module de classe, n'ayant point de fichier...

dans le module de l'userform :

Option Explicit
Private MesTexBox() As New Classe1
Private Sub UserForm_Initialize()
Dim ctrl As Control, i As Byte
For Each ctrl In Me.Controls
    If TypeOf ctrl Is MSForms.TextBox Then
        ReDim Preserve MesTexBox(0 To i)
        Set MesTexBox(i).tb = ctrl
        ctrl.MaxLength = 10
        i = i + 1
    End If
Next ctrl
End Sub

dans un module de classe :

Option Explicit
Public WithEvents tb As MSForms.TextBox
Private Sub tb_Change()
Dim t
If tb = "" Then Exit Sub
If Len(tb) = 2 Or Len(tb) = 5 Then tb = tb & "/"
If Len(tb) = 10 Then
    If Not IsDate(tb) Then GoTo fin
    t = Split(tb, "/")
    If CInt(t(1)) > 12 Or CInt(t(0)) > Day(DateSerial(CInt(t(2)), CInt(t(1)) + 1, 0)) Then GoTo fin
End If
Exit Sub
fin:
MsgBox "saisie erronée": tb = ""
End Sub
Private Sub tb_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
If InStr("0123456789", Chr(KeyAscii)) = 0 Then KeyAscii = 0
End Sub

bonne journée
@+

 

[chaelie2015]

Re : Format Date dans plusieur Textbox dans multipage

Bonjour PIERROT
COOL, ça fonctionne parfaitement c'est nickel, merci beaucoup PIERROT.
il reste un petit souci, après avoir testé la date 12/13/15 et non pas 12/13/20015 , le code n'a pas réagi ???
SALUTATIONS

 

[Pierrot93]

Re : Format Date dans plusieur Textbox dans multipage

Re,

12/13/15 et non pas 12/13/20015 , le code n'a pas réagi ???

regarde bien le code... il faut saisir obligatoirement 10 caractères...

 

[chaelie2015]

Re : Format Date dans plusieur Textbox dans multipage

Re,
Oky merci
PBLM RESOLU
SALUTATIONS