Recherche de valeurs dans plusieurs colonnes

[Qoods]

Bonjour à tous,
Je voudrais gagner un temps fou dans mon travail de recherche et j'ai besoin de vous.

J'ai 34 colonnes dont leur contenu est un ensemble de champs mais tous les champs ne sont pas forcément présents dans chaque colonne.
Admettons les champs suivants : 1, 2, 3, 4, 5, 6, 7
Admettons les colonnes avec les noms suivants : A, B, C, D

Exemple : 
A  B  C  D 
----------- 
1  3  1  3 
2  2  5  5 
3     7 
4 
5

Je voudrais savoir s'il était possible d'inverser l'affichage de façon à avoir les champs en en-tête de colonne et leurs colonnes respectives en contenu ?

Exemple : 
1  2  3  4  5  6  7 
--------------------
A  A  A  A  A     C 
C  B  B     C 
      D     D

Merci d'avance

 

[Dugenou]

Re : Recherche de valeurs dans plusieurs colonnes

Bonjour,
Voir pj avec une formule matricielle qui se recopie en bas et à droite.
Pas certain que le temps de calcul reste raisonnable si 34 colonnes et plus de 1000 lignes

Cordialement

 

[Qoods]

Re : Recherche de valeurs dans plusieurs colonnes

Merci beaucoup Dugenou, ça à l'air de bien marcher !
J'ai juste à recopier la formule dans ma feuille ?

EDIT3 : j'utilise des caractères, pas des nombre. La formule ne fonctionne qu'avec des nombres. Tu as l'équivalent pour du texte ?

 

[Dugenou]

Re : Recherche de valeurs dans plusieurs colonnes

Re,
1) as-tu validé la formule avec la combinaison des 3 touches ctrl+maj +enter ?
des {} doivent apparaître autour de la formule.
le fait que ce soit des caractères n'a pas d'importance. par contre les parties en rouge sont à adapter !
=SIERREUR(INDEX($A$1:$D$1;;PETITE.VALEUR(SI($A$2:$D$6=A$11;COLONNE($A$2:$D$6));LIGNES($12:12)));"")

si tu as changé la plage $A$2:$D$6 il faut la mettre à jour dans les deux parties : le SI et le COLONNE(..)
si ton tableau de résultat commence en ligne 25 au lieu de la ligne 12 il faut corriger la partie LIGNES(...)
enfin, quelle que soit la plage des valeurs à afficher : il faut commencer en colonne A : si tes données sont en C15:BD50 avec les titres en C14:BD14, et le tableau de résultat en A25... pour le titre avec la première valeur en A26 cela donnerait :

=SIERREUR(INDEX($A$14:$BD$14;;PETITE.VALEUR(SI($C$15:$BD$50=A$25;COLONNE($C$15:$BD$50));LIGNES($26:26)));"")
à valider par ctrl+majprov+enter

PS si ça ne va toujours pas : joins un ptit bout de ton fichier (5 colonnes et 4 lignes mais avec exactement la vraie disposition

 

[Qoods]

Re : Recherche de valeurs dans plusieurs colonnes

Voici mon topo, pour moi je ne vois pas l'erreur :/

Les titres (A, B, C, ...) : A1:AH1
Le contenu (aaa, bbb, ccc, ...): A2:AH56

J'inverse tout ça,
Les titres (aaa, bbb, ccc, ...) : A59:EO59
Ma formule en A60 :
=SIERREUR(INDEX($A$1:$AH$1;;PETITE.VALEUR(SI($A$2:$AH$56=A$59;COLONNE($A$2:$AH$56));LIGNES($60:60)));"")

Une idée ?

EDIT : c'est bon ça marche !
Merci infiniment !!!!!!!! <3

 

[Dugenou]

Re : Recherche de valeurs dans plusieurs colonnes

C'est bien ça avec validation en matriciel : des {} doivent apparaître autour de la formule

 

[Qoods]

Re : Recherche de valeurs dans plusieurs colonnes [Résolu]

Tout marche niquel, t'es un chef !

 

[david84]

Re : Recherche de valeurs dans plusieurs colonnes

Bonsoir,
autre possibilité :

=SIERREUR(INDIRECT(ADRESSE(1;PETITE.VALEUR(SI($A$2:$D$6=A$11;COLONNE($A$2:$D$6));LIGNE(1:1))));"")

Si l'on veut éviter les doublons de colonnes qui se répètent (à tester en A12):

=SIERREUR(INDIRECT(ADRESSE(1;MIN(SI(($A$2:$D$6=A$11)*(NB.SI(A$11:A11;$A$1:$D$1)=0);COLONNE($A$2:$D$6)))));"")

Validation matricielle.
A+

 

[Qoods]

Re : Recherche de valeurs dans plusieurs colonnes

Merci beaucoup les gars

 

[gosselien]

Re : Recherche de valeurs dans plusieurs colonnes

Bonjour à tous,

je tente péniblement d'aider l'ami Qoods pour son problème qui pourrait faire 34 colonnes X 1000 lignes (donc 34.000 cellules quand même) , pour aller plus vite et que ça soit moins gourmand en ressource mémoire, j'ai écris un code VBA mais comme à chaque fois ou presque je me retrouve bloqué.
Alors , pour lui, comme pour mon égo blessé grièvement dans la bataille, y a t il une bonne âme pour me dire où et pourquoi mon code ne fonctionne pas ?

Merci