Problème sur formule: "#Valeur"

Armand11

XLDnaute Occasionnel
Bonjour à toute la communauté Exceldownload, et pour commencer meilleurs vœux 2018 à toutes et à tous, et merci à celles et ceux qui m'ont aidé en 2017...

Mon problème: sur une formule je n'arrive pas à solutionner le #valeur même en insérant la fonction "SIESTERREUR"...
Ma formule :=SI((A298="P&L");((SI(ESTNA(INDEX((SI($C$4=1;THOFY17!U:U;SI($C$4=2;THOFY17!V:V;SI($C$4=3;THOFY17!W:W;SI($C$4=4;THOFY17!X:X;SI($C$4=5;THOFY17!Y:Y;SI($C$4=6;THOFY17!Z:Z;SI($C$4=7;THOFY17!AA:AA;SI($C$4=8;THOFY17!AB:AB;SI($C$4=9;THOFY17!AC:AC;SI($C$4=10;THOFY17!AD:AD;SI($C$4=11;THOFY17!AE:AE;SI($C$4=12;THOFY17!AF:AF)))))))))))));EQUIV('BG Pointage'!B298;THOFY17!F:F;0)));"";INDEX((SI($C$4=1;THOFY17!U:U;SI($C$4=2;THOFY17!V:V;SI($C$4=3;THOFY17!W:W;SI($C$4=4;THOFY17!X:X;SI($C$4=5;THOFY17!Y:Y;SI($C$4=6;THOFY17!Z:Z;SI($C$4=7;THOFY17!AA:AA;SI($C$4=8;THOFY17!AB:AB;SI($C$4=9;THOFY17!AC:AC;SI($C$4=10;THOFY17!AD:AD;SI($C$4=11;THOFY17!AE:AE;SI($C$4=12;THOFY17!AF:AF)))))))))))));EQUIV('BG Pointage'!B298;THOFY17!F:F;0)))))*-1;"")

Elle est assez lourde je l'avoue mais fonctionne à merveille.... Mais dans certain cas elle m'affiche "#Valeur" car elle ne retrouve pas à juste titre le compte comptable qui n'éxiste pas... En effet les comptes comptables de la colonne B proviennent de de l'onglet FY18 donc les nouveaux comptes créés en FY18 ne se retrouvent effectivement pas en FY17 (car ils n'existaient pas en 2017).... Avez vous uen solution pour afficher une cellule BLANCHE au lieu de #Valeur ?

Merci pour votre aide ci-joint mon fichier de travail pour exemple...

A très bientôt, Armand
 

Fichiers joints

vgendron

XLDnaute Barbatruc
et tu peux simplifier ta fonction (colonne I) par
VB:
=SIERREUR(SI(A6="P&L";INDEX(DECALER(THOFY17!U:U;;$C$4-1);EQUIV('BG Pointage'!B6;THOFY17!F:F;0))*-1;"");"")
 

vgendron

XLDnaute Barbatruc
tu peux aussi avoir une seule formule pour tes deux colonnes I et J
en I6
=SIERREUR(SI($A6="P&L";INDEX(DECALER(INDIRECT("'THO" &I$4 &"'!U:U");;$C$4-1);EQUIV('BG Pointage'!$B6;INDIRECT("'THO" &I$4 &"'!F:F");0))*-1;"");"")
tu tires vers la droite
et vers le bas
 

vgendron

XLDnaute Barbatruc
à noter que le sierreur prend aussi en compte les N/A...
donc plus besoin dans tes formules de Si (NA(formule);"";formule)
tu peux remplacer par
sierreur(formule;"")
je pense que tu vas gagner en légèreté de fichier et rapidité d'execution..
 

Armand11

XLDnaute Occasionnel
Vgendron,
1-Mille Mercis Vgendron, je vais pouvoir simplifier mes formules...Je teste et reviens vers toi.
2- je profite de tes compétences car je bloque sur un fichier en formule matricielle sur le fichier joint. En effet j'ai mis en place un Agenda fiscal avec toutes mes dates et taches à faire que je récupère sur une fiche en fonction de la date. Mais je n'arrive pas à arranger ma formule matricielle... Peux tu me dire où ca pèche ? dans l'onglet "Fiche THOM" je sélectionne en B3 grâce à un menu déroulant la pèriode que je veux et là il est censé m'afficher mes tâches du mois à faire..... Merci encore ! , Armand
 

Fichiers joints

Armand11

XLDnaute Occasionnel
Cher Vgendron !
1- tout d'abord c'est exceptionnel ! oui c'est la meilleure façon de traiter une macro. Je vais la refaire de mon côté chez moi et apprendre à les maîtriser....si j'ai un probleme je reviens vers toi.
2- juste une petite remarque (malgré l'extraordinaire solution que tu m'apportes...): en Oct-17 j'aurai souhaité avoir le format en date exemple : 15/10/2017 et non pas "15" (je sais je pinaille mais je suis comptable ..... ) c'est pour une meilleure lecture...
ET toujours en Oct-17 il reprend la première ligne de Titre du tableau principal (onglet THOM) : 01 / Social et Fiscal / Source / Formulaire.imprimé ... est ce possible de ne pas les mentionner ...?

MErci encore pour ton aide
Très sincèrement , Armand
 

vgendron

XLDnaute Barbatruc
Voici la version corrigée
1) ne prend plus la ligne de titre
2) met la date complète en colonne A ou le texte
3) et j'ai modifié la liste de validation pour la cellule B3 (où tu sélectiones le mois)
j'ai créé une zone nommée "ListeMois" DYNAMIQUE ==> qui s'adapte au nombre de mois qu'il y a dans ta feuille THOM
 

