Recherche multicritères avec Index + Equiv

tamatave33

XLDnaute Occasionnel
Bonjour le forum,

Je bute sur une recherche multicritères avec les fonctions Index + Equiv
Dans le tableau joint, je cherche à trouver le diamètre (B8:B15) en fonction de la pente (C5:L5) et du débit (C7:L15).
Quelqu'un pourrait-il m'aider, car je ne trouve pas.
Merci d'avance.
 

Pièces jointes

  • Tableau.xls
    15 KB · Affichages: 30
  • Tableau.xls
    15 KB · Affichages: 33
  • Tableau.xls
    15 KB · Affichages: 35

Dugenou

XLDnaute Barbatruc
Re : Recherche multicritères avec Index + Equiv

Bonjour,
aprés avoir trié le tableau dans l'autre sens (plus grands débits en haut) acr j'ai pensé qu'on devait prendre la valeur de diametre immédiatement supérieure
Code:
=INDEX($B$7:$B$15;EQUIV($C$17;DECALER($B$7:$B$15;;EQUIV($C$18;$C$5:$L$5;0));-1))
Voir en PJ la formule expliquée.
On cherche la colonne de la pente EQUIV($C$18;$C$5:$L$5;0) le 0 indique qu'on cherche la valeur exacte
et on décale : DECALER($B$7:$B$15;;EQUIV(---))
pour rechercher le débit dans cette colonne : EQUIV($C$17;DECALER(---);-1)
on affiche le diametre : INDEX($B$7:$B$15;----)
Cordialement
 

Pièces jointes

  • tamatave33.xls
    25.5 KB · Affichages: 40

tamatave33

XLDnaute Occasionnel
Re : Recherche multicritères avec Index + Equiv

Bonsoir Dugenou,
Je reviens vers vous, car j'ai un problème lorsqu'on est en dehors du tableau.
Existe-t-il un moyen pour éviter "#N/A" lorsque le débit est en dehors de la limite du tableau.
J'ai essayé avec ESTERREUR, mais cela ne fonctionne pas.
Merci d'avance.
 

Calvus

XLDnaute Barbatruc
Re : Recherche multicritères avec Index + Equiv

Bonsoir,

Code:
=SI(ESTNUM(INDEX($B$7:$B$15;EQUIV($C$17;DECALER($B$7:$B$15;;EQUIV($C$18;$C$5:$L$5;0));-1)));INDEX($B$7:$B$15;EQUIV($C$17;DECALER($B$7:$B$15;;EQUIV($C$18;$C$5:$L$5;0));-1));"")

Bonne soirée.
 

CISCO

XLDnaute Barbatruc
Re : Recherche multicritères avec Index + Equiv

Bonsoir

Tu peux peut être faire un peu plus simple en supprimant le 1er INDEX et une ou deux parenthèses :
Code:
SI(ESTNUM(EQUIV($C$17;DECALER($B$7:$B$15;;EQUIV($C$18;$C$5:$L$5;0));-1));INDEX($B$7:$B$15;EQUIV($C$17;DECALER($B$7:$B$15;;EQUIV($C$18;$C$5:$L$5;0));-1));"")

Comme je n'ai pas suivi toute l'histoire, il faut mieux vérifier. Ce n'est qu'une petite proposition au passage...

@ plus
 

Statistiques des forums

Discussions
311 733
Messages
2 082 019
Membres
101 872
dernier inscrit
Colin T