Ouverture de n'importe quel fichier via une Listbox

[thespeedy20]

Bonjour le forum,

Je viens de récupérer un code qui permet d'afficher les fichiers d'un répertoire dans une listbox...j'aimerais qu'en sélectionnant le fichier qu'il s'ouvre ...

Merci beaucoup pour votre aide

Oli

 

[sylvanu]

Bonsoir Thespeedy,
Pourquoi passer par une listbox ?
On peut utiliser un service VBA pour le faire :

Sub OuvrirFichier()
  Dim Fichier As String
    With Application.FileDialog(3)
        .Show
        On Error Resume Next
        Fichier = .SelectedItems(1)
        If Err.Number <> 0 Then Exit Sub
        Workbooks.Open Fichier
    End With
End Sub

ou encore si on veut aller à un endroit spécifique :

Sub OuvrirFichier()
    Dim Fichier As String, Chemin As String
    Chemin = "g:\Users\PC_PAPA\Documents\_SYLVAIN\Technique\Excel" ' Mettre le chemin désiré
    ChDrive "G"
    ChDir Chemin
    Fichier = Application.GetOpenFilename()
    If Fichier = "Faux" Then Exit Sub
    Workbooks.Open Fichier
End Sub

 

[thespeedy20]

Bonsoir Sylvanu,

tes deux propositions sont valables pour ouvrir des fichiers excel...ici je désire pouvoir ouvrir tous les fichiers, aussi bien image, que pdf, que format word....

Oli

 

[sylvanu]

Oups, désolé, ce n'était pas précisé.
Au cas où ... cette macro ouvre tout type.

Sub OuvrirFichier3()
  Dim Fichier As String
    With Application.FileDialog(3)
        .Show
        On Error Resume Next
        Fichier = .SelectedItems(1)
        If Err.Number <> 0 Then Exit Sub
        OuvrirFichier4 Fichier
    End With
End Sub
Public Function OuvrirFichier4(MonFichier As String)
'par Excel-Malin.com ( https://excel-malin.com )
On Error GoTo OuvertureFichierErreur
   'vérifie si le fichier existe
   If Len(Dir(MonFichier)) = 0 Then
    OuvrirFichier4 = False
    Exit Function
   Else
   End If
   'ouvre le fichier dans son application associée
   Dim MonApplication As Object
   Set MonApplication = CreateObject("Shell.Application")
    MonApplication.Open (MonFichier)
    OuvrirFichier4 = True
   Set MonApplication = Nothing
Exit Function
OuvertureFichierErreur:
   Set MonApplication = Nothing
    OuvrirFichier4 = False
End Function

 

[thespeedy20]

re,

Grand Merci à toi Sylvanu, cela fonctionne nickel.....

Bonne fin de soirée

OLi