Problème de calcul entre 2 dates

[premion]

Bonsoir à toutes et à tous,

Je suis confronté à un petit problème pour lequel je coince depuis cet après-midi.

Dans le fichier joint, j'ai tout expliqué.

En fait, j'ai deux tableaux:
- sur le premier, je rentre des actions avec un budget avec une date de début et une date de fin
- sur le deuxième, le budget est splitté par mois et éventuellement additionné.
Les formules fonctionnent lorsque les deux dates sont dans le même mois. Ca se complique lorsque le budget est étalé sur plusieurs mois. Dans ce dernier cas, le budget est bien divisé par le nbre de mois mais seulement pour le premier mois. LEs mois suivants restent à 0. Je n'ai pas trouvé l'astuce me permettant d'intégrer la date de fin pour les mois suivants, ou la formule devient beaucouop trop complexe.

Auriez-vous une idée qui me permette de me décoincer? Merci beaucoup et bonne soirée.

Philippe

 

[Dranreb]

Re : Problème de calcul entre 2 dates

Bonsoir.
Alors bon, faudrait peut être pas éviter à tout prix les colonnes intermédiaires, n'est-ce pas ?
Alors j'ai calculé les budgets par mois en colonne O. En O8 :

=$K8/((ANNEE($I8)-ANNEE($G8))*12+MOIS($I8)-MOIS($G8)+1)

À ce prix là, en T9 :

=SOMMEPROD(($C$8:$C$19=$S9)*(T$8>=$G$8:$G$19)*(MOIS.DECALER(T$8;1)-1<=$I$8:$I$19);$O$8:$O$19)

Ça semble marcher.
Cordialement.

 

[premion]

Re : Problème de calcul entre 2 dates

Bonjour Dranreb,

Tout d'abord merci beaucoup, ça fonctionne déjà beaucoup mieux. Toutefois un petit souci subsiste...

Dans le cas où la période entre les deux dates ne contient pas au moins un mois entier, la fonction MOIS.DECALER ne considère plus le 1/2 mois.
Par exemple
- du 01/04/2012 au 30/04/2012 ça fonctionne puisque "2" s'affiche dans Avril
- du 01/04/2012 au 31/05/2012 fonctionne aussi puisque "1" s'affiche dans Avril et MAi

En revanche lorsque l'on a une date du 01/04/2012 au 15/04/2012 ça ne fonctionne plus et Avril affiche "0"

C'est pourquoi j'avais opté pour un calcul qui permettait de ne considérer que le mois entier en arrondissant au mois supérieur:

=ARRONDI.SUP(12*(ANNEE($I8)-ANNEE($G8))+MOIS($I$8)-MOIS($G8)+(JOUR($I$8)-JOUR($G$8))/30;0)

Mais là ça ne marche plus parce que je mélange les torchons et les serviettes...

Alors toute idée serait bienvenue!

Philippe

 

[Dranreb]

Re : Problème de calcul entre 2 dates

Bonjour.
La formule pour qu'elle travaille uniquement avec les mois, en T9:

=SOMMEPROD(($C$8:$C$19=$S9)*(ANNEE(T$8)*12+MOIS(T$8)>=ANNEE($G$8:$G$19)*12+MOIS($G$8:$G$19))*(ANNEE(T$8)*12+MOIS(T$8)<=ANNEE($I$8:$I$19)*12+MOIS($I$8:$I$19));$O$8:$O$19)

Remarques: La formule colonne O pourrait être mise ailleurs, tout à la fin pour pouvoir ne pas être englobée dans une future zone d'impression.
Il devrait être possible dans les options, même en Excel 2010 de demander à ce que les valeurs 0 ne soient pas affichées.
À +

 

[premion]

Re : Problème de calcul entre 2 dates

Re-Bonjour,

Et merci mille fois! c'est top: tout marche parfaitement!

Très bonne journée

Philippe