XL 2010 Renvoi cellule même valeurs après double clic ( Résolu )

[Kael_88]

Le forum,

Les gens du savoir, je fais appel à vous sur un problème ou je sèche lamentablement,

quand je double clic dans la feuil2 sur une cellule, je voudrai me retrouver sur la cellule avec la même valeur dans la feuil1.

Cordialement

 

[Staple1600]

Bonsoir le filo, le forum

@Kael_88
Un essai basique
(à mettre dans le code de la feuille 2=> Clic-droit sur onglet->Visualiser code)

Private Sub Worksheet_BeforeDoubleClick(ByVal R As Range, Cancel As Boolean)
Set v = Feuil1.Cells.Find(R.Text, Feuil1.Cells(1, 1))
On Error Resume Next
Application.Goto Feuil1.Range(v.Address)
End Sub

 

[mapomme]

Bonsoir @Kael_88, @Staple1600,

Un autre essai mais on recherche à partir de la fin de la colonne D sur Feuil1.

 

[job75]

Bonsoir Kael_88, JM, mapomme,

A priori il faut concaténer les textes avec les nombres à droite car il y a des doublons :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Row < 7 Or Target.Column <> 7 Then Exit Sub
Dim c As Range
Cancel = True
With Sheets("Feuil1") 'nom à adapter
    .Visible = xlSheetVisible 'si la feuille est masquée
    If .FilterMode Then .ShowAllData 'si la feuille est filtrée
    With .Range("A1", .UsedRange)
        With .Columns(.Columns.Count + 1) 'colonne auxiliaire
            .Formula = "=D1&E1" 'concaténation
            Set c = .Find(Target & Target(1, 2), , xlValues, xlWhole)
            .ClearContents 'RAZ
            If c Is Nothing Then
                MsgBox "Pas de correspondance en Feuil1..."
            Else
                Application.Goto .Parent.Cells(c.Row, "D")
            End If
        End With
    End With
End With
End Sub

Fichier joint.

Bonne nuit.

 

[Kael_88]

Le forum,@Staple1600 , @mapomme , @job75,

Merci à vous, chaque proposition est excellente à sa façon.

Cordialement.

 

[Staple1600]

Bonjour le fil, le forum,Kael_88, mapomme, job75

Kael_88
La mienne de proposition excelle surtout dans sa rustique incomplétude

 

[mapomme]

Bonjour Staple1600, Kael_88, job75 et les autres,

Kael_88
La mienne de proposition excelle surtout dans sa rustique incomplétude

Doucement avec l'autoflagellation ...

En même temps, la demande de Kael_88 n'était pas des plus précises. Et sa réponse est tout autant ambigüe mais a l"avantage de ménager la chèvre, le chou et le loup (chacun de Staple1600, job75 et mapomme se reconnaitra)

 

[job75]

Bonjour Kael_88, JM, mapomme, le forum,

Avec ce fichier (2) le tableau en Feuil1 peut être placé n'importe où :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Row < 7 Or Target.Column <> 7 Or Target = "" Then Exit Sub
Dim c As Range, adr$
Cancel = True
With Sheets("Feuil1") 'nom à adapter
    .Visible = xlSheetVisible 'si la feuille est masquée
    If .FilterMode Then .ShowAllData 'si la feuille est filtrée
    Set c = .Cells(.Rows.Count, .Columns.Count)
    Do
        Set c = .Cells.Find(Target, c, xlValues, xlWhole)
        If c Is Nothing Then
            Exit Do
        Else
            If adr = "" Then adr = c.Address Else If c.Address = adr Then Exit Do
            If c & c(1, 2) = Target & Target(1, 2) Then Application.Goto c: Exit Do
        End If
    Loop
End With
If ActiveSheet.Name = Me.Name Then MsgBox "Pas de correspondance en Feuil1..."
End Sub

Toujours concaténation à cause des doublons.

Bonne journée.

 

[Staple1600]

Re, job75, mapomme

En même temps, la demande de Kael_88 n'était pas des plus précises. Et sa réponse est tout autant ambigüe mais a l"avantage de ménager la chèvre, le chou et le loup (chacun de Staple1600, job75 et mapomme se reconnaitra)

@mapomme
On peut aussi trouver avantage à ne pas ménager le chou et ta soeur*
Comme ici par exemple

*: il faut cliquer sur le lien ci-dessus pour comprendre

 

[mapomme]

Re,

il faut cliquer sur le lien ci-dessus pour comprendre

J'ai vu celle-ci. L'agneau peut bien remplacer la chèvre.

 

[Staple1600]

Re

Quant au loup, il peut se marier à la pomme
(L'agrafe passera son tour, car ne s'épluche pas, ne s'émince pas, ne se grille pas etc..)

Ceci dit, j'aimerai comprendre le mode opératoire qui oblige à avoir deux feuilles quasi-identiques et le pourquoi du va-et-vient entre ces deux feuilles

 

[job75]

Bonjour Kael_88, JM, mapomme, le forum,

le pourquoi du va-et-vient entre ces deux feuilles

Ah oui un va-et-vient, alors dans ThisWorkbook :

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
If Target(1) = "" Then Exit Sub
Dim a, n As Variant, c As Range, adr$
a = Array("Feuil1", "Feuil2") 'noms des feuilles à adapter
n = Application.Match(Sh.Name, a, 0)
If IsError(n) Then Exit Sub
Cancel = True
With Sheets(a(2 - n))
    .Visible = xlSheetVisible 'si la feuille est masquée
    If .FilterMode Then .ShowAllData 'si la feuille est filtrée
    Set c = .Cells(.Rows.Count, .Columns.Count)
    Do
        Set c = .Cells.Find(Target, c, xlValues, xlWhole)
        If c Is Nothing Then
            Exit Do
        Else
            If adr = "" Then adr = c.Address Else If c.Address = adr Then Exit Do
            If c & c(1, 2) & c(1, 3) = Target(1) & Target(1, 2) & Target(1, 3) Then Application.Goto c: Exit Do
        End If
    Loop
End With
If ActiveSheet.Name = Sh.Name Then MsgBox "Pas de correspondance en " & a(2 - n)
End Sub

3 cellules concaténées...

Fichier (3).

Bonne journée.

 

[Kael_88]

Le forum,@Staple1600 , @mapomme , @job75,

Merci à vous et bon appétit.

Le va et vient se fait après une modification en feuil2,
or je doit rechercher la corrélation avec la feuil1
puis modifié certains paramètres en manuel, (automatique pas possible),
ce qui me permet, maintenant de gagner du temps sur la recherche.

merci encore à vous.

Cordialement