[Résolu] Colorer une cellule en fonction d'une autre colorée

[anthonygg]

Bonjour,

J'aimerai que lorsque que je colorie une cellule en jaune dans la colonne A cela colorie aussi la même cellule de la colonne C.

Est ce possible ?

Merci

 

[Staple1600]

Re : Colorer une cellule en fonction d'une autre colorée

Bonjour à tous

anthonygg
Voir en bas de page les discussions similaires.

NB: Prendre le réflexe également de suivre le point 1) de la charte (section demandeur)
Cela te fera gagner du temps.

 

[anthonygg]

Re : Colorer une cellule en fonction d'une autre colorée

Oui j'ai bien regardé les 7-8 topics avant de poster ... :/
Hélàs je n'ai rien trouvé de concluant à part le fait que c'est très difficile à mettre en place car Excel ne peut pas prendre la couleur d'une autre cellule.

Je me suis quand même permis de poster pour voir si quelqu'un avait une solution.

 

[Staple1600]

Re : Colorer une cellule en fonction d'une autre colorée

Re

Tu la colories en jaune de quelle manière ta cellule en colonne A ?
Tu envisages l'emploi du VBA ?
Un début de piste
(code à mettre dans le code de la feuille concernée (et pas dans un module standard))
Pour tester, colorie en jaune une cellule en A, change de cellule et re-sélectionnes la cellule que tu viens de colorer.
Et observes ce qui se passe en colonne C.

Private Sub Worksheet_SelectionChange(ByVal T As Range)
If T.Interior.ColorIndex = 6 Then
T.Offset(, 3).Interior.ColorIndex = 6
End If
End Sub

NB: Faire des recherches avant de poser sa question, le signaler c'est mieux
Et cela m'évite de poster un message superflu

 

[anthonygg]

Re : Colorer une cellule en fonction d'une autre colorée

Grace à une formule VBA, ma touche F1 permet de colorier en jaune
Le but c'est que quand je colorie une ou plusieurs cellules de la colone A cela la colorie aussi pour la colone C

Voici un fichier qui explique mieux ce que je veux je l'espère:

 

[Staple1600]

Re : Colorer une cellule en fonction d'une autre colorée

Re

J'ai édité mon précédent message et ajouté un bout de code VBA
Regardes ce que cela t'inspire.

Le plus simple serait sans doute de passer par une mise en forme conditionnelle.

EDITION: Bonjour Si...

 

[Si...]

Re : Colorer une cellule en fonction d'une autre colorée

salut

tout dépend de ce que tu envisages de faire !
Avec la couleur seulement en cliquant sur F1 ou F3 (j'éviterais), change tes macros et adapte les selon ton choix

Dim R as Range 'en début de page
Sub jaune()
  If ActiveCell.Column > 1 Then Exit Sub
  Selection.Interior.ColorIndex = 6
  'si les cellules sont contigües,supprimer l'apostrophe en début de la ligne ci-dessous
   'Selection(1, 3).Resize(Selection.Count).Interior.ColorIndex = 6
   'si elles sont dispersées, supprimer l'apostrophe en début de la ligne ci-dessous
   'For Each R In Selection: R(1, 3).Interior.ColorIndex = 6: Next
End Sub

Sub blanc()
  If ActiveCell.Column > 1 Then Exit Sub
  'si les cellules sont contigües, supprimer l'apostrophe en début de la ligne ci-dessous
   'Selection.Interior.ColorIndex = 2
   'si elles sont dispersées, supprimer l'apostrophe en début de la ligne ci-dessous
   'Selection(1, 3).Resize(Selection.Count).Interior.ColorIndex = 2
End Sub

Si tu colores avec le "Forrmat" de cellule, passe par une évènementielle !

Si tu colores avec une MFC comme le pense Staple , passe la "Mise en forme conditionnelle" !

 

[job75]

Re : Colorer une cellule en fonction d'une autre colorée

Bonjour anthonygg, Jean-Marie, Si...

Puisqu'on utilise les touches F1 et F3 il est simple de colorier la colonne C en même temps que la colonne A :

Private Sub Workbook_Open()
'La touche F1 colorie en jaune, la touche F3 en blanc
    Application.OnKey "{F1}", "ThisWorkbook.jaune"
    Application.OnKey "{F3}", "ThisWorkbook.blanc"
 End Sub

Sub jaune() 'Couleur jaune
    ActiveCell.Activate 'au cas où un objet serait sélectionné
    Selection.Interior.ColorIndex = 6
    If Not Intersect(Selection, [A:A]) Is Nothing Then _
      Intersect(Intersect(Selection, [A:A]).EntireRow, [C:C]).Interior.ColorIndex = 6
End Sub

Sub blanc() 'Couleur blanche
    ActiveCell.Activate 'au cas où un objet serait sélectionné
    Selection.Interior.ColorIndex = 2 'pourquoi pas = xlNone ???
    If Not Intersect(Selection, [A:A]) Is Nothing Then _
      Intersect(Intersect(Selection, [A:A]).EntireRow, [C:C]).Interior.ColorIndex = 2
End Sub

A+

 

[anthonygg]

Re : Colorer une cellule en fonction d'une autre colorée

Bonjour anthonygg, Jean-Marie, Si...

Puisqu'on utilise les touches F1 et F3 il est simple de colorier la colonne C en même temps que la colonne A :

Private Sub Workbook_Open()
'La touche F1 colorie en jaune, la touche F3 en blanc
    Application.OnKey "{F1}", "ThisWorkbook.jaune"
    Application.OnKey "{F3}", "ThisWorkbook.blanc"
 End Sub

Sub jaune() 'Couleur jaune
    ActiveCell.Activate 'au cas où un objet serait sélectionné
    Selection.Interior.ColorIndex = 6
    If Not Intersect(Selection, [A:A]) Is Nothing Then _
      Intersect(Intersect(Selection, [A:A]).EntireRow, [C:C]).Interior.ColorIndex = 6
End Sub

Sub blanc() 'Couleur blanche
    ActiveCell.Activate 'au cas où un objet serait sélectionné
    Selection.Interior.ColorIndex = 2 'pourquoi pas = xlNone ???
    If Not Intersect(Selection, [A:A]) Is Nothing Then _
      Intersect(Intersect(Selection, [A:A]).EntireRow, [C:C]).Interior.ColorIndex = 2
End Sub

A+

T'es un sacré pro ! Bravo. Cette idée me trottais dans la tête depuis longtemps ... Enfin c'est réalisé MERCI MERCI ! *_*