XL 2013 [Résolu] Extraire valeurs d'un tableau

[TooFatBoy]

Bonjour,

Je voudrais, à l'aide d'une formule, reporter dans mon tableau "Bilan annuel" le montant correspondant à chacun des 12 mois de l'autre tableau de ma feuille.

Dans la colonne "Montant", pour chacun des 12 mois, il n'y a qu'une seule cellule contenant un nombre ; les autres cellules contiennent "".

 

[TooFatBoy]

Ca faisait deux jours que je cherchais, et il a suffit que je pose la question pour que je trouve une formule qui semble fonctionner :
=SOMME.SI.ENS($E2:$E48;$B2:$B48;G3;$E2:$E48;"<>")

Y a-t-il mieux ?

 

[JHA]

Bonjour à tous,

Je pense que personne ne veut se refaire le tableau pour te donner une autre solution.
Peux tu joindre le fichier excel au lieu d'une image?

JHA

 

[JCGL]

Bonjour à tous,

Tu as aussi en G4 et vers la droite :

=SOMMEPROD(($B$3:$B$48=G$3)*$E$3:$E$48)

ou un TCD

A+ à tous

 

[TooFatBoy]

Merci JCGL, mais ça ne fonctionne pas, apparemment à cause des cellules qui contiennent "". Mais si je remplace les "" par des 0 (zéro) alors ça fonctionne bien.

Y a-t-il une astuce pour qu'une telle formule fonctionne même si elle rencontre du texte au lieu d'une valeur numérique ?

 

[Shakki]

Bonjour,

Un SOMME.SI devrait suffire il me semble.

=SOMME.SI($B2:$B48;G3;$E2:$E48)

A+

 

[TooFatBoy]

En effet, ça marche très bien avec SOMME.SI.
Merci Shakki.

 

[TooFatBoy]

Les trois formules fonctionnent (*) et me plaisent bien, mais je pense que celle de Shakki est la moins gourmande en ressources donc c'est celle que je vais adopter.
Merci à vous trois.


(*) La formule de JCGL nécessite (chez moi) de n'avoir que des valeurs numériques dans la colonne "Montant".
D'ailleurs si quelqu'un sait comment faire fonctionner ce genre de formule même s'il y a du texte dans la colonne "Montant", je suis toujours preneur.

 

[JCGL]

Bonjour à tous,

Fonctionne chez moi avec la transposition de ton image....
Pas facile de faire du XL avec une image. Bis repetita. Merci JHA...

A+ à tous

 

[Shakki]

Re,

Perso, je n'ai jamais trouvé la parade avec les "" quand j'utilise SOMMEPROD. Enfin si, je fais comme toi, je remplace les "" par des 0.

Si quelqu'un sait comment faire directement par formule, ça m'intéresse aussi.

A+

 

[JCGL]

Bonjour à tous,

Pour les "" :

=SOMMEPROD(($B$3:$B$48=G$3)*($E$3:$E$48<>"")*$E$3:$E$48)

Pas certain que cela change grand chose....

A+ à tous

 

[TooFatBoy]

Hélas non, ça ne change rien chez moi, ça ne fonctionne toujours pas.

Mais ce n'est pas grave. Merci d'avoir essayé.

 

[TooFatBoy]

Perso, je n'ai jamais trouvé la parade avec les "" quand j'utilise SOMMEPROD. Enfin si, je fais comme toi, je remplace les "" par des 0.

Si quelqu'un sait comment faire directement par formule, ça m'intéresse aussi.

J'ai bien sûr aussi pensé aux 0 (zéro), mais dans ce cas précis de "gestion de compte", je ne peux pas remplacer un "" par un zéro car pour moi un "" veut dire qu'il n'y a pas de valeur calculée dans la cellule concernée alors qu'un zéro veut dire qu'il y a un calcul et que le résultat est zéro.


Ceci dit, il me semble que quelqu'un m'avait donné une astuce il y a quelques années, mais j'ai beau chercher dans ma mémoire je n'ai pas le moindre début de commencement de mémoire de cette astuce...

 

[TooFatBoy]

Shakki, voyant que je n'étais pas le seul à chercher une solution au problème de textes venant s'incruster au milieu des valeurs numériques, ça m'a forcé à relever le défi et je crois bien que c'est réussi...

Chez moi ça fonctionne parfaitement, bien qu'il y ait des valeurs numériques et du texte (en fait des "") dans la colonne "Montant" (colonne E).
Pour rappel, voici d'abord la formule initiale qui ne fonctionne pas chez moi :
=SOMMEPROD(($B$2:$B$48=G$3)*$E2:$E48)
Et maintenant voici la formule magique qui fonctionne malgré la présence de texte :
=SOMMEPROD(--($B$2:$B$48=G$3);($E2:$E48))

Ce n'est bien sûr pas moi qui ait trouvé l'astuce. Je l'ai prise sur le site de monsieur Boisgontier.

 

[JCGL]

Bonjour à tous,

Peux-tu essayer ceci dans ton fichier :

=SOMMEPROD(($B$3:$B$48=G$3)*($E$3:$E$48<>"");$E$3:$E$48)

A+ à tous