récupérer liste sans doublons avec formule dans une autre colonne et sans suppression

marcosisi

XLDnaute Nouveau
Bonjour à tous,
j'aimerai svp faire une copie d'une liste "A" se trouvant dans une colonne (composée de dates en doublons) dans une liste "B" sans doublons dans une autre colonne et tout ça par une formule en non par le filtrage avancé dans l'onglet données.
merci bcp
 

haonv

XLDnaute Occasionnel
Re : récupérer liste sans doublons avec formule dans une autre colonne et sans suppre

Bonjour marcosisi, forum,

Un exemple joint
Si tu ne veux garder que les valeurs et que la liste n’évolue pas , tu peux faire un copier collage special-valeurs en colonne B.

Amicalement
 

Pièces jointes

  • pour marcosisi.xls
    20.5 KB · Affichages: 459

R@chid

XLDnaute Barbatruc
Re : récupérer liste sans doublons avec formule dans une autre colonne et sans suppre

Salut,
sur Excel2007 :
Nommer la Plage A2:A30 ===> "zone", dans le fichier de hanov
Selectionner la plage C2:C20 par exemple et coller cette formule :
=SIERREUR(INDEX(zone;PETITE.VALEUR(SI(EQUIV(zone;zone;0)=LIGNE(INDIRECT("1:"&LIGNES(zone)));EQUIV(zone;zone;0);"");LIGNE(INDIRECT("1:"&LIGNES(zone)))));"")
à valider par Ctrl+Maj+Entree
@+
Rachid
 

Pièces jointes

  • pour marcosisi_Rachid.xlsx
    9.7 KB · Affichages: 434
Dernière édition:

david84

XLDnaute Barbatruc
Re : récupérer liste sans doublons avec formule dans une autre colonne et sans suppre

Bonsoir,
si l'on veut passer par PETITE.VALEUR, plus simple comme cela :
Code:
=SI(LIGNES($1:1)<=SOMME(1/NB.SI(zone;zone));INDEX(zone;PETITE.VALEUR(SI(EQUIV(zone;zone;0)=LIGNE(INDIRECT("1:"&LIGNES(zone)));EQUIV(zone;zone;0));LIGNES($1:1)));"")
Validation matricielle puis tirer la formule vers le bas.
A+
 

R@chid

XLDnaute Barbatruc
Re : récupérer liste sans doublons avec formule dans une autre colonne et sans suppre

Salut David84,
pas plus simple que cela :
Code:
=SIERREUR(INDEX(zone;PETITE.VALEUR(SI(EQUIV(zone;zone;0)=LIGNE(INDIRECT("1:"&LIGNES(zone)));EQUIV(zone;zone;0));LIGNES($1:1)));"")
A valider par Ctrl+Maj+Entree et à tirer vers le bas.
 

david84

XLDnaute Barbatruc
Re : récupérer liste sans doublons avec formule dans une autre colonne et sans suppre

Re
@Rachid: personnellement, je préfère utiliser un test logique dès que je le peux à la place de =SI(EST.....).
Concernant SIERREUR c'est vrai que c'est plus simple de l'utiliser mais il me semble que cette fonction n'existe pas sur les versions antérieures à 2007. Donc, si l'utilisateur qui est sous 2007 doit communiquer avec d'autres personnes qui possèdent une version d'Excel plus ancienne, la formule ne sera pas opérationnelle. Maintenant, c'est vrai que cela facilite et raccourcit l'écriture de la formule.
A+
 
Dernière édition:

R@chid

XLDnaute Barbatruc
Re : récupérer liste sans doublons avec formule dans une autre colonne et sans suppre

Re,
Oui c'est vrai que cette fonction n'existe que sur Excel2007, et j'ai vu que le monsieur travail sur cette version c'est pour cela j'ai proposé cette formule.
@+
Rachid
 

Discussions similaires

Statistiques des forums

Discussions
311 733
Messages
2 082 015
Membres
101 870
dernier inscrit
Dethomas