Reherche formule pour effacer cellules sous condition

[simrobert21]

Bonjour

J'ai un fichier dont j'aimerais que le contenu des cellules D6 à J6 soit supprimé si la cellules B6 contient quelque chose. et ainsi de suite pour les lignes suivantes Je joins une copie de mon fichier. Merci de m'aider, j'ai fait plusieurs recherche et je n'ai rien trouvé qui soit satisfaisant.

 

[JJ1]

Re : Reherche formule pour effacer cellules sous condition

Bonsoir,
Avec un Si en D6:
=Si(B6<>"";"";date)
la date peut être aujourdhui() si date du jour?
a tester en D6:J6.
A+

 

[alex67800]

Re : Reherche formule pour effacer cellules sous condition

Bonjour simrobert21 et JJ1,


Essai cela ça à l'air de fonctionner:

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Application.Intersect(Target, ActiveSheet.Range("B6:B22")) Is Nothing Then
If IsDate(Target.Value) Then
ActiveSheet.Range("D6:J22").Value = ""
End If
End If
End Sub

Je n'ai aucun mérite j'ai trouvé ce code que j'ai adapté pour ton cas ici:

https://www.excel-downloads.com/thr...utomatiquement-en-fonction-dune-autre.105335/

Mas attention comme tu pourras le lire en suivant ce fil les cellules seront éffacés, donc les données D6:J6 (et suivantes) perdues.

Merci à tototiti2008

Bonne journée

 

[simrobert21]

Re : Reherche formule pour effacer cellules sous condition

Merci, ta solution fonctionne très bien. Par contre j'aimerais que lors d'ajout de texte dans la cellule B6, le texte dans présent seulement dans entre D6 à J6 sois effacé. La même chose pour les lignes suivantes. Est-ce possible ? Merci de votre aide.

 

[tototiti2008]

Re : Reherche formule pour effacer cellules sous condition

Bonjour à tous,

à tester :

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Application.Intersect(Target, ActiveSheet.Range("B6:B22")) Is Nothing Then
ActiveSheet.Range("D" & target.row & ":J" & target.row).Value = ""
End If
End Sub

remarque : ne fonctionne que si on ne modifie qu'une cellule (pas si on en efface plusieurs par exemple)

 

[simrobert21]

Re : Reherche formule pour effacer cellules sous condition

Incroyable, tu est fort. Ça fonctionne par contre est-il possible que si j'éfface le texte dans la cellule B6, le texte entre D6 et J6 reste là et qu'il s'éfface seulement si j'ajoute du texte dans B6. Merci à l'avance

 

[tototiti2008]

Re : Reherche formule pour effacer cellules sous condition

Re,

Mais oui :

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Application.Intersect(Target, ActiveSheet.Range("B6:B22")) Is Nothing Then
if Target.value <> "" then
ActiveSheet.Range("D" & target.row & ":J" & target.row).Value = ""
end if
End If
End Sub

 

[simrobert21]

Re : Reherche formule pour effacer cellules sous condition

Excellent, c'est exactement ce que j'avais besoin. Le fait de ne pas pouvoir éffacer la colonne B d'un coup me causait un problème mais finalement lors de l'éffacement, le bébogueur démare mais en faisant fin, j'ai le résultat désiré.

Merci à tous

 

[tototiti2008]

Re : Reherche formule pour effacer cellules sous condition

Re,

pour éviter les bug et permettre l'effacement de plusieurs cellules ou le copier/coller :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cellule As Range
    If Not Application.Intersect(Target, ActiveSheet.Range("B6:B22")) Is Nothing Then
        For Each Cellule In Application.Intersect(Target, ActiveSheet.Range("B6:B22"))
            If Cellule.Value <> "" Then
                ActiveSheet.Range("D" & Cellule.Row & ":J" & Cellule.Row).Value = ""
            End If
        Next Cellule
    End If
End Sub

 

[simrobert21]

Re : Reherche formule pour effacer cellules sous condition

Je viens de tester ton nouveau code et malheureusement il n'éfface plus les cellules D6 à J6. tu as une idée pourquoi ?

 

[tototiti2008]

Re : Reherche formule pour effacer cellules sous condition

je ne comprend pas, ça marche trés bien chez moi....

 

[simrobert21]

Re : Reherche formule pour effacer cellules sous condition

Merci, c'est mon erreur, j'avais changé le B22 pour B500 dans juste une des deux place. Excellent support, MERCI

 

[alex67800]

Re : Reherche formule pour effacer cellules sous condition

Bonjour simrobert21, tototiti2008,

Je vois que l'auteur est venus à ton secours et c'est tant mieux.

Tototiti2008, tu ne m'en veux pas de t'avoir plagier, sans oublier de te citer (respect oblige). lol

Bonne continuation simrobert21, et tototiti2008.

 

[simrobert21]

Re : Reherche formule pour effacer cellules sous condition

Encore une petite question, y a t'il moyen de faire effacer de D6 à H6 et J6. En gros j'aimerais que I6 ne soit pas supprimé. Encore merci

 

[tototiti2008]

Re : Reherche formule pour effacer cellules sous condition

Re,

mais oui, il y a moyen :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cellule As Range
    If Not Application.Intersect(Target, ActiveSheet.Range("B6:B22")) Is Nothing Then
        For Each Cellule In Application.Intersect(Target, ActiveSheet.Range("B6:B22"))
            If Cellule.Value <> "" Then
                ActiveSheet.Range("D" & Cellule.Row & ":H" & Cellule.Row & ",J" & Cellule.Row).Value = ""
            End If
        Next Cellule
    End If
End Sub

Bonjour alex67800,

mais ça ne me dérange pas du tout d'être cité, c'est même plutôt flatteur