Fichiers joints

Armand11

XLDnaute Occasionnel
Très cher Vgendron,
Et bien c'est juste parfait je ne sais pas quoi dire ou faire pour te remercier. Je vais m'y mettre au macro dés à présent car tu m'as convaincu de sa réelle efficacité. Merci infiniment Vgendron. A ta dispo au cas où ... Armand
 

Armand11

XLDnaute Occasionnel
Bonjour Vgendron,

J'ai amélioré et allégé grâce à toi mon fichier et mes formules en colonne H, I, J & K...et ç'est parfait...
Par contre je bute sur ma colonne N pour déterminer le sens de ma variation notamment sur les postes "Bilan". Ma formule marche sur les "P&L" mais quand j'associe dans la même formule les conditions relatives aux "Bilan" il me marque "FAUX"....

Je voudrais intégrer :

=SI(GAUCHE(A709;3)="P&L";SIERREUR(SI(ET(F709="passif";(L709*1)>0);$N$5;SI(ET(F709="passif";(L709*1)<0);$N$6;SI(ET(F709="actif";(L709*1)<0);$N$5;SI(ET(F709="actif";(L709*1)>0);$N$6))));SI(A709="Bilan";SIERREUR(SI(ET(F709="passif";(L709*1)>0);$N$6;SI(ET(F709="passif";(L709*1)<0);$N$5;SI(ET(F709="actif";(L709*1)<0);$N$6;SI(ET(F709="actif";(L709*1)>0);$N$5))));""))))

Je ne comprends pas pourquoi ?

Ma règle est la suivante :
Si Variation (col L) =0 ALORS "", Sinon :
Si compte de P&L (col A) + Actif (col F) + Variation (col L) >0 ALORS Fleche qui baisse
Si compte de P&L (col A)+ Actif (col F) + Variation (col L) <0 ALORS Fleche qui monte
Si compte de P&L (col A)+ Passif (col F) + Variation (col L) <0 ALORS Fleche qui baisse
Si compte de P&L (col A) + Passif (col F) + Variation (col L) >0 ALORS Fleche qui monte
Si compte de Bilan (col A) + Actif (col F) + Variation (col L) >0 ALORS Fleche qui monte
Si compte de Bilan (col A) + Actif (col F) + Variation (col L) <0 ALORS Fleche qui baisse
Si compte de Bilan (col A) + Passif (col F) + Variation (col L)>0 ALORS Fleche qui baisse
Si compte de Bilan (col A) + Passif (col F) + Variation (col L) <0 ALORS Fleche qui monte

Merci pour ton aide Vgendron, Bien à toi

Armand
 

Fichiers joints

Haut Bas