Raccourcir une formule sommeprod

madtnt09

XLDnaute Junior
Bonjour le forum,

Je me tourne vers vous parce que je n'ai pas les qualifications pour avancer plus loin et mes recherches ne m'ont mener nul part.

Voici ma formule:
"SUM(SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$68)*8),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$69)*7.5),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$70)*7),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$71)*6.5),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$72)*6),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$73)*5.5),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$74)*5),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$75)*4.5),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$76)*4),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$77)*3.5),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$78)*3),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$79)*2.5),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$80)*2),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$81)*1.5),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$82)*1),SUMPRODUCT((travailleurs_cardinal=$A$2)*(OFFSET('Janvier 14 '!J$11:p$116,,(ROWS($8:8)-1)*7)=$A$83)*0.5))"

Vu les sommeprod le système est très lent, j'ai essayé de trouvé une façon de diminuer la formule, mais sans succès si vous pouvez m'aider ce serait super.

En piece jointe le fichier utilisé, merci.
 

Pièces jointes

  • absences 2014 back up.xlsx
    118.9 KB · Affichages: 63
  • absences 2014 back up.xlsx
    118.9 KB · Affichages: 63
  • absences 2014 back up.xlsx
    118.9 KB · Affichages: 64

Modeste

XLDnaute Barbatruc
Re : Raccourcir une formule sommeprod

Bonjour madtnt09,

Compte-tenu de ce que j'ai cru comprendre ... pas certain que ta machine ne va pas "ramer" longtemps encore! J'espère que tu ne comptes pas insérer autant de feuilles qu'il y a de travailleurs renseignés :eek:

S'il n'y a pas de doublons dans la liste des travailleurs (ce que j'ai considéré comme acquis) on peut effectivement raccourcir la formule. Il est possible (mais nullement certain) que cet autre système soit un peu moins gourmand en ressources ... pour autant que je n'aie pas compris de travers!?

J'ai utilisé une formule pour nommer la plage relative au travailleur concerné, à la date recherchée et sur une période de 7 jours. Cette plage se nomme "SemCourante" et la formule est:
Code:
=DECALER('Janvier 14 '!$D$11;EQUIV('Théroux, Martin'!$A$2;travailleurs_cardinal;0)-1;EQUIV('Théroux, Martin'!$A7;'Janvier 14 '!$D$10:$NE$10;0)-1;;7)

Comme cette plage correspond à la semaine de Mr X, à dater du lundi Y, la formule (qui semble donner les mêmes résultats que la tienne) devient, en F7:
Code:
=SOMMEPROD((SemCourante=$A$68:$A$83)*($B$68:$B$83))
... à recopier vers le bas.

Fichier joint, pour la traduction des formules.
J'ai supprimé quelques noms et la moitié des dates pour "alléger" un peu le fichier. Attention: j'ai aussi remplacé les noms par des données "bidons". Pense à faire de même avec ton fichier!
 

Pièces jointes

  • absences 2014 (madtnt09).xlsx
    83.3 KB · Affichages: 48

madtnt09

XLDnaute Junior
Re : Raccourcir une formule sommeprod

Bonjour Modeste,

C'est génial comme solution en plus au lieu d'utiliser un onglet par personne je vais pouvoir utiliser une liste déroulante ce qui rendra probablement le fichier moins lourd.

Merci mille fois!!!
 

Discussions similaires

Statistiques des forums

Discussions
311 724
Messages
2 081 936
Membres
101 844
dernier inscrit
pktla